Bagaimana cara mengatur ulang urutan di Oracle?

Di PostgreSQL , saya bisa melakukan sesuatu seperti ini:

ALTER SEQUENCE serial RESTART WITH 0;

Apakah ada yang setara dengan Oracle?

Berikut adalah prosedur yang baik untuk mengatur ulang urutan ke 0 dari guru Oracle Tom Kyte . Diskusi hebat tentang pro dan kontra di tautan di bawah juga.

tkyte@TKYTE901.US.ORACLE.COM> 
create or replace
procedure reset_seq( p_seq_name in varchar2 )
is
    l_val number;
begin
    execute immediate
    'select ' || p_seq_name || '.nextval from dual' INTO l_val;

    execute immediate
    'alter sequence ' || p_seq_name || ' increment by -' || l_val || 
                                                          ' minvalue 0';

    execute immediate
    'select ' || p_seq_name || '.nextval from dual' INTO l_val;

    execute immediate
    'alter sequence ' || p_seq_name || ' increment by 1 minvalue 0';
end;
/

Dari halaman ini: SQL dinamis untuk mereset nilai urutan
Diskusi lain yang bagus juga ada di sini: Bagaimana cara mereset urutan?

Restart yang benar tidak dimungkinkan AFAIK . (Tolong perbaiki saya jika saya salah!).

Namun, jika Anda ingin mengaturnya ke 0, Anda bisa menghapus dan membuatnya kembali.

Jika Anda ingin mengaturnya ke nilai tertentu, Anda dapat mengatur INCREMENT ke nilai negatif dan mendapatkan nilai berikutnya.

Artinya, jika urutan Anda adalah 500, Anda dapat mengaturnya ke 100 via

ALTER SEQUENCE serial INCREMENT BY -400;
SELECT serial.NEXTVAL FROM dual;
ALTER SEQUENCE serial INCREMENT BY 1;

Ini pendekatan saya:

1. jatuhkan urutan
2. buat ulang itu

Contoh:

--Drop sequence

DROP SEQUENCE MY_SEQ;

-- Create sequence 

create sequence MY_SEQ
minvalue 1
maxvalue 999999999999999999999
start with 1
increment by 1
cache 20;

alter sequence serial restart start with 1;

Fitur ini secara resmi ditambahkan dalam 18c tetapi secara tidak resmi tersedia dalam 12.1.

Bisa dibilang aman untuk menggunakan fitur tidak berdokumen ini di 12.1. Meskipun sintaks tidak termasuk dalam dokumentasi resmi , itu dihasilkan oleh paket Oracle DBMS_METADATA_DIFF . Saya sudah menggunakannya beberapa kali pada sistem produksi. Namun, saya membuat permintaan Layanan Oracle dan mereka memverifikasi bahwa itu bukan bug dokumentasi, fitur ini benar-benar tidak didukung.

Dalam 18c, fitur ini tidak muncul dalam Sintaks Bahasa SQL, tetapi termasuk dalam Panduan Administrator Database .

Pendekatan saya adalah ekstensi sangat kecil untuk contoh Dougman .

Ekstensi adalah ...

Masukkan nilai seed sebagai parameter. Mengapa? Saya suka memanggil hal yang mengatur ulang urutan kembali ke ID maks yang digunakan dalam beberapa tabel . Saya akhirnya memanggil proc ini dari skrip lain yang mengeksekusi beberapa panggilan untuk sejumlah sekuens, mengatur ulang nextval kembali ke tingkat yang cukup tinggi untuk tidak menyebabkan pelanggaran kunci utama di mana saya menggunakan nilai urutan untuk pengidentifikasi unik.

Ini juga menghormati nilai min sebelumnya . Bahkan mungkin mendorong nilai berikutnya semakin tinggi jika p_val yang diinginkan atau nilai minv yang ada lebih tinggi dari nilai saat ini atau dihitung berikutnya.

Yang terbaik dari semuanya, ini dapat dipanggil untuk mereset ke nilai yang ditentukan, dan tunggu saja sampai Anda melihat wrapper prosedur "perbaiki semua urutan saya" di bagian akhir.

create or replace
procedure Reset_Sequence( p_seq_name in varchar2, p_val in number default 0)
is
  l_current number := 0;
  l_difference number := 0;
  l_minvalue user_sequences.min_value%type := 0;

