Mengalihkan Output dari dalam file Batch

Saya membuat file batch dengan beberapa perintah sederhana untuk mengumpulkan informasi dari sistem. File batch berisi perintah untuk mendapatkan waktu, informasi IP, pengguna, dll.

Saya mengumpulkan semua perintah dalam file batch, dan itu berjalan, tetapi saya ingin file batch, ketika dijalankan untuk menampilkan hasilnya ke file teks (log). Apakah ada perintah yang dapat saya tambahkan ke batch yang akan melakukannya?

Perlu diingat bahwa saya tidak ingin menjalankan batch dari cmd, lalu alihkan keluaran; Saya ingin mengarahkan output dari dalam batch, jika memungkinkan.

Cara naif sederhana yang lambat karena membuka dan memposisikan penunjuk file ke End-Of-File beberapa kali.

@echo off
command1 >output.txt
command2 >>output.txt
...
commandN >>output.txt

Cara yang lebih baik - lebih mudah untuk menulis, dan lebih cepat karena file dibuka dan diposisikan hanya sekali.

@echo off
>output.txt (
  command1
  command2
  ...
  commandN
)

Cara lain yang baik dan cepat yang hanya membuka dan memposisikan file sekali

@echo off
call :sub >output.txt
exit /b

:sub
command1
command2
...
commandN

Sunting 2020-04-17

Sesekali Anda mungkin ingin berulang kali menulis ke dua file atau lebih. Anda mungkin juga menginginkan pesan yang berbeda di layar. Masih mungkin untuk melakukan ini secara efisien dengan mengarahkan ke tuas yang tidak ditentukan di luar blok atau subrutin yang diberi tanda kurung, lalu menggunakan &notasi untuk mereferensikan file yang sudah dibuka.

call :sub 9>File1.txt 8>File2.txt
exit /b

:sub
echo Screen message 1
>&9 File 1 message 1
>&8 File 2 message 1
echo Screen message 2
>&9 File 1 message 2
>&8 File 2 message 2
exit /b

Saya memilih untuk menggunakan pegangan 9 dan 8 dalam urutan terbalik karena cara itu lebih cenderung menghindari potensi pengalihan permanen karena cacat desain implementasi pengalihan Microsoft saat melakukan beberapa pengalihan pada perintah yang sama. Ini sangat tidak mungkin, tetapi bahkan pendekatan itu dapat mengekspos bug jika Anda berusaha cukup keras. Jika Anda melakukan pengalihan daripada Anda dijamin akan terhindar dari masalah.

3>File1.txt ( 4>File2.txt call :sub)
exit /b

:sub
etc.

jika Anda ingin aliran keluar dan aliran yang salah dialihkan

dir >> a.txt 2>&1

Saya tahu ini adalah posting yang lebih lama, tetapi seseorang akan menemukannya di pencarian Google dan sepertinya beberapa pertanyaan yang diajukan OP dalam komentar tidak ditangani secara khusus. Juga, mohon tenanglah karena ini adalah jawaban pertama saya yang diposting di SO. :)

Untuk mengarahkan output ke file menggunakan nama file yang dibuat secara dinamis, pendekatan masuk saya (baca: cepat & kotor) adalah solusi kedua yang ditawarkan oleh @dbenham. Jadi contohnya, ini:

@echo off
> filename_prefix-%DATE:~-4%-%DATE:~4,2%-%DATE:~7,2%_%time:~0,2%%time:~3,2%%time:~6,2%.log (
echo Your Name Here
echo Beginning Date/Time: %DATE:~-4%-%DATE:~4,2%-%DATE:~7,2%_%time:~0,2%%time:~3,2%%time:~6,2%.log
REM do some stuff here
echo Your Name Here
echo Ending Date/Time: %DATE:~-4%-%DATE:~4,2%-%DATE:~7,2%_%time:~0,2%%time:~3,2%%time:~6,2%.log
)

Akan membuat file seperti yang Anda lihat di tangkapan layar ini dari file di direktori target

Itu akan berisi keluaran ini:

Your Name Here
Beginning Date/Time: 2016-09-16_141048.log
Your Name Here
Ending Date/Time: 2016-09-16_141048.log

Juga perlu diingat bahwa solusi ini bergantung pada lokal, jadi berhati-hatilah bagaimana / kapan Anda menggunakannya.

echo some output >"your logfile"

atau

(
 echo some output
 echo more output
)>"Your logfile"

harus mengisi tagihan.

Jika Anda ingin APPENDoutput, menggunakan >>bukan >. >akan memulai logfile baru.

