Mengatasi jalur absolut dari jalur relatif dan / atau nama file

Apakah ada cara dalam skrip kumpulan Windows untuk mengembalikan jalur absolut dari nilai yang berisi nama file dan / atau jalur relatif?

Diberikan:

"..\"
"..\somefile.txt"

Saya perlu path absolut relatif terhadap file batch.

Contoh:

• "somefile.txt" terletak di "C: \ Foo \"
• "test.bat" terletak di "C: \ Foo \ Bar".
• Pengguna membuka jendela perintah di "C: \ Foo" dan memanggil Bar\test.bat ..\somefile.txt
• Dalam file batch "C: \ Foo \ somefile.txt" akan berasal dari %1

Dalam file batch, seperti dalam program C standar, argumen 0 berisi path ke skrip yang sedang dieksekusi. Anda bisa menggunakan %~dp0untuk mendapatkan hanya bagian jalur dari argumen ke-0 (yang merupakan skrip saat ini) - jalur ini selalu merupakan jalur yang sepenuhnya memenuhi syarat.

Anda juga bisa mendapatkan lintasan yang memenuhi syarat penuh dari argumen pertama Anda dengan menggunakan %~f1, tetapi ini memberikan lintasan sesuai dengan direktori kerja saat ini, yang jelas bukan yang Anda inginkan.

Secara pribadi, saya sering menggunakan %~dp0%~1idiom dalam file batch saya, yang mengartikan argumen pertama relatif terhadap path dari batch yang dieksekusi. Itu memang memiliki kekurangan: gagal total jika argumen pertama sepenuhnya memenuhi syarat.

Jika Anda perlu mendukung jalur relatif dan absolut, Anda dapat menggunakan solusi Frédéric Ménez : untuk sementara mengubah direktori kerja saat ini.

Berikut adalah contoh yang akan menunjukkan masing-masing teknik ini:

@echo off
echo %%~dp0 is "%~dp0"
echo %%0 is "%0"
echo %%~dpnx0 is "%~dpnx0"
echo %%~f1 is "%~f1"
echo %%~dp0%%~1 is "%~dp0%~1"

rem Temporarily change the current working directory, to retrieve a full path 
rem   to the first parameter
pushd .
cd %~dp0
echo batch-relative %%~f1 is "%~f1"
popd

Jika Anda menyimpan ini sebagai c: \ temp \ example.bat dan jalankan dari c: \ Users \ Public as

c: \ Users \ Public> \ temp \ example.bat .. \ windows

... Anda akan mengamati output berikut:

%~dp0 is "C:\temp\"
%0 is "\temp\example.bat"
%~dpnx0 is "C:\temp\example.bat"
%~f1 is "C:\Users\windows"
%~dp0%~1 is "C:\temp\..\windows"
batch-relative %~f1 is "C:\Windows"

dokumentasi untuk set pengubah yang diizinkan pada argumen batch dapat ditemukan di sini: https://docs.microsoft.com/en-us/windows-server/administration/windows-commands/call

Saya menemukan kebutuhan serupa pagi ini: bagaimana mengubah jalur relatif menjadi jalur absolut di dalam skrip perintah Windows.

Berikut ini triknya:

@echo off

set REL_PATH=..\..\
set ABS_PATH=

rem // Save current directory and change to target directory
pushd %REL_PATH%

rem // Save value of CD variable (current directory)
set ABS_PATH=%CD%

rem // Restore original directory
popd

echo Relative path: %REL_PATH%
echo Maps to path: %ABS_PATH%

Sebagian besar jawaban ini tampak gila karena rumit dan sangat bermasalah, ini milik saya - ini berfungsi pada variabel lingkungan apa pun, tidak ada %CD%atau PUSHD/ POPD, atau for /fomong kosong - hanya fungsi batch lama. - Direktori & file bahkan tidak harus ada.

CALL :NORMALIZEPATH "..\..\..\foo\bar.txt"
SET BLAH=%RETVAL%

ECHO "%BLAH%"

:: ========== FUNCTIONS ==========
EXIT /B

:NORMALIZEPATH
  SET RETVAL=%~f1
  EXIT /B

Tanpa harus memiliki file batch lain untuk meneruskan argumen (dan menggunakan operator argumen), Anda dapat menggunakan FOR /F:

FOR /F %%i IN ("..\relativePath") DO echo absolute path: %%~fi