begin

  select min_value
  into l_minvalue
  from user_sequences
  where sequence_name = p_seq_name;

  execute immediate
  'select ' || p_seq_name || '.nextval from dual' INTO l_current;

  if p_Val < l_minvalue then
    l_difference := l_minvalue - l_current;
  else
    l_difference := p_Val - l_current;
  end if;

  if l_difference = 0 then
    return;
  end if;

  execute immediate
    'alter sequence ' || p_seq_name || ' increment by ' || l_difference || 
       ' minvalue ' || l_minvalue;

  execute immediate
    'select ' || p_seq_name || '.nextval from dual' INTO l_difference;

  execute immediate
    'alter sequence ' || p_seq_name || ' increment by 1 minvalue ' || l_minvalue;
end Reset_Sequence;

Prosedur itu berguna semua dengan sendirinya, tetapi sekarang mari kita tambahkan satu lagi yang memanggilnya dan menentukan semuanya secara terprogram dengan konvensi penamaan urutan dan mencari nilai maksimum yang digunakan dalam tabel / bidang yang ada ...

create or replace
procedure Reset_Sequence_to_Data(
  p_TableName varchar2,
  p_FieldName varchar2
)
is
  l_MaxUsed NUMBER;
BEGIN

  execute immediate
    'select coalesce(max(' || p_FieldName || '),0) from '|| p_TableName into l_MaxUsed;

  Reset_Sequence( p_TableName || '_' || p_Fieldname || '_SEQ', l_MaxUsed );

END Reset_Sequence_to_Data;

Sekarang kita memasak dengan gas!

Prosedur di atas akan memeriksa nilai maks bidang dalam tabel, membangun nama urutan dari pasangan tabel / bidang dan memanggil "Reset_Sequence" dengan nilai maks yang dirasakan.

Bagian terakhir dari teka-teki ini dan lapisan gula pada kue datang berikutnya ...

create or replace
procedure Reset_All_Sequences
is
BEGIN

  Reset_Sequence_to_Data( 'ACTIVITYLOG', 'LOGID' );
  Reset_Sequence_to_Data( 'JOBSTATE', 'JOBID' );
  Reset_Sequence_to_Data( 'BATCH', 'BATCHID' );

END Reset_All_Sequences;

Dalam database aktual saya, ada sekitar seratus urutan lainnya yang diatur ulang melalui mekanisme ini, jadi ada 97 panggilan lagi ke Reset_Sequence_to_Data dalam prosedur di atas.

Suka? Benci itu? Acuh tak acuh?

Script berikut mengatur urutan ke nilai yang diinginkan:

Diberikan urutan yang baru dibuat bernama PCS_PROJ_KEY_SEQ dan tabel PCS_PROJ:

BEGIN
   DECLARE
      PROJ_KEY_MAX       NUMBER := 0;
      PROJ_KEY_CURRVAL   NUMBER := 0;
   BEGIN

    SELECT MAX (PROJ_KEY) INTO PROJ_KEY_MAX FROM PCS_PROJ;
    EXECUTE IMMEDIATE 'ALTER SEQUENCE PCS_PROJ_KEY_SEQ INCREMENT BY ' || PROJ_KEY_MAX;
    SELECT PCS_PROJ_KEY_SEQ.NEXTVAL INTO PROJ_KEY_CURRVAL FROM DUAL;
    EXECUTE IMMEDIATE 'ALTER SEQUENCE PCS_PROJ_KEY_SEQ INCREMENT BY 1';

END;
END;
/

Prosedur tersimpan ini me-restart urutan saya:

Create or Replace Procedure Reset_Sequence  
  is
  SeqNbr Number;
begin
   /*  Reset Sequence 'seqXRef_RowID' to 0    */
   Execute Immediate 'Select seqXRef.nextval from dual ' Into SeqNbr;
   Execute Immediate 'Alter sequence  seqXRef increment by - ' || TO_CHAR(SeqNbr) ;
   Execute Immediate 'Select seqXRef.nextval from dual ' Into SeqNbr;
   Execute Immediate 'Alter sequence  seqXRef increment by 1';
END;

/

Ada cara lain untuk mengatur ulang urutan di Oracle: atur maxvaluedan cycleproperti. Ketika nextvalurutan mencapai maxvalue, jika cycleproperti diatur maka itu akan mulai lagi dariminvalue urutan.