@echo off
>output.txt (
echo Checking your system infor, Please wating...

systeminfo | findstr /c:"Host Name" 
systeminfo | findstr /c:"Domain"

ipconfig /all | find "Physical Address" 

ipconfig | find "IPv4" 
ipconfig | find "Default Gateway"

)

@pause

Ada program kecil keren yang dapat Anda gunakan untuk mengarahkan output ke file dan konsol

some_command  ^|  TEE.BAT  [ -a ]  filename 

@ECHO OFF
:: Check Windows version
IF NOT "%OS%"=="Windows_NT" GOTO Syntax

:: Keep variables local
SETLOCAL

:: Check command line arguments
SET Append=0
IF /I [%1]==[-a] (
	SET Append=1
	SHIFT
)
IF     [%1]==[] GOTO Syntax
IF NOT [%2]==[] GOTO Syntax

:: Test for invalid wildcards
SET Counter=0
FOR /F %%A IN ('DIR /A /B %1 2^>NUL') DO CALL :Count "%%~fA"
IF %Counter% GTR 1 (
	SET Counter=
	GOTO Syntax
)

:: A valid filename seems to have been specified
SET File=%1

:: Check if a directory with the specified name exists
DIR /AD %File% >NUL 2>NUL
IF NOT ERRORLEVEL 1 (
	SET File=
	GOTO Syntax
)

:: Specify /Y switch for Windows 2000 / XP COPY command
SET Y=
VER | FIND "Windows NT" > NUL
IF ERRORLEVEL 1 SET Y=/Y

:: Flush existing file or create new one if -a wasn't specified
IF %Append%==0 (COPY %Y% NUL %File% > NUL 2>&1)

:: Actual TEE
FOR /F "tokens=1* delims=]" %%A IN ('FIND /N /V ""') DO (
	>  CON    ECHO.%%B
	>> %File% ECHO.%%B
)

:: Done
ENDLOCAL
GOTO:EOF

:Count
SET /A Counter += 1
SET File=%1
GOTO:EOF

:Syntax
ECHO.
ECHO Tee.bat,  Version 2.11a for Windows NT 4 / 2000 / XP
ECHO Display text on screen and redirect it to a file simultaneously
ECHO.
IF NOT "%OS%"=="Windows_NT" ECHO Usage:  some_command  ³  TEE.BAT  [ -a ]  filename
IF NOT "%OS%"=="Windows_NT" GOTO Skip
ECHO Usage:  some_command  ^|  TEE.BAT  [ -a ]  filename
:Skip
ECHO.
ECHO Where:  "some_command" is the command whose output should be redirected
ECHO         "filename"     is the file the output should be redirected to
ECHO         -a             appends the output of the command to the file,
ECHO                        rather than overwriting the file
ECHO.
ECHO Written by Rob van der Woude
ECHO http://www.robvanderwoude.com
ECHO Modified by Kees Couprie
ECHO http://kees.couprie.org
ECHO and Andrew Cameron

Tambahkan dua baris ini di dekat bagian atas file batch Anda, semua stdout dan stderr setelahnya akan diarahkan ke log.txt:

if not "%1"=="STDOUT_TO_FILE"  %0 STDOUT_TO_FILE %*  >log.txt 2>&1
shift /1

@echo OFF
[your command] >> [Your log file name].txt

Saya menggunakan perintah di atas dalam file batch saya dan berhasil. Di file log, ini menunjukkan hasil dari perintah saya.

Ini mungkin gagal dalam kasus karakter "beracun" dalam masukan. Mempertimbangkan masukan seperti iniIsAnIn ^^^^ adalah cara yang baik untuk memahami apa yang sedang terjadi. Tentu ada aturan bahwa string input HARUS berada di dalam tanda kutip ganda tetapi saya merasa bahwa aturan ini adalah aturan yang valid hanya jika arti inputnya adalah lokasi di partisi NTFS (mungkin itu adalah aturan untuk URL I saya tidak yakin). Tetapi tentu saja ini bukan aturan untuk string masukan yang berubah-ubah (ini adalah "praktik yang baik" tetapi Anda tidak dapat menghitungnya).

Menambahkan baris berikut di bagian bawah file batch Anda akan mengambil semuanya seperti yang ditampilkan di dalam jendela CMD dan mengekspor ke file teks:

powershell -c "$wshell = New-Object -ComObject wscript.shell; $wshell.SendKeys('^a')
powershell -c "$wshell = New-Object -ComObject wscript.shell; $wshell.SendKeys('^c')
powershell Get-Clipboard > MyLog.txt

Ini pada dasarnya melakukan pilih semua -> salin ke clipboard -> tempel ke file teks .