di mana iin %%~fiadalah variabel yang didefinisikan pada /F %%i. misalnya. jika Anda mengubahnya /F %%amaka bagian terakhir akan menjadi %%~fa.

Untuk melakukan hal yang sama di prompt perintah (dan bukan dalam file batch) ganti %%dengan %...

Ini untuk membantu mengisi kekosongan dalam jawaban Adrien Plisson (yang harus ditingkatkan segera setelah dia mengeditnya ;-):

Anda juga bisa mendapatkan jalur yang sepenuhnya memenuhi syarat dari argumen pertama Anda dengan menggunakan% ~ f1, tetapi ini memberikan jalur sesuai dengan jalur saat ini, yang jelas bukan yang Anda inginkan.

sayangnya, saya tidak tahu bagaimana cara mencampurkan keduanya ...

Seseorang dapat menangani %0dan %1juga:

• %~dpnx0untuk drive + path + nama + ekstensi + dari batchfile itu sendiri,
  %~f0juga cukup;
• %~dpnx1untuk drive + lintasan + nama + ekstensi sepenuhnya argumen pertama [jika itu nama file sama sekali],
  %~f1juga cukup;

%~f1akan bekerja terlepas dari bagaimana Anda menentukan argumen pertama Anda: dengan jalur relatif atau dengan jalur absolut (jika Anda tidak menentukan ekstensi file saat penamaan %1, itu tidak akan ditambahkan, bahkan jika Anda menggunakan %~dpnx1- namun.

Tapi bagaimana pula Anda memberi nama file pada drive yang berbeda jika Anda tidak akan memberikan info path lengkap pada commandline di tempat pertama?

Namun, %~p0, %~n0, %~nx0dan %~x0mungkin berguna, jika Anda tertarik pada jalan (tanpa hurufkandar), nama file (tanpa ekstensi), nama file penuh dengan ekstensi atau ekstensi nama file hanya. Tetapi perhatikan, saat %~p1dan %~n1akan bekerja untuk mengetahui jalur atau nama argumen pertama, %~nx1dan %~x1tidak akan menambahkan + menunjukkan ekstensi, kecuali Anda sudah menggunakannya pada commandline.

Anda juga dapat menggunakan fungsi batch untuk ini:

@echo off
setlocal 

goto MAIN
::-----------------------------------------------
:: "%~f2" get abs path of %~2. 
::"%~fs2" get abs path with short names of %~2.
:setAbsPath
  setlocal
  set __absPath=%~f2
  endlocal && set %1=%__absPath%
  goto :eof
::-----------------------------------------------

:MAIN
call :setAbsPath ABS_PATH ..\
echo %ABS_PATH%

endlocal

Perbaikan kecil untuk solusi hebat BrainSlugs83 . Umum untuk memungkinkan penamaan variabel lingkungan keluaran dalam panggilan.

@echo off
setlocal EnableDelayedExpansion

rem Example input value.
set RelativePath=doc\build

rem Resolve path.
call :ResolvePath AbsolutePath %RelativePath%

rem Output result.
echo %AbsolutePath%

rem End.
exit /b

rem === Functions ===

rem Resolve path to absolute.
rem Param 1: Name of output variable.
rem Param 2: Path to resolve.
rem Return: Resolved absolute path.
:ResolvePath
    set %1=%~dpfn2
    exit /b

Jika dijalankan dari C:\projectoutput adalah:

C:\project\doc\build

Saya belum melihat banyak solusi untuk masalah ini. Beberapa solusi memanfaatkan traversal direktori menggunakan CD dan lainnya menggunakan fungsi batch. Preferensi pribadi saya adalah untuk fungsi batch dan khususnya, fungsi MakeAbsolute yang disediakan oleh DosTips.

Fungsi ini memiliki beberapa manfaat nyata, terutama karena tidak mengubah direktori kerja Anda saat ini dan kedua bahwa jalur yang dievaluasi bahkan tidak harus ada. Anda dapat menemukan beberapa kiat bermanfaat tentang cara menggunakan fungsi di sini juga.

Berikut ini contoh skrip dan hasilnya:

@echo off

set scriptpath=%~dp0
set siblingfile=sibling.bat
set siblingfolder=sibling\
set fnwsfolder=folder name with spaces\
set descendantfolder=sibling\descendant\
set ancestorfolder=..\..\
set cousinfolder=..\uncle\cousin

call:MakeAbsolute siblingfile      "%scriptpath%"
call:MakeAbsolute siblingfolder    "%scriptpath%"
call:MakeAbsolute fnwsfolder       "%scriptpath%"
call:MakeAbsolute descendantfolder "%scriptpath%"
call:MakeAbsolute ancestorfolder   "%scriptpath%"
call:MakeAbsolute cousinfolder     "%scriptpath%"

echo scriptpath:       %scriptpath%
echo siblingfile:      %siblingfile%
echo siblingfolder:    %siblingfolder%
echo fnwsfolder:       %fnwsfolder%
echo descendantfolder: %descendantfolder%
echo ancestorfolder:   %ancestorfolder%
echo cousinfolder:     %cousinfolder%
GOTO:EOF

::----------------------------------------------------------------------------------
:: Function declarations
:: Handy to read http://www.dostips.com/DtTutoFunctions.php for how dos functions
:: work.
::----------------------------------------------------------------------------------
:MakeAbsolute file base -- makes a file name absolute considering a base path
::                      -- file [in,out] - variable with file name to be converted, or file name itself for result in stdout
::                      -- base [in,opt] - base path, leave blank for current directory
:$created 20060101 :$changed 20080219 :$categories Path
:$source http://www.dostips.com
SETLOCAL ENABLEDELAYEDEXPANSION
set "src=%~1"
if defined %1 set "src=!%~1!"
set "bas=%~2"
if not defined bas set "bas=%cd%"
for /f "tokens=*" %%a in ("%bas%.\%src%") do set "src=%%~fa"
( ENDLOCAL & REM RETURN VALUES
    IF defined %1 (SET %~1=%src%) ELSE ECHO.%src%
)
EXIT /b

Dan hasilnya:

C:\Users\dayneo\Documents>myscript
scriptpath:       C:\Users\dayneo\Documents\
siblingfile:      C:\Users\dayneo\Documents\sibling.bat
siblingfolder:    C:\Users\dayneo\Documents\sibling\
fnwsfolder:       C:\Users\dayneo\Documents\folder name with spaces\
descendantfolder: C:\Users\dayneo\Documents\sibling\descendant\
ancestorfolder:   C:\Users\
cousinfolder:     C:\Users\dayneo\uncle\cousin

Saya harap ini membantu ... Ini tentu membantu saya :) PS Terima kasih lagi untuk DosTips! Kamu keren!

