Cara menyalin struktur direktori tetapi hanya menyertakan file tertentu (menggunakan file batch windows)

Seperti judulnya, bagaimana saya bisa menyalin struktur direktori secara rekursif tetapi hanya menyertakan beberapa file. Misalnya, diberikan struktur direktori berikut:

folder1
  folder2
    folder3
      data.zip
      info.txt
      abc.xyz
    folder4
    folder5
      data.zip
      somefile.exe
      someotherfile.dll

File data.zip dan info.txt dapat muncul di mana saja dalam struktur direktori. Bagaimana cara menyalin struktur direktori lengkap, tetapi hanya menyertakan file bernama data.zip dan info.txt (semua file lain harus diabaikan)?

Struktur direktori yang dihasilkan akan terlihat seperti ini:

copy_of_folder1
  folder2
    folder3
      data.zip
      info.txt
    folder4
    folder5
      data.zip

Anda tidak menyebutkan apakah itu harus batch saja, tetapi jika Anda bisa menggunakan ROBOCOPY, coba ini:

ROBOCOPY C:\Source C:\Destination data.zip info.txt /E

EDIT: Mengubah /Sparameter /Euntuk menyertakan folder kosong.

Solusi alternatif yang menyalin satu file pada satu waktu dan tidak memerlukan ROBOCOPY:

@echo off
setlocal enabledelayedexpansion

set "SOURCE_DIR=C:\Source"
set "DEST_DIR=C:\Destination"
set FILENAMES_TO_COPY=data.zip info.txt

for /R "%SOURCE_DIR%" %%F IN (%FILENAMES_TO_COPY%) do (
    if exist "%%F" (
        set FILE_DIR=%%~dpF
        set FILE_INTERMEDIATE_DIR=!FILE_DIR:%SOURCE_DIR%=!
        xcopy /E /I /Y "%%F" "%DEST_DIR%!FILE_INTERMEDIATE_DIR!"
    )
)

Pernyataan outer for menghasilkan kombinasi jalur yang mungkin dari subdirektori in SOURCE_DIRdan name in FILENAMES_TO_COPY. Untuk setiap file yang ada, xcopy dipanggil. FILE_INTERMEDIATE_DIRmemegang jalur subdirektori file yang di SOURCE_DIRdalamnya perlu dibuat DEST_DIR.

coba piping keluaran find (mis. path file) ke cpio

find . -type f -name '*.jpg' | cpio -p -d -v targetdir/

cpio memeriksa stempel waktu pada file target - jadi aman dan cepat.

hapus -v untuk operasi yang lebih cepat, setelah Anda terbiasa.

Jika Powershell adalah opsi, Anda dapat melakukan ini:

Copy-Item c:\sourcePath d:\destinationPath -filter data.zip -recurse

Kerugian utamanya adalah menyalin semua folder, bahkan jika folder itu akan kosong karena tidak ada file yang cocok dengan filter yang Anda tentukan. Jadi Anda bisa berakhir dengan pohon yang penuh dengan folder kosong, selain beberapa folder yang memiliki file yang Anda inginkan.

Terima kasih Untuk Jawaban Sebelumnya. :)

Skrip ini bernama "r4k4copy.cmd":

@echo off
for %%p in (SOURCE_DIR DEST_DIR FILENAMES_TO_COPY) do set %%p=
cls
echo :: Copy Files Including Folder Tree
echo :: http://stackoverflow.com
rem     /questions/472692/how-to-copy
rem     -a-directory-structure-but-only
rem     -include-certain-files-using-windows
echo :: ReScripted by r4k4
echo.
if "%1"=="" goto :NoParam
if "%2"=="" goto :NoParam
if "%3"=="" goto :NoParam
setlocal enabledelayedexpansion
set SOURCE_DIR=%1
set DEST_DIR=%2
set FILENAMES_TO_COPY=%3
for /R "%SOURCE_DIR%" %%F IN (%FILENAMES_TO_COPY%) do (
if exist "%%F" (
set FILE_DIR=%%~dpF
set FILE_INTERMEDIATE_DIR=!FILE_DIR:%SOURCE_DIR%=!
xcopy /E /I /Y "%%F" "%DEST_DIR%!FILE_INTERMEDIATE_DIR!"
)
)
goto :eof
:NoParam
echo.
echo Syntax: %0 [Source_DIR] [Dest_DIR] [FileName]
echo Eg.   : %0 D:\Root E:\Root\Lev1\Lev2\Lev3 *.JPG
echo Means : Copy *.JPG from D:\Root to E:\Root\Lev1\Lev2\Lev3

Ini menerima variabel "Sumber", "Tujuan", dan "Nama File". Itu juga hanya dapat menyalin jenis file tertentu atau nama file selektif.

Perbaikan apapun dipersilakan. :)

Dengan hanya temukan dan cp:

mkdir /tmp/targetdir
cd sourcedir
find . -type f -name '*.zip' -exec cp -p --parents {} /tmp/targetdir ";"
find . -type f -name '*.txt' -exec cp -p --parents {} /tmp/targetdir ";"

Mirip dengan solusi Paulius, tetapi file yang tidak Anda pedulikan tidak disalin kemudian dihapus:

@echo OFF

:: Replace c:\temp with the directory where folder1 resides.
cd c:\temp

:: You can make this more generic by passing in args for the source and destination folders.
for /f "usebackq" %%I in (`dir /b /s /a:-d folder1`) do @echo %%~nxI | find /V "data.zip" | find /v "info.txt" >> exclude_list.txt
xcopy folder1 copy_of_folder1 /EXCLUDE:exclude_list.txt /E /I

