Saya telah menambahkan notepad++.exevariabel Path in Environment saya.

Sekarang di command prompt, notepad++.exe filename.txtbuka filename.txt. Tapi saya ingin lakukan hanya np filename.txtuntuk membuka file.

Saya mencoba menggunakan DOSKEY np=notepad++. Tapi itu hanya membawa ke depan notepad yang sudah dibuka ++ tanpa membuka file. Bagaimana saya bisa membuatnya membuka file?

Terima kasih.

Untuk menambah jawaban josh,

Anda dapat membuat alias tetap dengan langkah-langkah berikut,

1. Buat file .bat atau .cmd dengan DOSKEYperintah Anda .
2. Jalankan regedit dan buka HKEY_CURRENT_USER\Software\Microsoft\Command Processor

3. Tambahkan entri Nilai String dengan nama AutoRundan path lengkap file .bat / .cmd Anda.

   Misalnya, %USERPROFILE%\alias.cmdmengganti segmen awal jalur dengan %USERPROFILE%berguna untuk sinkronisasi antara beberapa mesin.

Dengan cara ini, setiap kali cmd dijalankan, alias dimuat.

Untuk Windows 10 , tambahkan entri HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Command Processorsebagai gantinya.

Untuk kelengkapan, berikut adalah templat untuk menggambarkan jenis alias yang mungkin berguna.

@echo off

:: Temporary system path at cmd startup

set PATH=%PATH%;"C:\Program Files\Sublime Text 2\"

:: Add to path by command

DOSKEY add_python26=set PATH=%PATH%;"C:\Python26\"
DOSKEY add_python33=set PATH=%PATH%;"C:\Python33\"

:: Commands

DOSKEY ls=dir /B
DOSKEY sublime=sublime_text $*  
    ::sublime_text.exe is name of the executable. By adding a temporary entry to system path, we don't have to write the whole directory anymore.
DOSKEY gsp="C:\Program Files (x86)\Sketchpad5\GSP505en.exe"
DOSKEY alias=notepad %USERPROFILE%\Dropbox\alias.cmd

:: Common directories

DOSKEY dropbox=cd "%USERPROFILE%\Dropbox\$*"
DOSKEY research=cd %USERPROFILE%\Dropbox\Research\

• Perhatikan bahwa $*sintaks berfungsi setelah string direktori dan juga executable yang mengambil argumen. Jadi dalam contoh di atas, perintah yang ditentukan pengguna dropbox researchmenunjuk ke direktori yang sama dengan research.
• Seperti yang ditunjukkan oleh Rivenfall, merupakan ide bagus untuk memasukkan perintah yang memungkinkan pengeditan alias.cmdfile yang nyaman. Lihat di aliasatas. Jika Anda berada di sesi cmd, masukkan cmduntuk me-restart cmd dan memuat kembali alias.cmdfile.

Ketika saya mencari di internet untuk jawaban atas pertanyaan itu, entah bagaimana diskusi itu berfokus pada ketekunan saja atau pada penggunaan DOSKEY saja. Saya harap seseorang akan mendapat manfaat dari dua aspek ini bersama di sini!

Berikut .regfile untuk membantu Anda menginstal alias.cmd. Sudah diatur sekarang sebagai contoh ke folder dropbox seperti yang disarankan di atas.

Windows Registry Editor Version 5.00

[HKEY_CURRENT_USER\Software\Microsoft\Command Processor]
"AutoRun"="%USERPROFILE%\\alias.cmd"

Untuk aplikasi pengguna tunggal, hal di atas akan dilakukan. Namun demikian, ada situasi di mana perlu untuk memeriksa apakah alias.cmdada terlebih dahulu di kunci registri. Lihat contoh di bawah ini.

Dalam C:\Users\Public\init.cmdfile hosting konfigurasi yang berpotensi lintas-pengguna:

@ECHO OFF
REM Add other configurations as needed
IF EXIST "%USERPROFILE%\alias.cmd" ( CALL "%USERPROFILE%\alias.cmd" )

Kunci registri harus diperbarui sesuai dengan C:\Users\Public\init.cmdatau, menggunakan .regfile:

Windows Registry Editor Version 5.00

