Bagaimana saya bisa keluar dari Ediff segera tanpa harus mengetikkan 'y'

Ketika saya berhenti dari EDiff dengan qsaya ditanya apakah saya benar-benar ingin berhenti. Saya lebih suka berhenti segera. Tidak ada yang jelas dalam kustomisasi . Ada solusi di sini yang tampaknya berfungsi dengan mendefinisikan ulang qkunci, tapi saya tidak yakin dengan detail tentang bagaimana fungsi bekerja. Apa cara paling sederhana untuk berhenti benar-benar berarti berhenti?

Anda dapat memberi saran ediff-quitsehingga ia secara dinamis berayun y-or-n-pke fungsi yang kembali t.

(defun disable-y-or-n-p (orig-fun &rest args)
  (cl-letf (((symbol-function 'y-or-n-p) (lambda (prompt) t)))
    (apply orig-fun args)))

(advice-add 'ediff-quit :around #'disable-y-or-n-p)

Ini lebih kuat untuk perubahan hulu daripada mendefinisikan ulang ediff-quit.

Sayangnya saya pikir Anda harus memutar ulang q atau menyesuaikan sumber ediff-quit. Seperti yang terlihat dalam sumber ediff-quitbisikan selalu terjadi.

(defun ediff-quit (reverse-default-keep-variants)
  "Finish an Ediff session and exit Ediff.
Unselects the selected difference, if any, restores the read-only and modified
flags of the compared file buffers, kills Ediff buffers for this session
\(but not buffers A, B, C\).

If `ediff-keep-variants' is nil, the user will be asked whether the buffers
containing the variants should be removed \(if they haven't been modified\).
If it is t, they will be preserved unconditionally.  A prefix argument,
temporarily reverses the meaning of this variable."
  (interactive "P")
  (ediff-barf-if-not-control-buffer)
  (let ((ctl-buf (current-buffer))
    (ctl-frm (selected-frame))
    (minibuffer-auto-raise t))
    (if (y-or-n-p (format "Quit this Ediff session%s? "
              (if (ediff-buffer-live-p ediff-meta-buffer)
                  " & show containing session group" "")))
    (progn
      (message "")
      (set-buffer ctl-buf)
      (ediff-really-quit reverse-default-keep-variants))
      (select-frame ctl-frm)
      (raise-frame ctl-frm)
      (message ""))))

Saya akan menyarankan mendefinisikan ulang ediff-quitdi Anda .emacsdan mengirimkan tambalan ke sumber menambahkan variabel kustomisasi.

Ingatlah bahwa sumber implementasi di emacs selalu beberapa penekanan tombol saja. Anggap sumber elisp diinstal, ketik C-h f, masukkan nama fungsi dan ikuti tautan ke tempat definisi itu.

Saya menggunakan rebind q di ediff berikut. Jika ada buffer yang dimodifikasi, ia bertanya apakah mereka akan diselamatkan, maka itu hanya berhenti. Jika tidak ada buffer yang dimodifikasi, itu hanya berhenti.

(add-hook 'ediff-startup-hook
          (lambda ()
            (local-set-key (kbd"q") 'my-ediff-quit)))

(defun my-ediff-quit ()
  "If any of the ediff buffers have been modified, ask if changes
should be saved. Then quit ediff normally, without asking for
confirmation"
  (interactive)
  (ediff-barf-if-not-control-buffer)
  (let* ((buf-a ediff-buffer-A)
         (buf-b ediff-buffer-B)
         (buf-c ediff-buffer-C)
         (ctl-buf (current-buffer))
         (modified (remove-if-not 'buffer-modified-p
                                  (list buf-a buf-b buf-c))))
    (let ((save (if modified (yes-or-no-p "Save changes?")nil)))
      (loop for buf in modified do
            (progn
              (set-buffer buf)
              (if save
                  (save-buffer)
                (set-buffer-modified-p nil))))
      (set-buffer ctl-buf)
      (ediff-really-quit nil))))