Anda bisa menggabungkannya.

SET ABS_PATH=%~dp0 
SET REL_PATH=..\SomeFile.txt
SET COMBINED_PATH=%ABS_PATH%%REL_PATH%

itu terlihat aneh dengan \ .. \ di tengah jalan Anda tetapi berfungsi. Tidak perlu melakukan hal-hal gila :)

Dalam contoh Anda, dari Bar \ test.bat, DIR / B / S .. \ somefile.txt akan mengembalikan path lengkap.

PowerShell sangat umum hari ini, jadi saya sering menggunakannya sebagai cara cepat untuk memanggil C # karena itu memiliki fungsi untuk hampir semua:

@echo off
set pathToResolve=%~dp0\..\SomeFile.txt
for /f "delims=" %%a in ('powershell -Command "[System.IO.Path]::GetFullPath( '%projectDirMc%' )"') do @set resolvedPath=%%a

echo Resolved path: %resolvedPath%

Agak lambat, tetapi fungsi yang didapat sulit dikalahkan kecuali tanpa menggunakan bahasa skrip yang sebenarnya.

solusi stijn bekerja dengan subfolder di bawah C:\Program Files (86)\,

@echo off
set projectDirMc=test.txt

for /f "delims=" %%a in ('powershell -Command "[System.IO.Path]::GetFullPath( '%projectDirMc%' )"') do @set resolvedPath=%%a

echo full path:    %resolvedPath%

File Lihat semua jawaban lain

Direktori

Dengan ..menjadi jalur relatif Anda, dan dengan asumsi Anda saat ini berada di D:\Projects\EditorProject:

cd .. & cd & cd EditorProject (jalur relatif)

mengembalikan jalur absolut misalnya

D:\Projects

SET CD=%~DP0

SET REL_PATH=%CD%..\..\build\

call :ABSOLUTE_PATH    ABS_PATH   %REL_PATH%

ECHO %REL_PATH%

ECHO %ABS_PATH%

pause

exit /b

:ABSOLUTE_PATH

SET %1=%~f2

exit /b