Keuntungan dari metode ini dibandingkan dengan menetapkan negatif increment byadalah urutan dapat terus digunakan saat proses reset berjalan, mengurangi kemungkinan Anda perlu mengambil beberapa bentuk pemadaman untuk melakukan reset.

Nilai untuk maxvalueharus lebih besar dari arus nextval, jadi prosedur di bawah ini mencakup parameter opsional yang memungkinkan buffer jika urutan diakses lagi antara memilih nextvaldalam prosedur dan pengaturan cycleproperti.

create sequence s start with 1 increment by 1;

select s.nextval from dual
connect by level <= 20;

   NEXTVAL
----------
         1 
...
        20

create or replace procedure reset_sequence ( i_buffer in pls_integer default 0)
as
  maxval pls_integer;
begin

  maxval := s.nextval + greatest(i_buffer, 0); --ensure we don't go backwards!
  execute immediate 'alter sequence s cycle minvalue 0 maxvalue ' || maxval;
  maxval := s.nextval;
  execute immediate 'alter sequence s nocycle maxvalue 99999999999999';

end;
/
show errors

exec reset_sequence;

select s.nextval from dual;

   NEXTVAL
----------
         1 

Prosedur sebagai tegakan masih memungkinkan kemungkinan bahwa sesi lain akan mengambil nilai 0, yang mungkin atau mungkin tidak menjadi masalah bagi Anda. Jika ya, Anda selalu bisa:

• Atur minvalue 1di alter pertama
• Kecualikan nextvalpengambilan kedua
• Pindahkan pernyataan untuk mengatur nocycleproperti ke prosedur lain, untuk dijalankan di kemudian hari (dengan asumsi Anda ingin melakukan ini).

Jezus, semua pemrograman ini hanya untuk restart indeks ... Mungkin saya idiot, tetapi untuk pre-oracle 12 (yang memiliki fitur restart), apa yang salah dengan simpel:

drop sequence blah;
create sequence blah 

?

1) Misalkan Anda membuat URUTAN seperti yang ditunjukkan di bawah ini:

CREATE SEQUENCE TESTSEQ
INCREMENT BY 1
MINVALUE 1
MAXVALUE 500
NOCACHE
NOCYCLE
NOORDER

2) Sekarang Anda mengambil nilai dari SEQUENCE. Katakanlah saya telah mengambil empat kali seperti yang ditunjukkan di bawah ini.

SELECT TESTSEQ.NEXTVAL FROM dual
SELECT TESTSEQ.NEXTVAL FROM dual
SELECT TESTSEQ.NEXTVAL FROM dual
SELECT TESTSEQ.NEXTVAL FROM dual

3) Setelah mengeksekusi empat perintah di atas, nilai SEQUENCE akan menjadi 4. Sekarang anggap saya telah mereset nilai SEQUENCE ke 1 lagi. Ikuti langkah-langkah berikut. Ikuti semua langkah dalam urutan yang sama seperti yang ditunjukkan di bawah ini:

1. ALTER SEQUENCE TESTSEQ INCREMENT BY -3;
2. SELECT TESTSEQ.NEXTVAL FROM dual
3. ALTER SEQUENCE TESTSEQ INCREMENT BY 1;
4. SELECT TESTSEQ.NEXTVAL FROM dual

Mengubah nilai INCREMENT urutan, menambahnya, dan kemudian mengubahnya kembali sangat tidak menyakitkan, ditambah Anda memiliki manfaat tambahan karena tidak perlu membangun kembali semua hibah karena Anda ingin Anda menjatuhkan / menciptakan kembali urutan.

Saya membuat blok untuk mengatur ulang semua urutan saya:

DECLARE
    I_val number;
BEGIN
    FOR US IN
        (SELECT US.SEQUENCE_NAME FROM USER_SEQUENCES US)
    LOOP
        execute immediate 'select ' || US.SEQUENCE_NAME || '.nextval from dual' INTO l_val;
        execute immediate 'alter sequence ' || US.SEQUENCE_NAME || ' increment by -' || l_val || ' minvalue 0';
        execute immediate 'select ' || US.SEQUENCE_NAME || '.nextval from dual' INTO l_val;
        execute immediate 'alter sequence ' || US.SEQUENCE_NAME || ' increment by 1 minvalue 0';
    END LOOP;
