Vim: Membuat direktori induk saat menyimpan

Jika saya memanggil vim foo/bar/somefiletetapi foo/barbelum ada, Vim menolak untuk menyimpan.

Saya tahu saya dapat beralih ke shell atau melakukan :!mkdir foo/bardari Vim tetapi saya malas :) Apakah ada cara untuk membuat Vim melakukan itu secara otomatis ketika itu menyimpan buffer?

augroup BWCCreateDir
    autocmd!
    autocmd BufWritePre * if expand("<afile>")!~#'^\w\+:/' && !isdirectory(expand("%:h")) | execute "silent! !mkdir -p ".shellescape(expand('%:h'), 1) | redraw! | endif
augroup END

Perhatikan kondisi: expand("<afile>")!~#'^\w\+:/'akan mencegah vim membuat direktori untuk file seperti ftp://*dan !isdirectoryakan mencegah panggilan mkdir yang mahal.

Perbarui : solusi yang lebih baik yang juga memeriksa buftype dan penggunaan yang tidak kosong mkdir():

function s:MkNonExDir(file, buf)
    if empty(getbufvar(a:buf, '&buftype')) && a:file!~#'\v^\w+\:\/'
        let dir=fnamemodify(a:file, ':h')
        if !isdirectory(dir)
            call mkdir(dir, 'p')
        endif
    endif
endfunction
augroup BWCCreateDir
    autocmd!
    autocmd BufWritePre * :call s:MkNonExDir(expand('<afile>'), +expand('<abuf>'))
augroup END

Berdasarkan saran untuk pertanyaan saya, inilah yang akhirnya saya dapatkan:

function WriteCreatingDirs()
    execute ':silent !mkdir -p %:h'
    write
endfunction
command W call WriteCreatingDirs()

Ini mendefinisikan :Wperintah. Idealnya, saya ingin memiliki semua :w!, :wq, :wq!, :walldll bekerja sama, tapi aku tidak yakin apakah itu mungkin tanpa dasarnya reimplementing mereka semua dengan fungsi kustom.

Saya menambahkan ini ke ~ / .vimrc saya

cnoremap mk. !mkdir -p <c-r>=expand("%:h")<cr>/

Jika saya perlu membuat direktori tempat saya berada, saya mengetik :mk.dan itu menggantikannya dengan "! Mkdir -p / path / to / my / file /" dan mengizinkan saya untuk meninjau perintah sebelum saya memanggilnya.

Saya :saveas!membuat direktori jika hilang: https://github.com/henrik/dotfiles/commit/54cc9474b345332cf54cf25b51ddb8a9bd00a0bb

Kode ini akan meminta Anda untuk membuat direktori dengan :w, atau lakukan saja dengan :w!:

augroup vimrc-auto-mkdir
  autocmd!
  autocmd BufWritePre * call s:auto_mkdir(expand('<afile>:p:h'), v:cmdbang)
  function! s:auto_mkdir(dir, force)
    if !isdirectory(a:dir)
          \   && (a:force
          \       || input("'" . a:dir . "' does not exist. Create? [y/N]") =~? '^y\%[es]$')
      call mkdir(iconv(a:dir, &encoding, &termencoding), 'p')
    endif
  endfunction
augroup END

Saya pikir saya berhasil melakukan ini dalam tiga baris, menggabungkan apa yang dikatakan orang lain tentang jawaban ini.

Ini sepertinya berhasil:

if has("autocmd")
  autocmd BufWritePre * :silent !mkdir -p %:p:h
end

Ia mencoba untuk membuat folder secara otomatis saat menyimpan buffer. Jika sesuatu yang buruk terjadi (yaitu masalah izin), itu hanya akan menutup dan membiarkan file menulis gagal.

Jika ada yang melihat kekurangan yang jelas, silakan kirim komentar. Saya tidak terlalu ahli dalam vimscript.

EDIT: Catatan berkat ZyX

• Ini tidak akan berfungsi jika folder Anda memiliki spasi di dalamnya (tampaknya mereka tidak di-escape dengan benar atau semacamnya)
• Atau jika Anda melakukan pseudo file.
• Atau jika Anda mencari vimrc Anda.
• Tapi nak, itu pendek.