Bagaimana saya bisa melakukan pencarian string terbalik di Excel tanpa menggunakan VBA?

Saya memiliki spreadsheet Excel yang berisi daftar string. Setiap string terdiri dari beberapa kata, tetapi jumlah kata dalam setiap string berbeda.

Menggunakan fungsi Excel bawaan (tanpa VBA), apakah ada cara untuk mengisolasi kata terakhir di setiap string?

Contoh:

  Apakah Anda diklasifikasikan sebagai manusia? -> manusia?
Negatif, saya adalah es loli daging -> es loli
                  Aziz! Cahaya! -> Cahaya!

Yang ini sudah diuji dan bekerja (berdasarkan posting asli Brad):

=RIGHT(A1,LEN(A1)-FIND("|",SUBSTITUTE(A1," ","|",
     LEN(A1)-LEN(SUBSTITUTE(A1," ","")))))

Jika string asli Anda dapat berisi pipa "|" karakter, lalu ganti keduanya di atas dengan beberapa karakter lain yang tidak akan muncul di sumber Anda. (Saya menduga asli Brad rusak karena karakter yang tidak patut dihapus dalam terjemahan).

Bonus: Cara kerjanya (dari kanan ke kiri):

LEN(A1)-LEN(SUBSTITUTE(A1," ",""))- Hitungan spasi dalam string asli
SUBSTITUTE(A1," ","|", ... )- Mengganti hanya ruang akhir dengan a |
FIND("|", ... )- Menemukan posisi absolut dari yang diganti |(itu adalah ruang final)
Right(A1,LEN(A1) - ... ))- Mengembalikan semua karakter setelah itu|

EDIT: untuk menjelaskan kasus di mana teks sumber tidak mengandung spasi, tambahkan yang berikut ke awal rumus:

=IF(ISERROR(FIND(" ",A1)),A1, ... )

buat seluruh rumus sekarang:

=IF(ISERROR(FIND(" ",A1)),A1, RIGHT(A1,LEN(A1) - FIND("|",
    SUBSTITUTE(A1," ","|",LEN(A1)-LEN(SUBSTITUTE(A1," ",""))))))