END;

Berikut adalah prosedur yang lebih kuat untuk mengubah nilai berikutnya yang dikembalikan secara berurutan, ditambah lebih banyak lagi.

• Pertama melindungi terhadap serangan injeksi SQL karena tidak ada string yang dilewatkan digunakan untuk secara langsung membuat pernyataan SQL dinamis,
• Kedua itu mencegah nilai urutan berikutnya dari yang diatur di luar batas nilai urutan min atau maks. The next_valueakan! = min_valueDan antara min_valuedan max_value.
• Ketiga dibutuhkan pengaturan saat ini (atau yang diusulkan) increment_byserta semua pengaturan urutan lainnya saat membersihkan.
• Keempat semua parameter kecuali yang pertama adalah opsional dan kecuali ditentukan mengambil pengaturan urutan saat ini sebagai default. Jika tidak ada parameter opsional yang ditentukan, tidak ada tindakan yang diambil.
• Akhirnya jika Anda mencoba mengubah urutan yang tidak ada (atau tidak dimiliki oleh pengguna saat ini) itu akan menimbulkan ORA-01403: no data foundkesalahan.

Berikut kodenya:

CREATE OR REPLACE PROCEDURE alter_sequence(
    seq_name      user_sequences.sequence_name%TYPE
  , next_value    user_sequences.last_number%TYPE := null
  , increment_by  user_sequences.increment_by%TYPE := null
  , min_value     user_sequences.min_value%TYPE := null
  , max_value     user_sequences.max_value%TYPE := null
  , cycle_flag    user_sequences.cycle_flag%TYPE := null
  , cache_size    user_sequences.cache_size%TYPE := null
  , order_flag    user_sequences.order_flag%TYPE := null)
  AUTHID CURRENT_USER
AS
  l_seq user_sequences%rowtype;
  l_old_cache user_sequences.cache_size%TYPE;
  l_next user_sequences.min_value%TYPE;
BEGIN
  -- Get current sequence settings as defaults
  SELECT * INTO l_seq FROM user_sequences WHERE sequence_name = seq_name;

  -- Update target settings
  l_old_cache := l_seq.cache_size;
  l_seq.increment_by := nvl(increment_by, l_seq.increment_by);
  l_seq.min_value    := nvl(min_value, l_seq.min_value);
  l_seq.max_value    := nvl(max_value, l_seq.max_value);
  l_seq.cycle_flag   := nvl(cycle_flag, l_seq.cycle_flag);
  l_seq.cache_size   := nvl(cache_size, l_seq.cache_size);
  l_seq.order_flag   := nvl(order_flag, l_seq.order_flag);

  IF next_value is NOT NULL THEN
    -- Determine next value without exceeding limits
    l_next := LEAST(GREATEST(next_value, l_seq.min_value+1),l_seq.max_value);

    -- Grab the actual latest seq number
    EXECUTE IMMEDIATE
        'ALTER SEQUENCE '||l_seq.sequence_name
            || ' INCREMENT BY 1'
            || ' MINVALUE '||least(l_seq.min_value,l_seq.last_number-l_old_cache)
            || ' MAXVALUE '||greatest(l_seq.max_value,l_seq.last_number)
            || ' NOCACHE'
            || ' ORDER';
    EXECUTE IMMEDIATE 
      'SELECT '||l_seq.sequence_name||'.NEXTVAL FROM DUAL'
    INTO l_seq.last_number;

    l_next := l_next-l_seq.last_number-1;

    -- Reset the sequence number
    IF l_next <> 0 THEN
      EXECUTE IMMEDIATE 
        'ALTER SEQUENCE '||l_seq.sequence_name
            || ' INCREMENT BY '||l_next
            || ' MINVALUE '||least(l_seq.min_value,l_seq.last_number)
            || ' MAXVALUE '||greatest(l_seq.max_value,l_seq.last_number)
            || ' NOCACHE'
            || ' ORDER';
      EXECUTE IMMEDIATE 
        'SELECT '||l_seq.sequence_name||'.NEXTVAL FROM DUAL'
      INTO l_next;
    END IF;
  END IF;

  -- Prepare Sequence for next use.
  IF COALESCE( cycle_flag
             , next_value
             , increment_by
             , min_value
             , max_value
             , cache_size
             , order_flag) IS NOT NULL
  THEN
    EXECUTE IMMEDIATE 
      'ALTER SEQUENCE '||l_seq.sequence_name
          || ' INCREMENT BY '||l_seq.increment_by
          || ' MINVALUE '||l_seq.min_value
          || ' MAXVALUE '||l_seq.max_value
          || CASE l_seq.cycle_flag
             WHEN 'Y' THEN ' CYCLE' ELSE ' NOCYCLE' END
          || CASE l_seq.cache_size
             WHEN 0 THEN ' NOCACHE'
             ELSE ' CACHE '||l_seq.cache_size END
          || CASE l_seq.order_flag
             WHEN 'Y' THEN ' ORDER' ELSE ' NOORDER' END;
  END IF;
