Groovy menjalankan perintah shell

Groovy menambahkan executemetode Stringuntuk membuat mengeksekusi shell cukup mudah;

println "ls".execute().text

tetapi jika kesalahan terjadi, maka tidak ada output yang dihasilkan. Apakah ada cara mudah untuk mengeluarkan standard error dan standard out? (selain membuat banyak kode untuk; membuat dua utas untuk membaca kedua aliran input, kemudian menggunakan aliran induk untuk menunggu mereka selesai kemudian mengonversi string kembali ke teks?)

Akan menyenangkan memiliki sesuatu seperti;

 def x = shellDo("ls /tmp/NoFile")
 println "out: ${x.out} err:${x.err}"

Oke, selesaikan sendiri;

def sout = new StringBuilder(), serr = new StringBuilder()
def proc = 'ls /badDir'.execute()
proc.consumeProcessOutput(sout, serr)
proc.waitForOrKill(1000)
println "out> $sout err> $serr"

menampilkan:

out> err> ls: cannot access /badDir: No such file or directory

"ls".execute()mengembalikan Processobjek yang mengapa "ls".execute().textbekerja. Anda harus bisa membaca aliran kesalahan untuk menentukan apakah ada kesalahan.

Ada metode ekstra pada Processyang memungkinkan Anda untuk melewati StringBufferuntuk mengambil teks: consumeProcessErrorStream(StringBuffer error).

Contoh:

def proc = "ls".execute()
def b = new StringBuffer()
proc.consumeProcessErrorStream(b)

println proc.text
println b.toString()

// a wrapper closure around executing a string                                  
// can take either a string or a list of strings (for arguments with spaces)    
// prints all output, complains and halts on error                              
def runCommand = { strList ->
  assert ( strList instanceof String ||
           ( strList instanceof List && strList.each{ it instanceof String } ) \
)
  def proc = strList.execute()
  proc.in.eachLine { line -> println line }
  proc.out.close()
  proc.waitFor()

  print "[INFO] ( "
  if(strList instanceof List) {
    strList.each { print "${it} " }
  } else {
    print strList
  }
  println " )"

  if (proc.exitValue()) {
    println "gave the following error: "
    println "[ERROR] ${proc.getErrorStream()}"
  }
  assert !proc.exitValue()
}

Saya menemukan ini lebih idiomatis:

def proc = "ls foo.txt doesnotexist.txt".execute()
assert proc.in.text == "foo.txt\n"
assert proc.err.text == "ls: doesnotexist.txt: No such file or directory\n"

Seperti posting lain menyebutkan, ini memblokir panggilan, tetapi karena kami ingin bekerja dengan output, ini mungkin diperlukan.

Untuk menambahkan satu lagi informasi penting ke jawaban yang diberikan di atas -

Untuk suatu proses

def proc = command.execute();

selalu coba gunakan

def outputStream = new StringBuffer();
proc.waitForProcessOutput(outputStream, System.err)
//proc.waitForProcessOutput(System.out, System.err)

daripada

def output = proc.in.text;

untuk menangkap output setelah menjalankan perintah di groovy karena yang terakhir adalah panggilan pemblokiran ( SO pertanyaan karena alasan ).

def exec = { encoding, execPath, execStr, execCommands ->

def outputCatcher = new ByteArrayOutputStream()
def errorCatcher = new ByteArrayOutputStream()

def proc = execStr.execute(null, new File(execPath))
def inputCatcher = proc.outputStream

execCommands.each { cm ->
    inputCatcher.write(cm.getBytes(encoding))
    inputCatcher.flush()
}

proc.consumeProcessOutput(outputCatcher, errorCatcher)
proc.waitFor()

return [new String(outputCatcher.toByteArray(), encoding), new String(errorCatcher.toByteArray(), encoding)]

}

def out = exec("cp866", "C:\\Test", "cmd", ["cd..\n", "dir\n", "exit\n"])

println "OUT:\n" + out[0]
println "ERR:\n" + out[1]

command = "ls *"

def execute_state=sh(returnStdout: true, script: command)

tetapi jika perintah gagal proses akan berakhir