Bagaimana saya bisa menumpuk satu tabel sintaks di yang lain?

Saya telah menulis mode sederhana untuk menangani JSON. Ia menggunakan mesin turunan untuk menggunakan kembali sebagian besar kode json-mode. Namun satu tambahan adalah Anda dapat memasukkan elisp ke dalam teks JSON yang dievaluasi pada waktu pengiriman JSON. Sebagai contoh kutipan dari json terlihat seperti ini:

{
    "parameters": {
        "IRC_USER": "stsquad",
        "PUB_KEY": `(format "\"%s\"" (s-trim (shell-command-to-string "cat ~/.ssh/id_rsa.pub")))`
    }
}

Saat ini penyorotan sintaks dari teks ini rusak karena sintaks JSON hightlighter get's dilemparkan oleh elisp. Saya ingin mengatur tabel sintaks bersarang sehingga elisp dikenali dengan benar sebagai elisp ketika di dalam karakter escape (saya telah memilih `dalam kasus ini). Saya mengerti Anda dapat bergabung dengan char-tables (dari mana sintaks-tables dibuat) dengan sesuatu seperti:

(defvar lava-mode-syntax-table
  (let ((json-table (copy-syntax-table json-mode-syntax-table))
        (elisp-table (copy-syntax-table lisp-mode-syntax-table)))
    (set-char-table-parent elisp-table json-table)
    (modify-syntax-entry ?` "(`" json-table)
    (modify-syntax-entry ?` ")`" json-table)
    json-table)
  "LAVA Mode syntax table.
This is a combination of json-mode-syntax-table with an escape into
  lisp-mode-syntax table for the embedded elisp.")

Tapi saya tidak mengerti bagaimana saya bisa memodifikasi tabel sintaks untuk mulai menggunakan tabel sintaks anak (elisp) sementara di antara karakter escape?

Anda tidak ingin membuat sarang satu tabel sintaks (yang merupakan struktur vektor) di dalam yang lain, Anda ingin mengatur buffer di mana, tergantung pada posisinya, satu tabel sintaks akan digunakan sebagai pengganti yang lain.

Jawaban lain menjelaskan bagaimana melakukan ini menggunakan syntax-tableproperti teks. Berikut ini cara melakukannya menggunakan salah satu paket "mode utama ganda", mmm-mode . Ini akan menggunakan segalanya mode primer di tingkat atas buffer, dan tabel sintaks submode, aturan font-lock, keymap, dll di "subregion".

(require 'mmm-auto)
(setq mmm-global-mode 'auto)

(mmm-add-classes
 '((eljson :submode emacs-lisp-mode
           :front ": *\\(`\\)" :back "`"
           :front-match 1
           :face mmm-code-submode-face)))

(mmm-add-mode-ext-class 'json-mode "\\.el\\.json\\'" 'eljson)

Ini mengasumsikan bahwa file mode campuran Anda dinamai *.el.json. Sesuaikan sesuai kebutuhan.

Sekarang, instal mmm-mode, evaluasi hal di atas dan (hanya kemudian) buka salah satu file yang dimaksud.

Ok, mari kita luruskan beberapa dasar.

Tabel sintaks Nesting dimungkinkan

Tabel sintaks tidak harus bersifat global ke seluruh buffer. Anda dapat menerapkannya sebagai properti teks ke wilayah tertentu. Ini berarti Anda memang dapat menerapkan elisptabel sintaks hanya untuk wilayah yang dikelilingi oleh backtick.

Bagaimana kamu melakukannya?

Inilah salah satu cara Anda dapat melakukannya. Metode ini melakukannya segera sebelum font-lock berjalan melalui buffer, jadi metode ini harus secara khusus mencegah masalah penguncian font Anda.

(defun endless/set-syntax-then-fontify (beg end loudly)
  "Apply elisp syntax table to relevant regions before calling font-lock."
  (save-match-data
    (save-excursion
      (save-restriction
        (widen)
        (narrow-to-region beg end)
        (while (search-forward "`" nil 'noerror)
          ;; Using `end' here excludes the `, I don't know which syntax you
          ;; want to apply to that.
          (let ((left (match-end 0)))
            (when (search-forward "`" nil 'noerror)
              (add-text-properties
               left (match-beginning 0)
               (list 'syntax-table emacs-lisp-mode-syntax-table))))))))
  (font-lock-default-fontify-region beg end loudly))

Dalam definisi mode-utama Anda, Anda harus menambahkan:

(set (make-local-variable 'font-lock-fontify-region-function)
     #'endless/set-syntax-then-fontify)

Tabel sintaksis tidak sama dengan penyorotan sintaksis

Highlighter sintaks (sistem font-lock) menggunakan Tabel Sintaks sebagai bagian dari informasinya, sehingga solusi di atas harus mencegah stabilo agar tidak menjadi gila.

Namun, itu hanya bagian dari data, jika Anda juga ingin teks di backticks berwarna persis seperti yang Anda lihat di buffer elisp, Anda harus memperluas fungsi di atas untuk melakukannya secara khusus.

(defun endless/set-syntax-then-fontify (beg end loudly)
  "Apply elisp syntax table to relevant regions before calling font-lock."
  (save-match-data
    (save-excursion
      (save-restriction
        (widen)
        (narrow-to-region beg end)
        (while (search-forward "`" nil 'noerror)
          ;; Using `end' here excludes the `, I don't know which syntax you
          ;; want to apply to that.
          (let ((left (match-end 0)))
            (when (search-forward "`" nil 'noerror)
              (add-text-properties
               left (match-beginning 0)
               (list 'syntax-table emacs-lisp-mode-syntax-table))))))))
  (font-lock-default-fontify-region beg end loudly)
  ;; Do some specific elisp fontifying here
  (save-match-data
    (save-excursion
      (save-restriction
        (widen)
        (narrow-to-region beg end)
        (while (search-forward "`" nil 'noerror)
          (let ((left (match-end 0)))
            (when (search-forward "`" nil 'noerror)
              ;; Call some function to fontify elisp between `left' and (match-beginning 0)
              )))))))