END;

Dalam proyek saya, sekali kebetulan seseorang memasukkan catatan secara manual tanpa menggunakan urutan, maka saya harus mengatur ulang nilai urutan secara manual, yang saya tulis di bawah potongan kode sql:

declare
max_db_value number(10,0);
cur_seq_value number(10,0);
counter number(10,0);
difference number(10,0);
dummy_number number(10);

begin

-- enter table name here
select max(id) into max_db_value from persons;
-- enter sequence name here
select last_number into cur_seq_value from user_sequences where  sequence_name = 'SEQ_PERSONS';

difference  := max_db_value - cur_seq_value;

 for counter in 1..difference
 loop
    -- change sequence name here as well
    select SEQ_PERSONS.nextval into dummy_number from dual;
 end loop;
end;

Harap dicatat, kode di atas akan berfungsi jika urutannya tertinggal.

Anda dapat menggunakan opsi CYCLE, yang ditunjukkan di bawah ini:

CREATE SEQUENCE test_seq
MINVALUE 0
MAXVALUE 100
START WITH 0
INCREMENT BY 1
CYCLE;

Dalam hal ini, ketika urutan mencapai MAXVALUE (100), itu akan didaur ulang ke MINVALUE (0).

Dalam kasus urutan yang dikurangi, urutan akan didaur ulang ke MAXVALUE.

Berikut cara membuat semua urutan peningkatan otomatis cocok dengan data aktual:

1. Buat prosedur untuk menegakkan nilai berikutnya seperti yang sudah dijelaskan di utas ini:

   CREATE OR REPLACE PROCEDURE Reset_Sequence(
       P_Seq_Name IN VARCHAR2,
       P_Val      IN NUMBER DEFAULT 0)
   IS
     L_Current    NUMBER                      := 0;
     L_Difference NUMBER                      := 0;
     L_Minvalue User_Sequences.Min_Value%Type := 0;
   BEGIN
     SELECT Min_Value
     INTO L_Minvalue
     FROM User_Sequences
     WHERE Sequence_Name = P_Seq_Name;
     EXECUTE Immediate 'select ' || P_Seq_Name || '.nextval from dual' INTO L_Current;
     IF P_Val        < L_Minvalue THEN
       L_Difference := L_Minvalue - L_Current;
     ELSE
       L_Difference := P_Val - L_Current;
     END IF;
     IF L_Difference = 0 THEN
       RETURN;
     END IF;
     EXECUTE Immediate 'alter sequence ' || P_Seq_Name || ' increment by ' || L_Difference || ' minvalue ' || L_Minvalue;
     EXECUTE Immediate 'select ' || P_Seq_Name || '.nextval from dual' INTO L_Difference;
     EXECUTE Immediate 'alter sequence ' || P_Seq_Name || ' increment by 1 minvalue ' || L_Minvalue;
   END Reset_Sequence;