Atau Anda dapat menggunakan =IF(COUNTIF(A1,"* *")sintaks versi lain.

Ketika string asli mungkin berisi spasi di posisi terakhir tambahkan fungsi trim sambil menghitung semua spasi: Jadikan fungsi sebagai berikut:

=IF(ISERROR(FIND(" ",B2)),B2, RIGHT(B2,LEN(B2) - FIND("|",
    SUBSTITUTE(B2," ","|",LEN(TRIM(B2))-LEN(SUBSTITUTE(B2," ",""))))))

Ini adalah teknik yang saya gunakan dengan sangat sukses:

=TRIM(RIGHT(SUBSTITUTE(A1, " ", REPT(" ", 100)), 100))

Untuk mendapatkan kata pertama dalam sebuah string, cukup ubah dari KANAN ke KIRI

=TRIM(LEFT(SUBSTITUTE(A1, " ", REPT(" ", 100)), 100))

Juga, ganti A1 dengan sel yang memegang teks.

Versi jawaban Jerry yang lebih kuat:

=TRIM(RIGHT(SUBSTITUTE(TRIM(A1), " ", REPT(" ", LEN(TRIM(A1)))), LEN(TRIM(A1))))

Itu bekerja terlepas dari panjang tali, ruang depan atau belakang, atau apa pun dan itu masih cukup pendek dan sederhana.

Saya menemukan ini di google, diuji di Excel 2003 & itu berfungsi untuk saya:

=IF(COUNTIF(A1,"* *"),RIGHT(A1,LEN(A1)-LOOKUP(LEN(A1),FIND(" ",A1,ROW(INDEX($A:$A,1,1):INDEX($A:$A,LEN(A1),1))))),A1)

[sunting] Saya tidak punya cukup perwakilan untuk berkomentar, jadi ini sepertinya tempat terbaik ... Jawaban BradC juga tidak bekerja dengan spasi tambahan atau sel kosong ...
[sunting ke-2] sebenarnya, itu tidak berfungsi untuk kata tunggal baik ...

=RIGHT(TRIM(A1),LEN(TRIM(A1))-FIND(CHAR(7),SUBSTITUTE(" "&TRIM(A1)," ",CHAR(7),
LEN(TRIM(A1))-LEN(SUBSTITUTE(" "&TRIM(A1)," ",""))+1))+1)

Ini sangat kuat - ini berfungsi untuk kalimat tanpa spasi, spasi awal / spasi, banyak spasi, banyak spasi depan / akhir ... dan saya menggunakan char (7) untuk pembatas daripada bilah vertikal "|" kalau-kalau itu adalah item teks yang diinginkan.

Ini sangat bersih dan ringkas, dan berfungsi dengan baik.

{=RIGHT(A1,LEN(A1)-MAX(IF(MID(A1,ROW(1:999),1)=" ",ROW(1:999),0)))}

Itu tidak kesalahan jebakan tanpa spasi atau satu kata, tapi itu mudah ditambahkan.

Sunting:
Ini menangani spasi tambahan, kata tunggal, dan skenario sel kosong. Saya belum menemukan cara untuk memecahkannya.

{=RIGHT(TRIM(A1),LEN(TRIM(A1))-MAX(IF(MID(TRIM(A1),ROW($1:$999),1)=" ",ROW($1:$999),0)))}

=RIGHT(A1,LEN(A1)-FIND("`*`",SUBSTITUTE(A1," ","`*`",LEN(A1)-LEN(SUBSTITUTE(A1," ",""))))) 

Untuk menambah jawaban Jerry dan Joe, jika Anda ingin menemukan teks SEBELUM kata terakhir yang dapat Anda gunakan:

=TRIM(LEFT(SUBSTITUTE(TRIM(A1), " ", REPT(" ", LEN(TRIM(A1)))), LEN(SUBSTITUTE(TRIM(A1), " ", REPT(" ", LEN(TRIM(A1)))))-LEN(TRIM(A1))))

Dengan 'Kucing kecil saya' di A1 akan menghasilkan 'Kucing kecil saya' (di mana Joe dan Jerry akan memberikan 'kucing'

Dengan cara yang sama seperti Jerry dan Joe mengisolasi kata terakhir, ini kemudian hanya mendapatkan segalanya di sebelah kiri itu (kemudian memotongnya kembali)

Bayangkan string bisa dibalik. Maka itu sangat mudah. Alih-alih mengerjakan string:

"My little cat" (1)

kamu bekerja dengan

"tac elttil yM" (2)

Dengan =LEFT(A1;FIND(" ";A1)-1)dalam A2 Anda dapatkan "My"dengan (1) dan "tac"dengan (2), yang terbalik "cat", kata terakhir dalam (1).

Ada beberapa VBA di sekitar untuk membalikkan string. Saya lebih suka fungsi VBA publik ReverseString.

Instal di atas seperti yang dijelaskan. Kemudian dengan string Anda di A1, misalnya, "My little cat"dan fungsi ini di A2:

=ReverseString(LEFT(ReverseString(A1);IF(ISERROR(FIND(" ";A1));
  LEN(A1);(FIND(" ";ReverseString(A1))-1))))

Anda akan melihat "cat"di A2.

Metode di atas mengasumsikan bahwa kata-kata dipisahkan oleh kosong. The IFklausul bagi sel-sel yang mengandung kata-kata tunggal = tidak ada kekosongan dalam sel. Catatan: TRIMdan CLEANstring asli juga berguna. Pada prinsipnya itu membalik seluruh string dari A1 dan hanya menemukan kosong pertama dalam string terbalik yang di sebelah kata (terbalik) terakhir (yaitu, "tac "). LEFTmengambil kata ini dan pembalikan string lain menyusun kembali urutan asli kata ( " cat"). Pada -1akhir FINDpernyataan menghapus kosong.

Idenya adalah bahwa mudah untuk mengekstrak kata pertama (!) Dalam string dengan LEFTdan FINDmemasukkan kata pertama. Namun, untuk kata terakhir (!), RIGHTFungsinya adalah pilihan yang salah ketika Anda mencoba melakukan itu karena sayangnya FIND tidak memiliki bendera untuk arah yang Anda inginkan untuk menganalisis string Anda.

Oleh karena itu seluruh string dibalik. LEFTdan FINDbekerja seperti biasa tetapi string yang diekstraksi terbalik. Tapi itu bukan masalah besar setelah Anda tahu cara membalikkan string. ReverseStringPernyataan pertama dalam rumus melakukan pekerjaan ini.

=LEFT(A1,FIND(IF(
 ISERROR(
  FIND("_",A1)
 ),A1,RIGHT(A1,
  LEN(A1)-FIND("~",
   SUBSTITUTE(A1,"_","~",
    LEN(A1)-LEN(SUBSTITUTE(A1,"_",""))
   )
  )
 )
),A1,1)-2)

Salin ke dalam kolom, pilih kolom itu dan HOME> Editing> Temukan & Pilih, Ganti:

Replace All.

Ada spasi setelah tanda bintang.

Saya menerjemahkan ke PT-BR, karena saya juga membutuhkannya.

(Harap dicatat bahwa saya telah mengubah spasi menjadi \karena saya hanya memerlukan nama file dari string path.)

=SE(ÉERRO(PROCURAR("\",A1)),A1,DIREITA(A1,NÚM.CARACT(A1)-PROCURAR("|", SUBSTITUIR(A1,"\","|",NÚM.CARACT(A1)-NÚM.CARACT(SUBSTITUIR(A1,"\",""))))))

Cara lain untuk mencapai ini adalah seperti di bawah ini

=IF(ISERROR(TRIM(MID(TRIM(D14),SEARCH("|",SUBSTITUTE(TRIM(D14)," ","|",LEN(TRIM(D14))-LEN(SUBSTITUTE(TRIM(D14)," ","")))),LEN(TRIM(D14))))),TRIM(D14),TRIM(MID(TRIM(D14),SEARCH("|",SUBSTITUTE(TRIM(D14)," ","|",LEN(TRIM(D14))-LEN(SUBSTITUTE(TRIM(D14)," ","")))),LEN(TRIM(D14)))))

Saya juga punya tugas seperti ini dan ketika saya selesai, menggunakan metode di atas, metode baru terjadi pada saya: Mengapa Anda tidak melakukan ini:

1. Balikkan string ("string one" menjadi "eno gnirts").
2. Gunakan Find lama yang baik (yang hardcoded untuk kiri-ke-kanan).
3. Balikkan menjadi string yang dapat dibaca lagi.

Bagaimana ini terdengar?