Saya kebanyakan menggunakan fungsi ini:
cf() {
cd "$(osascript -e 'tell app "Finder" to POSIX path of (insertion location as alias)')"
}
Anda juga dapat menetapkan pintasan ke skrip seperti yang di bawah ini.
Gunakan kembali tab yang ada atau buat jendela baru (Terminal):
tell application "Finder" to set p to POSIX path of (insertion location as alias)
tell application "Terminal"
if (exists window 1) and not busy of window 1 then
do script "cd " & quoted form of p in window 1
else
do script "cd " & quoted form of p
end if
activate
end tell
Gunakan kembali tab yang ada atau buat tab baru (Terminal):
tell application "Finder" to set p to POSIX path of (insertion location as alias)
tell application "Terminal"
if not (exists window 1) then reopen
activate
if busy of window 1 then
tell application "System Events" to keystroke "t" using command down
end if
do script "cd " & quoted form of p in window 1
end tell
Selalu buat tab baru (iTerm 2):
tell application "Finder" to set p to POSIX path of (insertion location as alias)
tell application "iTerm"
if exists current terminal then
current terminal
else
make new terminal
end if
tell (launch session "Default") of result to write text "cd " & quoted form of p
activate
end tell
Dua skrip pertama memiliki beberapa keunggulan dibandingkan dengan layanan yang ditambahkan pada 10.7:
- Pada 10.9, ada bug di mana layanan yang menerima folder sebagai input tidak pernah terdaftar di menu layanan dalam tampilan kolom. Jika Anda menetapkan Tab Terminal Baru di Folder layanan pintasan keyboard, itu tidak berfungsi dalam tampilan kolom.
- Mereka menggunakan folder pada bilah judul alih-alih mengharuskan Anda untuk memilih folder terlebih dahulu.
- Mereka menggunakan kembali tab paling depan jika tidak sibuk, mis. Menjalankan perintah, menampilkan halaman manual, atau menjalankan emacs.
Jika Anda menggunakan 10.7 atau 10.8, ubah tell application "Finder" to set p to POSIX path of (insertion location as alias)ke:
tell application "Finder"
if exists Finder window 1 then
set p to POSIX path of (target of Finder window 1 as alias)
else
set p to POSIX path of (path to desktop)
end if
end tell
Ada bug di 10.7 dan 10.8 (tetapi tidak di 10.9 atau 10.6) di mana Finder mengabaikan windows yang dibuat setelah fokus terakhir kali dipindahkan ke aplikasi lain dan kembali ketika mendapatkan insertion locationproperti.