2. Buat prosedur lain untuk merekonsiliasi semua urutan dengan konten aktual:

   CREATE OR REPLACE PROCEDURE RESET_USER_SEQUENCES_TO_DATA
   IS
     STMT CLOB;
   BEGIN
     SELECT 'select ''BEGIN'' || chr(10) || x || chr(10) || ''END;'' FROM (select listagg(x, chr(10)) within group (order by null) x FROM ('
       || X
       || '))'
     INTO STMT
     FROM
       (SELECT LISTAGG(X, ' union ') WITHIN GROUP (
       ORDER BY NULL) X
       FROM
         (SELECT CHR(10)
           || 'select ''Reset_Sequence('''''
           || SEQ_NAME
           || ''''','' || coalesce(max('
           || COL_NAME
           || '), 0) || '');'' x from '
           || TABLE_NAME X
         FROM
           (SELECT TABLE_NAME,
             REGEXP_SUBSTR(WTEXT, 'NEW\.(\S*) IS NULL',1,1,'i',1) COL_NAME,
             REGEXP_SUBSTR(BTEXT, '(\.|\s)([a-z_]*)\.nextval',1,1,'i',2) SEQ_NAME
           FROM USER_TRIGGERS
           LEFT JOIN
             (SELECT NAME BNAME,
               TEXT BTEXT
             FROM USER_SOURCE
             WHERE TYPE = 'TRIGGER'
             AND UPPER(TEXT) LIKE '%NEXTVAL%'
             )
           ON BNAME = TRIGGER_NAME
           LEFT JOIN
             (SELECT NAME WNAME,
               TEXT WTEXT
             FROM USER_SOURCE
             WHERE TYPE = 'TRIGGER'
             AND UPPER(TEXT) LIKE '%IS NULL%'
             )
           ON WNAME             = TRIGGER_NAME
           WHERE TRIGGER_TYPE   = 'BEFORE EACH ROW'
           AND TRIGGERING_EVENT = 'INSERT'
           )
         )
       ) ;
     EXECUTE IMMEDIATE STMT INTO STMT;
     --dbms_output.put_line(stmt);
     EXECUTE IMMEDIATE STMT;
   END RESET_USER_SEQUENCES_TO_DATA;

CATATAN:

1. Prosedur mengekstrak nama dari kode pemicu dan tidak bergantung pada konvensi penamaan
2. Untuk memeriksa kode yang dihasilkan sebelum eksekusi, alihkan komentar pada dua baris terakhir

Saya membuat alternatif bahwa pengguna tidak perlu tahu nilai-nilai, sistem dapatkan dan gunakan variabel untuk memperbarui.

--Atualizando sequence da tabela SIGA_TRANSACAO, pois está desatualizada
DECLARE
 actual_sequence_number INTEGER;
 max_number_from_table INTEGER;
 difference INTEGER;
BEGIN
 SELECT [nome_da_sequence].nextval INTO actual_sequence_number FROM DUAL;
 SELECT MAX([nome_da_coluna]) INTO max_number_from_table FROM [nome_da_tabela];
 SELECT (max_number_from_table-actual_sequence_number) INTO difference FROM DUAL;
IF difference > 0 then
 EXECUTE IMMEDIATE CONCAT('alter sequence [nome_da_sequence] increment by ', difference);
 --aqui ele puxa o próximo valor usando o incremento necessário
 SELECT [nome_da_sequence].nextval INTO actual_sequence_number from dual;
--aqui volta o incremento para 1, para que futuras inserções funcionem normalmente
 EXECUTE IMMEDIATE 'ALTER SEQUENCE [nome_da_sequence] INCREMENT by 1';
 DBMS_OUTPUT.put_line ('A sequence [nome_da_sequence] foi atualizada.');
ELSE
 DBMS_OUTPUT.put_line ('A sequence [nome_da_sequence] NÃO foi atualizada, já estava OK!');
END IF;
END;

Prosedur tersimpan yang berhasil untuk saya

create or replace
procedure reset_sequence( p_seq_name in varchar2, tablename in varchar2 )
is
    l_val number;
    maxvalueid number;
begin
    execute immediate 'select ' || p_seq_name || '.nextval from dual' INTO l_val;
    execute immediate 'select max(id) from ' || tablename INTO maxvalueid;
    execute immediate 'alter sequence ' || p_seq_name || ' increment by -' || l_val || ' minvalue 0';
    execute immediate 'select ' || p_seq_name || '.nextval from dual' INTO l_val;
    execute immediate 'alter sequence ' || p_seq_name || ' increment by '|| maxvalueid ||' minvalue 0';  
    execute immediate 'select ' || p_seq_name || '.nextval from dual' INTO l_val;
    execute immediate 'alter sequence ' || p_seq_name || ' increment by 1 minvalue 0';
end;

Cara menggunakan prosedur tersimpan:

execute reset_sequence('company_sequence','company');