Saat membuka file DMG, bagaimana saya membuatnya terbuka di depan windows?

Setiap kali saya mengunduh .dmgfile dan kemudian membukanya (biasanya dari bilah unduhan di Chrome), itu akan terbuka di latar belakang. Apakah ada cara untuk membuatnya terbuka di depan jendela saya?

Edit

Untuk memperjelas: Saya ingin jendela DMG muncul sebagai jendela aktif.

Saya membuat skrip Tindakan Folder dalam Applescript, yang mungkin melakukan apa yang Anda inginkan. Salin dan tempel ke dalam Applescript baru, dan simpan sebagai Aplikasi (tanpa dialog awal!) Ke "/ Library / Scripts / Folder Action Scripts /". Anda kemudian dapat melampirkannya ke folder apa pun (kemungkinan besar ~ / Downloads / folder Anda) dengan mengklik kanan folder tersebut dan memilih "mengkonfigurasi tindakan folder" dari menu drop-out layanan. Aktifkan Tindakan Folder dan biarkan skrip menonton folder.

Apa yang dilakukan skrip pada dasarnya, adalah bereaksi pada item yang dijatuhkan ke folder yang dilampirkan dan jika item yang dijatuhkan adalah Jenis: "Gambar" itu melampirkan Gambar sebagai Volume melalui alat baris perintah "hdiutil".

Anda dapat mengonfigurasi perilakunya dengan mengatur openWindow dan membuat propertiFrontmost di Script; ini juga dapat dilakukan dengan mengklik dua kali pada Script setelah Anda menyimpannya sebagai aplikasi - kemudian akan bertanya dalam dua dialog tentang apa itu seharusnya perilaku standar.

Saya harap ini membantu,

Asmus

 property openWindow : true
 property makeFrontmost : true

 on run

    display dialog "Do you want to bring the Finder to the front after new items are added?" buttons {"Don't Activate", "Activate"} default button 2
    if the button returned of the result is "Don't Activate" then
        set makeFrontmost to false
    else
        set makeFrontmost to true
    end if


    display dialog "Open Folder after adding new files?" buttons {"Don't Open", "Open"} default button 2
    if the button returned of the result is "Don't Open" then
        set openWindow to false
    else
        set openWindow to true
    end if


 end run

 on adding folder items to thisFolder after receiving addedItems

    repeat with i from 1 to number of items in addedItems
        set itemKind to the kind of (info for item i of addedItems) as string

        if itemKind is "Disk Image" then
            set itemPath to (quoted form of POSIX path of item i of addedItems)
            try
                showImage(itemPath)
            end try
        end if

    end repeat

 end adding folder items to


 on showImage(itemPath)

    set volumeMountpointInfo to do shell script "/usr/bin/hdiutil  attach " & itemPath & " | grep Volumes"


    if (openWindow is true) then
        if (makeFrontmost is true) then
            tell application "Finder" to activate
        end if

       set currentDelim to text item delimiters
       set text item delimiters to tab

       set volumeMountpoint to POSIX file (text item 3 of volumeMountpointInfo)

       set text item delimiters to currentDelim

       tell application "Finder" to open folder volumeMountpoint

    end if

 end showImage

====

Applescript kedua untuk menentukan jenis file yang dijatuhkan ke folder

On adding folder items to thisFolder after receiving addedItems
repeat with i from 1 to number of items in addedItems
    set itemKind to the kind of (info for item i of addedItems) as string
    display dialog itemKind
end repeat
end adding folder items to

Yang Diedit Harus "Disk Image" daripada "Image"

Dari apa yang dapat saya katakan, OS X hanya akan secara otomatis menampilkan isi dari disk image jika hanya-baca. Ini ditunjukkan oleh pensil dengan garis miring di bagian kiri bawah jendela Finder saat melihat konten gambar.

Jika Anda ingin mengubah image disk sehingga akan melakukan ini, Anda dapat membuat image disk yang ada hanya-baca dengan menggunakan Disk Utility. Sayangnya, ini tidak akan mengubah perilaku untuk gambar yang diproduksi secara tidak benar yang dapat Anda unduh dari Internet.

1. Pasang gambar disk yang ingin Anda buka otomatis.
2. Buka Disk Utility dengan mencarinya dengan Spotlight.
3. Pilih ikon "Gambar Baru" di bilah alat.
4. Beri nama file dan pilih "read-only" di bawah "Format Gambar."
5. Klik "Simpan." Ketika Anda memasang gambar baru ini, secara otomatis akan membuka jendela Finder.

Ini mungkin tidak menjawab pertanyaan dengan cukup baik, tetapi ...

Jika Anda menekan perintah dan mengklik item di bilah unduhan, itu menunjukkan item di finder. Pada titik itu, cukup menekan perintah-O (atau mengklik dua kali file dmg) akan memasangnya dan membukanya di jendela baru di latar depan.