[HKEY_CURRENT_USER\Software\Microsoft\Command Processor]
"AutoRun"="C:\\Users\\Public\\init.cmd"

Anda harus melewati parameter, coba ini:

doskey np=notepad++.exe $*

Sunting (menanggapi komentar Romonov) T: Apakah ada cara saya dapat membuat command prompt ingat jadi saya tidak harus menjalankan ini setiap kali saya membuka command prompt baru?

doskey adalah perintah teks yang ditafsirkan oleh pemroses perintah (mis. cmd.exe), ia tidak dapat mengubah keadaan dalam beberapa proses lain (terutama yang belum dimulai).

Orang-orang yang menggunakan doskeyuntuk mengatur lingkungan shell perintah awal mereka biasanya menggunakan /Kopsi (sering melalui jalan pintas) untuk menjalankan file batch yang melakukan semua pengaturan umum (seperti-mengatur judul jendela, warna, dll).

cmd.exe /K env.cmd

env.cmd:

title "Foo Bar"
doskey np=notepad++.exe $*
...

Jika Anda hanya menjalankan beberapa perintah sederhana, Anda dapat mengikuti langkah-langkah ini:

1. Buat folder bernama C: \ Alias
2. Tambahkan C: \ Alias ke jalur Anda (sehingga file di dalamnya akan ditemukan setiap saat)
3. Buat file .bat di C: \ Alias ​​untuk setiap alias yang Anda inginkan

Mungkin berlebihan, tetapi tidak seperti jawaban (jika tidak luar biasa) dari @Argyll, ini memecahkan masalah pemuatan ini setiap waktu.

Sebagai contoh, saya memiliki file bernama dig2.bat dengan yang berikut di dalamnya:

@echo off
echo.
dig +noall +answer %1

File np Anda hanya memiliki yang berikut ini:

@echo off
echo.
notepad++.exe %1

Kemudian cukup tambahkan folder C: \ Alias ke variabel lingkungan PATH Anda. Jika CMD atau PowerShell sudah dibuka, Anda harus memulai ulang.

FWIW, saya memiliki sekitar 20 alias (file .bat terpisah) di direktori C: \ Aliases - Saya hanya membuat yang baru seperlunya. Mungkin bukan yang paling rapi, tetapi berfungsi dengan baik.

UPDATE : Sesuai saran yang sangat baik dari pengguna @Mav, lebih baik menggunakan % * daripada % 1 , sehingga Anda dapat mengirimkan banyak file ke perintah, misalnya:

@echo off
echo.
notepad++.exe %*

Dengan begitu, Anda bisa melakukan ini:

np c:\temp\abc.txt c:\temp\def.txt c:\temp\ghi.txt

dan itu akan membuka semua 3 file.

Atau Anda dapat menggunakan cmderyang memungkinkan Anda menambahkan alias seperti linux:

alias subl="C:\Program Files\Sublime Text 3\subl.exe" $*

Mengingat Anda menambahkan notepad ++. Exe ke variabel PATH Anda, ini sangat sederhana. Buat file di folder System32 Anda dipanggil np.batdengan kode berikut:

@echo off
call notepad++.exe %*

The %*berlalu bersama semua argumen Anda memberikan npperintah ke notepad++.exeperintah.

EDIT: Anda akan memerlukan akses admin untuk menyimpan file ke folder System32, yang agak miring bagi saya. Saya baru saja membuat file di tempat lain dan memindahkannya ke System32 secara manual.

Anda juga dapat membuat alias.cmd di jalur Anda (misalnya C: \ Windows) dengan perintah

@echo %2 %3 %4 %5 %6 > %windir%\%1.cmd

Setelah Anda melakukannya, Anda dapat melakukan sesuatu seperti ini:

alias nameOfYourAlias commands to run 

Dan setelah itu Anda bisa mengetikkan baris comman

nameOfYourAlias 

ini akan mengeksekusi

commands to run 

TETAPI cara terbaik bagi saya hanyalah menambahkan jalur program.

setx PATH "%PATH%;%ProgramFiles%\Sublime Text 3" /M 

Dan sekarang saya menjalankan sublim sebagai

subl index.html

Alias ​​Konsol di Windows 10

