Apakah mungkin untuk mengikat Kamus Mac OSX saya.app ke Google Terjemahan?


10

Aplikasi Kamus memiliki pengalaman yang sangat keren di MacOSX. Tetapi saya harus menginstal kamus untuk digunakan. Apakah mungkin mengikatnya ke Google Terjemahan?

Terima kasih!


Sepertinya itu tidak akan berfungsi, setidaknya tanpa peretasan dan pembangunan kembali aplikasi dan ekstensi Kamus yang luas karena seperti kamus khusus yang statis dan bukan program yang berarti saya tidak bisa hanya menulis "kamus" yang mengambil teks dan menerjemahkan.
Sirene

Jawaban:


26

Sayangnya itu tampaknya tidak mungkin, atau paling tidak langsung. Sebagai alternatif, Anda mungkin ingin mempertimbangkan untuk membuat Layanan OS X yang membuka Google Translate di jendela browser, untuk kata atau frasa apa pun yang Anda pilih.

Jika ini kedengarannya cocok, ikuti prosedur di bawah ini:

Membuat Layanan terjemahan

  • Buka Automatoraplikasi dari Applicationsfolder Anda
  • Pilih Servicesebagai jenis dokumen dan klikChoose
  • Di jendela yang muncul, klik bidang pencarian dan ketik 'AppleScript'
  • Seret dan lepas Run AppleScripttindakan dari daftar di sebelah kiri ke area berlabel 'Seret tindakan atau file di sini untuk membangun alur kerja Anda'

Salin skrip di bawah ini dan rekatkan ke Run Applescripttindakan:

on run {input, parameters}
    set phrase to input as string
    set phrase to quoted form of phrase

    set ui_lang to "en"
    set from_lang to "en"
    set to_lang to "zh-CN"

    do shell script "open 'https://translate.google.com/?hl='" & ui_lang & "'&sl='" & from_lang & "'&tl='" & to_lang & "'&text='" & phrase
end run

Jendela Anda akan terlihat seperti berikut:

Alur kerja automator

Ada tiga nilai yang mungkin ingin Anda ubah dalam skrip di atas:

  • ui_lang - bahasa yang digunakan untuk antarmuka halaman
  • from_lang - bahasa sumber
  • to_lang - bahasa tujuan

Ubah satu atau lebih dari ini untuk mencapai terjemahan yang diinginkan. Untuk menemukan parameter bahasa yang benar, lihat Referensi Bahasa . Dalam contoh di atas enmengacu pada English, dan zh-CNuntuk Cina (Sederhana).

Setelah melakukan perubahan, klik File> Save...dan pada panel yang muncul ketikkan nama yang cocok (mis Translate English to Chinese.).


Menggunakan Layanan terjemahan

Setelah menyimpan alur kerja Anda di atas, Anda dapat menggunakan layanan terjemahan Anda dengan salah satu dari dua metode berikut:

1. Metode Menu Layanan

  • Sorot sebuah kata atau frasa dalam aplikasi apa pun
  • Klik Menu Aplikasi di sebelah kanan ikon Apple (), lalu klik Servicesdan Translate English to Chinese(atau nama yang Anda berikan Layanan saat menyimpannya):

Contoh menu layanan

2. Metode Menu Kontekstual

  • Sorot sebuah kata atau frasa dalam aplikasi apa pun
  • Klik kanan teks dan pilih Serviceskemudian Translate English to Chinese(atau Layanan kustom Anda bernama):

Contoh menu kontekstual


Metode apa pun yang Anda gunakan, jendela browser akan muncul dengan teks yang diterjemahkan:

Contoh Google Translate


1
Benar-benar brilian - terima kasih (Saya baru mengaturnya untuk beralih dari Bahasa Inggris ke Bahasa Mandarin (S), dengan cara yang sama seperti yang Anda lakukan dan kemudian memodifikasinya menjadi Bahasa Mandarin (S) ke Bahasa Inggris. Bantuan yang luar biasa! Terima kasih !!
user291332

1
Saya mengatur from_languntuk "auto".
Erik Kaplun

1

Yang ini melakukan segalanya seperti jawaban soulcake tetapi jika url penerjemah sudah ada - memuat terjemahan baru di tab yang sama

on run {input, parameters}
    set phrase to input as string

    set ui_lang to "en"
    set from_lang to "en"
    set to_lang to "ru"

    set theBaseUrl to "https://translate.google.com/"
    set theUrl to theBaseUrl & "?hl=" & ui_lang & "&sl=" & from_lang & "&tl=" & to_lang & "&text=" & phrase

    tell application "Google Chrome"
        activate

        if (count every window) = 0 then
            make new window
        end if

        set found to false
        set theTabIndex to -1
        repeat with theWindow in every window
            set theTabIndex to 0
            repeat with theTab in every tab of theWindow
                set theTabIndex to theTabIndex + 1
                if theTab's URL starts with theBaseUrl then
                    set found to true
                    exit repeat
                end if
            end repeat

            if found then
                exit repeat
            end if
        end repeat

        if found then
            set URL of theTab to theUrl
            set theWindow's active tab index to theTabIndex
            set index of theWindow to 1
        else
            tell window 1 to make new tab with properties {URL:theUrl}
        end if
    end tell

end run

Sayangnya, ia mengembalikan bug saat mencoba menggunakannya.
yonivav

@yonivav apa masalahnya? dapatkah Anda menjelaskan langkah-langkah untuk memperbanyaknya?
vladkha
Dengan menggunakan situs kami, Anda mengakui telah membaca dan memahami Kebijakan Cookie dan Kebijakan Privasi kami.
Licensed under cc by-sa 3.0 with attribution required.