Memasukkan nilai sub-superskrip terakhir yang digunakan dalam rumus matematika

Saya menggunakan AUCTeX untuk teks matematika tipe-pengaturan. Seringkali saya harus mengetikkan persamaan dengan jumlah, integral, dll. Yang semuanya memiliki sub- atau superskrip yang sama. Saya ingin mengisi ulang sub- / superscript saat ini dengan nilai yang dimilikinya sebelumnya. Contoh:

\sum_{i=1}^{\infty} a_i = \sum…

Ketika saya menekan _persamaan di atas Emacs harus menulis _{i=1}. Opsional akan lebih baik jika superscript kedua juga diisi.

Bagaimana ini bisa diwujudkan?

Tambahkan ke file init Anda:

(defvar mg-TeX-insert-subscript-history nil)
(defvar mg-TeX-insert-superscript-history nil)

(defun TeX-insert-sub-or-superscript (arg)
  "Insert typed key ARG times and possibly a pair of braces.
Brace insertion is only done if point is in a math construct and
`TeX-electric-sub-and-superscript' has a non-nil value."
  (interactive "*p")
  (self-insert-command arg)
  (when (and TeX-electric-sub-and-superscript (texmathp))
    (let* ((history (cond
             ((equal last-input-event ?_)
              'mg-TeX-insert-subscript-history)
             ((equal last-input-event ?^)
              'mg-TeX-insert-superscript-history)))
       (content (read-string "Content: " (car (symbol-value history)) history)))
      (insert (concat TeX-grop content TeX-grcl))
      (if (zerop (length content))
      (backward-char)))))

Pastikan TeX-electric-sub-and-superscriptdiatur ke non-nil.

Berikut adalah versi yang secara non-interaktif menyisipkan sub / skrip super terakhir yang terjadi untuk token pada titik:

(defun my/electric-sub-super-script (arg)
  "Insert typed character ARG times and possibly a sub/super-script.
Sub/super-script insertion is done only in a (La)TeX math mode region.
The inserted sub/super-script is copied from the last occurence of a
sub/superscript for the token at point."
  (interactive "p")
  (self-insert-command arg)
  (when (texmathp)
    (insert
     (save-excursion
       (let ((current-token (let ((end (point)))
                              (backward-sexp 1)
                              (buffer-substring-no-properties (point) end))))
         (if (search-backward current-token nil t)
             (progn
               (search-forward current-token)
               (let ((begin (point)))
                 (forward-sexp 1)
                 (buffer-substring-no-properties begin (point))))
           ""))))))

(define-key TeX-mode-map (kbd "_") #'my/electric-sub-super-script)
(define-key TeX-mode-map (kbd "^") #'my/electric-sub-super-script)

Mengambil contoh dalam pertanyaan, di bawah ini adalah urutan status buffer yang diperoleh dengan memulai dengan baris pertama dan mengetik _^SPCa_:

\sum_{i=1}^{\infty} a_i = \sum▮
\sum_{i=1}^{\infty} a_i = \sum_{i=1}▮
\sum_{i=1}^{\infty} a_i = \sum_{i=1}^{\infty}▮
\sum_{i=1}^{\infty} a_i = \sum_{i=1}^{\infty} a▮
\sum_{i=1}^{\infty} a_i = \sum_{i=1}^{\infty} a_i▮