Untuk menentukan alias konsol, gunakan Doskey.exeuntuk membuat makro, atau gunakan AddConsoleAliasfungsi.

doskey

doskey test=cd \a_very_long_path\test

Untuk juga menambahkan parameter tambahkan $*di akhir:doskey short=longname $*

AddConsoleAlias

AddConsoleAlias( TEXT("test"), 
                 TEXT("cd \\<a_very_long_path>\\test"), 
                 TEXT("cmd.exe"));

Informasi lebih lanjut di sini Konsol Alias , Doskey , Parameter

Anda ingin membuat alias hanya dengan mengetik:

c:\>alias kgs kubectl get svc

Created alias for kgs=kubectl get svc

Dan gunakan alias sebagai berikut:

c:\>kgs alfresco-svc

NAME           TYPE        CLUSTER-IP     EXTERNAL-IP   PORT(S)   AGE
alfresco-svc   ClusterIP   10.7.249.219   <none>        80/TCP    8d

Cukup tambahkan alias.batfile berikut ke path Anda. Ini hanya membuat file batch tambahan di direktori yang sama dengan dirinya sendiri.

  @echo off
  echo.
  for /f "tokens=1,* delims= " %%a in ("%*") do set ALL_BUT_FIRST=%%b
  echo @echo off > C:\Development\alias-script\%1.bat
  echo echo. >> C:\Development\alias-script\%1.bat
  echo %ALL_BUT_FIRST% %%* >> C:\Development\alias-script\%1.bat
  echo Created alias for %1=%ALL_BUT_FIRST%

Contoh file batch yang disebut kgs.batini adalah:

@echo off 
echo. 
kubectl get svc %* 

Sebenarnya, saya akan memberi Anda satu yang lebih baik dan memberi Anda teknik kecil yang telah saya gunakan sejak saya menggunakan program pada Amiga. Pada sistem baru apa pun yang Anda gunakan, baik itu pribadi atau profesional, langkah pertama adalah membuat dua folder: C:\BINdan C:\BATCH. Kemudian modifikasi pernyataan jalur Anda untuk menempatkan keduanya di awal dalam urutanC:\BATCH;C:\BIN;[rest of path] .

Setelah melakukan itu, jika Anda memiliki sedikit utilitas luar biasa yang Anda butuhkan akses untuk cukup menyalinnya ke C:\BINfolder dan mereka ada di jalur Anda. Untuk sementara menimpa tugas ini, Anda bisa menambahkan file batch dengan nama yang sama dengan yang dapat dieksekusi ke C:\BATCHfolder dan path akan menemukannya sebelum file di C: \ BIN. Itu harus mencakup apa pun yang mungkin perlu Anda lakukan.

Tentu saja, akhir-akhir ini cara kanonik yang benar untuk melakukan ini adalah dengan membuat persimpangan simbolis ke file, tetapi prinsip yang sama berlaku. Ada juga bonus tambahan tambahan. Jika Anda ingin memasukkan sesuatu ke dalam sistem yang konflik dengan sesuatu yang sudah di jalan, menempatkan dalam C:\BINatau C:\Batchfolder hanya akan mendahului asli - yang memungkinkan Anda untuk menimpa hal-hal baik sementara atau permanen, atau mengubah nama hal yang nama Anda lebih nyaman dengan - tanpa benar-benar mengubah aslinya.

Memperluas pada roryhewitt jawaban .

Keuntungan menggunakan file .cmd melalui DOSKEY adalah bahwa "alias" ini kemudian tersedia di shell lain seperti PowerShell atau WSL (subsistem Windows untuk Linux).

Satu-satunya gotcha dengan menggunakan perintah-perintah ini di bash adalah mungkin diperlukan sedikit lebih banyak pengaturan karena Anda mungkin perlu melakukan beberapa manipulasi jalur sebelum memanggil "alias" Anda.

misal saya punya vs.cmd yang merupakan "alias" saya untuk mengedit file di Visual Studio

@echo off
if [%1]==[] goto nofiles
start "" "c:\Program Files (x86)\Microsoft Visual Studio 
11.0\Common7\IDE\devenv.exe" /edit %1
goto end
:nofiles
start "" "C:\Program Files (x86)\Microsoft Visual Studio 
11.0\Common7\IDE\devenv.exe" "[PATH TO MY NORMAL SLN]"
:end

