Bagaimana cara mencari kata Arab dalam teks tanpa diakritik / aksennya?

Dalam bahasa Arab seperti dengan beberapa bahasa lain ada yang disebut diakritik untuk meningkatkan pengucapan. Tidak ada konvensi tentang berapa banyak diakritik harus ditulis untuk satu kata. Beberapa menggunakan minimum (yang saya sukai) hanya cukup untuk mengacaukan pengucapan, sedangkan beberapa menggunakannya secara berlebihan atau hanya untuk tujuan kaligrafi estetika. Dengan demikian, ada variasi yang luas tentang apa dan berapa banyak diakritik terkait dengan satu kata. Ketika saya lakukan isearch-forward/backwarddengan menekan C-s/r, masalah muncul ketika saya mengetiknya di mini-buffer pencarian tanpa diakritik itu tidak akan cocok dengan kata yang sama dalam teks jika diakritik, membuat tugas mencari kata ini dengan potensi diakritik yang pernah tidak memuaskan.

Apakah ada cara untuk membuat pencarian / pencarian regexp tidak menyadari diakritik? Saya berharap akan ada jawaban yang dapat diperluas untuk memasukkan regexp C-M-s/rdan grepmencari yang saya gunakan cukup sering di helm-proyektil untuk mencari kata dalam proyek lateks multi-file.

Perbarui
Akan menyenangkan untuk melihat bahwa Emacs di semua fungsi pencariannya melakukan langkah pengupasan pada teks (dari aksen / diakritik / beri nama) sebelum mencocokkan langkah sebagai perilaku default yang mungkin dimatikan oleh awalan saat diminta tidak peduli apa bahasa yang ada. Biasanya, ketika saya mencari sesuatu yang saya tidak harapkan dari editor terbaik (Emacs) gagal dalam tugas ini hanya karena beberapa diakritik atau aksen yang jarang jika pernah diperlukan untuk menyelesaikan tugas-tugas teks biasa.

Inilah awal yang kasar, berdasarkan daftar penggabungan karakter dalam jawaban ini (dan kemudian diperluas). (Menandai ini sebagai wiki komunitas - harap edit dan perbaiki ini!)

(defconst arabic-diacritics '(#x064b #x064c #x064d #x064e #x064f #x0650 #x0651 #x0652 #x0653 #x0654 #x0655 #x0670)
  "Unicode codepoints for Arabic combining characters.")
(defconst arabic-diacritics-regexp (regexp-opt (mapcar #'string arabic-diacritics)))

(defconst arabic-equivalents
  '(
    ;; "alef" is equivalent to "alef with hamza above" etc
    (#x0627 #x0623 #x0625 #x0622)))

;; (require 'cl-lib)    
;; (defun arabic-strip-diacritics (string)
;;   (cl-reduce (lambda (s c) (remove c s)) arabic-diacritics :initial-value string))

(defun arabic-search-without-diacritics (string)
  (interactive (list (read-string "Search for: " nil nil nil t)))
  (let ((regexp
         (apply #'concat
                (mapcar (lambda (c)
                          (let ((equivalents (assq c arabic-equivalents)))
                            (concat
                             (if equivalents
                                 (regexp-opt (mapcar #'string equivalents))
                               (regexp-quote (string c)))
                             arabic-diacritics-regexp "*")))
                        string))))
    (search-forward-regexp regexp)))

Jadi jika buffer berisi "الْحَمْدُ لِلَّهِ رَبِّ الْعَالَمِينَ", dan saya mengevaluasi (arabic-search-without-diacritics "الحمد لله رب العالمين"), ia menemukan teks. Ini juga berfungsi secara interaktif, seperti M-x arabic-search-without-diacritics.

Pendekatan alternatif:

Berikut adalah contoh kode lengkap yang menunjukkan bagaimana tanda diakritik dan nonspacing lainnya ( Mnproperti) dapat dihilangkan dari string yang dinormalisasi dalam kecocokan regexp. Ini bekerja dengan contoh-contoh yang diberikan dan IMO adalah pendekatan yang tepat.

(defun kill-marks (string)
  (concat (loop for c across string
                when (not (eq 'Mn (get-char-code-property c 'general-category)))
                collect c)))

(let* ((original1 "your Arabic string here")
      (normalized1 (ucs-normalize-NFKD-string original1))
      (original2 "your other Arabic string here")
      (normalized2 (ucs-normalize-NFKD-string original2)))
  (equal
   (replace-regexp-in-string "." 'kill-marks normalized1)
   (replace-regexp-in-string "." 'kill-marks normalized2)))