Dapatkan daftar semua file dalam direktori (rekursif)

Saya mencoba untuk mendapatkan (bukan mencetak, itu mudah) daftar file di direktori dan sub direktorinya.

Saya sudah mencoba:

def folder = "C:\\DevEnv\\Projects\\Generic";
def baseDir = new File(folder);
files = baseDir.listFiles();

Saya hanya mendapatkan direktori. Saya juga sudah mencoba:

def files = [];

def processFileClosure = {
        println "working on ${it.canonicalPath}: "
        files.add (it.canonicalPath);
    }

baseDir.eachFileRecurse(FileType.FILES, processFileClosure);

Tapi "file" tidak dikenali dalam lingkup penutupan.

Bagaimana cara mendapatkan daftarnya?

Kode ini berfungsi untuk saya:

import groovy.io.FileType

def list = []

def dir = new File("path_to_parent_dir")
dir.eachFileRecurse (FileType.FILES) { file ->
  list << file
}

Setelah itu variabel daftar berisi semua file (java.io.File) dari direktori yang diberikan dan subdirektorinya:

list.each {
  println it.path
}

Versi yang lebih baru dari Groovy (1.7.2+) menawarkan ekstensi JDK agar lebih mudah menelusuri file dalam direktori, misalnya:

import static groovy.io.FileType.FILES
def dir = new File(".");
def files = [];
dir.traverse(type: FILES, maxDepth: 0) { files.add(it) };

Lihat juga [1] untuk contoh lainnya.

[1] http://mrhaki.blogspot.nl/2010/04/groovy-goodness-traversing-directory.html

Yang berikut ini berfungsi untuk saya di Gradle / Groovy untuk build.gradleproyek Android, tanpa harus mengimpor groovy.io.FileType(CATATAN: Subdirektori tidak berulang, tetapi ketika saya menemukan solusi ini, saya tidak lagi peduli tentang rekursi, jadi Anda juga tidak boleh):

FileCollection proGuardFileCollection = files { file('./proguard').listFiles() }
proGuardFileCollection.each {
    println "Proguard file located and processed: " + it
}

Inilah yang saya temukan untuk skrip build gradle:

task doLast {
    ext.FindFile = { list, curPath ->
        def files = file(curPath).listFiles().sort()

        files.each {  File file ->

            if (file.isFile()) {
                list << file
            }
            else {
                list << file  // If you want the directories in the list

                list = FindFile( list, file.path) 
            }
        }
        return list
    }

    def list = []
    def theFile = FindFile(list, "${project.projectDir}")

    list.each {
        println it.path
    }
}