Yang menyala VS (dalam hal ini VS2012 - tetapi sesuaikan dengan selera) menggunakan proyek "normal" saya tanpa file yang diberikan tetapi ketika diberi file akan berusaha melampirkan ke VS yang sedang berjalan membuka file itu "dalam proyek itu" daripada memulai contoh baru VS.

Untuk menggunakan ini dari bash saya kemudian menambahkan tingkat tipuan ekstra karena "vs Myfile" tidak akan selalu berfungsi

alias vs='/usr/bin/run_visual_studio.sh'

Yang menyesuaikan jalur sebelum memanggil vs.cmd

#!/bin/bash
cmd.exe /C 'c:\Windows\System32\vs.cmd' "`wslpath.sh -w -r $1`"

Jadi cara ini bisa saya lakukan

vs SomeFile.txt

Baik di command prompt, Power Shell atau bash dan terbuka di Visual Studio saya yang sedang berjalan untuk diedit (yang hanya menyelamatkan otak saya yang malang karena harus berurusan dengan perintah VI atau semacamnya ketika saya baru saja mengedit dalam VS selama berjam-jam).

Solusi ini bukan solusi yang tepat, tetapi melayani tujuan dalam beberapa kesempatan.

Pertama buat folder dan tambahkan ke jalur sistem Anda. Pergi ke program apa pun yang ingin Anda buat alias dapat dieksekusi. Klik kanan dan kirim ke Desktop (Buat Pintasan). Ganti nama pintasan menjadi nama alias apa pun yang nyaman. Sekarang, ambil jalan pintas dan letakkan di folder Anda.

Dari jalankan prompt, Anda dapat mengetik nama pintasan secara langsung dan Anda dapat membuka program untuk Anda. Tetapi dari command prompt, Anda perlu menambahkan .lnk dan tekan enter, program akan dibuka.

Secara alami, saya tidak akan beristirahat sampai saya memiliki solusi yang paling nyaman. Menggabungkan begitu banyak jawaban dan topik di internet yang luas, inilah yang dapat Anda miliki.

• Memuat secara otomatis dengan setiap instance dari cmd
• Tidak memerlukan kata kunci DOSKEYuntuk alias

Perhatikan bahwa ini sebagian besar didasarkan pada jawaban dan komentar Argyll , pasti membacanya untuk memahami konsep-konsepnya.

Bagaimana itu bekerja?

1) membuat file makro dengan alias (atau file bat / cmd untuk juga menjalankan hal-hal lain)
2) mendaftarkannya di Registry untuk dijalankan pada setiap instance cmd
  - Anda juga dapat menjalankannya melalui pintasan hanya jika Anda mau

Itu saja

;==============================================================================
;= This file is registered via registry to auto load with each instance of cmd.
;================================ general info ================================
;= https://stackoverflow.com/a/59978163/985454  -  how to set it up?
;= https://gist.github.com/postcog/5c8c13f7f66330b493b8  -  example doskey macrofile
;========================= loading with cmd shortcut ==========================
;= create a cmd link with the following target :
;= %comspec% /k "(doskey /macrofile=%userprofile%\cmd\aliases.mac)"

alias=subl %USERPROFILE%\cmd\aliases.mac
hosts=runas /noprofile /savecred /user:QWERTY-XPS9370\administrator "subl C:\Windows\System32\drivers\etc\hosts" > NUL

ls=ls --color=auto $*
ll=ls -l --color=auto $*
la=ls -la --color=auto $*
grep=grep --color

~=cd %USERPROFILE%
cdr=cd c:\repos
cdd=cd c:\repos\dixons
cds=cd c:\repos\stekkie
cdu=cd c:\repos\uplus
cduo=cd c:\repos\uplus\oxbridge-fe
cdus=cd c:\repos\uplus\stratus

;============================= :end ============================
;= rem ******************************************************************
;= rem * EOF - Don't remove the following line.  It clears out the ';'
;= rem * macro. We're using it because there is no support for comments
;= rem * in a DOSKEY macro file.
;= rem ******************************************************************
;=