Untuk menyalin semua file teks ke G: dan mempertahankan struktur direktori:

xcopy *.txt /s G:

Itu hanya dua perintah sederhana, tetapi saya tidak akan merekomendasikan ini, kecuali file yang tidak perlu Anda salin berukuran kecil. Itu karena ini akan menyalin SEMUA file dan kemudian menghapus file yang tidak diperlukan di salinan.

xcopy /E /I folder1 copy_of_folder1
for /F "tokens=1 delims=" %i in ('dir /B /S /A:-D copy_of_files ^| find /V "info.txt" ^| find /V "data.zip"') do del /Q "%i"

Tentu, perintah kedua agak panjang, tetapi berhasil!

Selain itu, pendekatan ini tidak mengharuskan Anda mengunduh dan menginstal alat pihak ketiga (Windows 2000+ BATCH memiliki cukup perintah untuk ini).

Di Linux dan sistem UNIX lainnya, menggunakan tarperintah akan melakukan ini dengan mudah.

$ tar cvf /tmp/full-structure.tar *data.zip *info.txt

Kemudian Anda akan beralih ke target dan:

$ tar xvf /tmp/full-structure.tar 

Tentu saja Anda bisa menyalurkan output dari tar pertama ke tar ke-2, tetapi melihatnya bekerja dalam langkah-langkah lebih mudah untuk dipahami dan dijelaskan. Saya kehilangan cd / ke / new / path / yang diperlukan dalam perintah berikut - saya tidak ingat bagaimana melakukannya sekarang. Semoga orang lain dapat menambahkannya.

$ tar cvf -  *data.zip *info.txt |  tar xvf - 

Tar (gnutar) juga tersedia di Windows, tetapi saya mungkin akan menggunakan xcopymetode ini sendiri di platform itu.

XCOPY /S folder1\data.zip copy_of_folder1  
XCOPY /S folder1\info.txt copy_of_folder1

EDIT: Jika Anda ingin mempertahankan folder kosong (yang, saat membaca ulang posting Anda, sepertinya Anda) gunakan / E daripada / S.

Menggunakan antarmuka baris perintah WinRAR, Anda dapat menyalin nama file dan / atau jenis file ke arsip. Kemudian Anda dapat mengekstrak arsip itu ke lokasi mana pun yang Anda suka. Ini mempertahankan struktur file asli.

Saya perlu menambahkan file gambar album yang hilang ke ponsel saya tanpa harus menyalin ulang musik itu sendiri. Untungnya struktur direktori di komputer dan ponsel saya sama!

Saya menggunakan:

   rar a -r C:\Downloads\music.rar X:\music\Folder.jpg

• C: \ Downloads \ music.rar = Arsip yang akan dibuat
• X: \ music \ = Folder berisi file musik
• Folder.jpg = Nama file yang ingin saya salin

Ini membuat arsip dengan semua file Folder.jpg di subdirektori yang tepat.

Teknik ini juga dapat digunakan untuk menyalin jenis file. Jika semua file memiliki nama yang berbeda, Anda dapat memilih untuk mengekstrak semua file ke satu direktori. Parameter baris perintah tambahan dapat mengarsipkan beberapa jenis file.

Informasi lebih lanjut di tautan yang sangat membantu ini http://cects.com/using-the-winrar-command-line-tools-in-windows/

Bagi mereka yang menggunakan Altap Salamander (pengelola file 2 panel): dalam Opsi popup Salin, cukup tentukan nama file atau topeng. Mudah.

Saya baik-baik saja dengan ekspresi reguler, malas dan tidak suka menginstal, jadi saya membuat file batch yang membuat direktori dan menyalin dengan perintah vanilla DOS. Kelihatannya melelahkan tetapi lebih cepat bagi saya daripada mengerjakan robocopy.

1. Buat daftar file sumber Anda dengan jalur lengkap, termasuk huruf drive jika nec, dalam file teks.
2. Aktifkan ekspresi reguler di editor teks Anda.
3. Tambahkan tanda kutip ganda di setiap baris jika ada spasi - cari string (.*)ganti string "\1", dan klik ganti semua
4. Buat dua baris per file - satu untuk membuat direktori, satu untuk menyalin file (qqq akan diganti dengan jalur tujuan) - cari string (.*)ganti string md qqq\1\nxcopy \1 qqq\1\ndan klik ganti semua
5. Hapus nama file dari jalur tujuan - cari \\([^\\^"]+)"\nganti\\"\n
6. Ganti di jalur tujuan (dalam contoh ini A:\srcdan B:\dest). Matikan ekspresi reguler, cari qqq"A:\src\ganti B:\dest\dan klik ganti semua.

md akan membuat direktori bersarang. copy mungkin akan berperilaku identik dengan xcopy dalam contoh ini. Anda mungkin ingin menambahkan / Y ke xcopy untuk menyembunyikan konfirmasi penimpaan. Anda berakhir dengan file batch seperti ini:

md "B:\dest\a\b\c\"
xcopy "C:\src\a\b\c\e.xyz" "B:\dest\a\b\c\e.xyz"

diulang untuk setiap file dalam daftar asli Anda. Diuji di Win7.

Untuk melakukan ini dengan drag and drop menggunakan winzip ada opsi pelestarian struktur dir. Cukup buat .zip baru di tingkat direktori yang akan menjadi root Anda dan seret file.