Mengurungkan perintah dalam vim

Vim adalah editor teks pilihan saya ketika saya memprogram, dan karena itu saya selalu mengalami masalah yang sangat mengganggu.

Seringkali, ketika saya dengan cepat perlu menyimpan buffer dan melanjutkan ke tugas lain-lain, saya melakukan yang khas

:w

Namun, saya - yang sepertinya lebih dari 50% dari waktu - selalu berhasil memanfaatkannya :w. Tentu saja, vim meneriaki saya karena Witu perintah yang tidak valid

E492: Not an editor command: W

Pertanyaan saya adalah bagaimana bisa satu alias perintah-usus di vim . Terutama, bisa Anda contoh bagaimana alias Wuntuk w.

Saya menyadari proses memetakan kunci ke perintah tertentu . Sayangnya, bukan itu yang saya cari.

Agar penyelesaian tidak tersentuh, coba gunakan

cnoreabbrev W w

, itu akan menggantikan Wdalam baris perintah dengan w, tetapi hanya jika itu tidak diikuti atau didahului oleh karakter kata, jadi :W<CR>akan diganti dengan :w<CR>, tetapi :Writetidak akan. (Perhatikan bahwa ini memengaruhi perintah yang cocok termasuk yang tidak Anda harapkan, misalnya perintah :saveas W Zakan diganti :saveas w Z, jadi berhati-hatilah dengan ini.)

Memperbarui

Inilah cara saya akan menulisnya sekarang :

cnoreabbrev <expr> W ((getcmdtype() is# ':' && getcmdline() is# 'W')?('w'):('W'))

Sebagai fungsi:

fun! SetupCommandAlias(from, to)
  exec 'cnoreabbrev <expr> '.a:from
        \ .' ((getcmdtype() is# ":" && getcmdline() is# "'.a:from.'")'
        \ .'? ("'.a:to.'") : ("'.a:from.'"))'
endfun
call SetupCommandAlias("W","w")

Ini memeriksa apakah tipe perintahnya :dan perintahnya W, jadi lebih aman dari pada adil cnoreabbrev W w.

Dengan mencari tambahan, saya telah menemukan bahwa seseorang bertanya hampir sama pertanyaan sebagai I.

:command <AliasName> <string of command to be aliased>

akan melakukan trik.

Perlu diketahui bahwa, seperti yang ditunjukkan Richo , perintah pengguna harus dimulai dengan huruf kapital.

Saya menemukan bahwa memetakan ;kunci untuk :menjadi solusi yang lebih baik, dan akan membuat Anda lebih produktif untuk mengetik perintah lain.

nnoremap ; :
vnoremap ; :

Solusi terbaik melibatkan penulisan fungsi khusus untuk menangani singkatan yang hanya terjadi di awal bilah perintah.

Untuk ini, tambahkan berikut ini file vimrc Anda atau di mana pun.

" cabs - less stupidity                                                      {{{
fu! Single_quote(str)
  return "'" . substitute(copy(a:str), "'", "''", 'g') . "'"
endfu
fu! Cabbrev(key, value)
  exe printf('cabbrev <expr> %s (getcmdtype() == ":" && getcmdpos() <= %d) ? %s : %s',
    \ a:key, 1+len(a:key), Single_quote(a:value), Single_quote(a:key))
endfu
"}}}

" use this custom function for cabbrevations. This makes sure that they only
" apply in the beginning of a command. Else we might end up with stuff like
"   :%s/\vfoo/\v/\vbar/
" if we happen to move backwards in the pattern.

" For example:
call Cabbrev('W', 'w')

Beberapa singkatan yang berguna dari bahan sumber tempat saya menemukan barang ini:

call Cabbrev('/',   '/\v')
call Cabbrev('?',   '?\v')

call Cabbrev('s/',  's/\v')
call Cabbrev('%s/', '%s/\v')

call Cabbrev('s#',  's#\v')
call Cabbrev('%s#', '%s#\v')

call Cabbrev('s@',  's@\v')
call Cabbrev('%s@', '%s@\v')

call Cabbrev('s!',  's!\v')
call Cabbrev('%s!', '%s!\v')

call Cabbrev('s%',  's%\v')
call Cabbrev('%s%', '%s%\v')

call Cabbrev("'<,'>s/", "'<,'>s/\v")
call Cabbrev("'<,'>s#", "'<,'>s#\v")
call Cabbrev("'<,'>s@", "'<,'>s@\v")
call Cabbrev("'<,'>s!", "'<,'>s!\v")

Mungkin Anda ingin memetakan salah satu tombol fungsi Anda (F1..F12) ke: w? Kemudian masukkan ini ke .vimrc Anda:

noremap  <f1> :w<return>
inoremap <f1> <c-o>:w<return>

(ctrl-o dalam mode insert beralih sementara ke mode normal).

Misalkan Anda ingin menambahkan alias untuk perintah tabnew di gvim. Anda cukup mengetik perintah berikut di file .vimrc Anda (jika tidak di folder home daripada membuatnya)

cabbrev t tabnew

Paling aman dan termudah adalah plugin seperti cmdalias.vim atau pembaruan terbaru saya -alias vim yang memperhitungkannya

• kekosongan atau pengubah sebelumnya seperti :sil(ent)(!)atau :redi(r),
• pengubah rentang seperti '<,'>untuk pemilihan visual saat ini,
• melarikan diri karakter khusus seperti kutipan, dan
• periksa apakah alias yang dipilih adalah singkatan baris perintah yang valid.