Sekarang Anda memiliki dua opsi:
a) daftar saja macrofile
b) gunakan biasacmd/bat file untuk juga menjalankan perintah sewenang-wenang.
Ganti nama yang Anda inginkan Autorun.

  Autorun    REG_SZ    doskey /macrofile=%userprofile%\cmd\aliases.mac
  Autorun_    REG_SZ    %USERPROFILE%\cmd\env.cmd

Windows Registry Editor Version 5.00
[HKEY_CURRENT_USER\Software\Microsoft\Command Processor]
"Autorun"="doskey /macrofile=%userprofile%\\cmd\\aliases.mac"
"Autorun_"="%USERPROFILE%\\cmd\\env.cmd"

:: This file is registered via registry to auto load with each instance of cmd.
:: https://stackoverflow.com/a/59978163/985454

@echo off
doskey /macrofile=%userprofile%\cmd\aliases.mac

:: put other commands here

Karena Anda sudah ada notepad++.exedi jalur Anda. Buat pintasan di folder yang bernama npdan arahkan ke notepad++.exe.

Pertama, Anda bisa membuat file bernama np.cmd dan meletakkannya di folder yang ada dalam daftar pencarian PATH. Kemudian, edit file np.cmd seperti di bawah ini:

@echo off
notepad++.exe

Jika Anda ingin mengaktifkan alias berdasarkan per-direktori / per-proyek , coba yang berikut ini:

1. Pertama, buat file batch yang akan mencari file bernama aliasesdi direktori saat ini dan inisialisasi alias dari itu, sebut sajamake-aliases.cmd

   @echo off
   if not exist aliases goto:eof
   echo [Loading aliases...]
   for /f "tokens=1* delims=^=" %%i in (aliases) do (
      echo   %%i ^<^=^> %%j
      doskey %%i=%%j
   )
   doskey aliases=doskey /macros
   echo   --------------------
   echo   aliases ^=^> list  all
   echo   alt+F10 ^=^> clear all
   echo [Done]
   

2. Lalu, buat di aliasesmana pun Anda membutuhkannya menggunakan format berikut:

   alias1 = command1
   alias2 = command2
   ...
   

   sebagai contoh:

   b = nmake
   c = nmake clean
   r = nmake rebuild
   

3. Kemudian, tambahkan lokasi make-aliases.cmdke %PATH%variabel Anda untuk membuatnya menjadi seluruh sistem atau hanya menyimpannya di tempat yang diketahui.

4. Buat itu mulai secara otomatis dengan cmd.

   • Saya pasti akan menyarankan untuk tidak menggunakan HKEY_CURRENT_USER\Software\Microsoft\Command Processor\AutoRunini, karena beberapa alat pengembangan akan memicu skrip autorun beberapa kali per sesi.

   • Jika Anda menggunakan ConEmu Anda bisa pergi dengan cara lain dan mulai script dari tugas startup ( Settings> Startup> Tasks), misalnya, saya membuat sebuah entri yang disebut {MSVC}:

     cmd.exe /k "vcvars64 && make-aliases",

     dan kemudian mendaftarkannya di menu konteks Explorer via Settings> Integration>with Command: {MSVC} -cur_console:n, sehingga sekarang saya dapat mengklik kanan folder dan meluncurkan prompt pengembang VS di dalamnya dengan aliasesmemuat saya secara otomatis, jika mereka berada di folder itu.

     Tanpa ConEmu, Anda mungkin hanya ingin membuat jalan pintas cmd.exedengan perintah yang sesuai atau cukup jalankan make-aliasessecara manual setiap waktu.

Jika Anda lupa alias, gunakan aliasesmakro, dan jika ada yang salah, setel ulang sesi saat ini dengan menekan Alt+ F10, yang merupakan perintah bawaan cmd.

Menggunakan doskey adalah cara yang tepat untuk melakukan ini, tetapi ini akan direset ketika jendela Command Prompt ditutup. Anda perlu menambahkan baris itu ke sesuatu seperti .bashrc equivalent. Jadi saya melakukan yang berikut:

1. Tambahkan "C: \ Program Files (x86) \ Notepad ++" ke variabel jalur sistem
2. Buat salinan notepad ++ .exe (di folder yang sama, tentu saja) dan ganti namanya menjadi np.exe

Bekerja dengan baik!