Dim wkbkdestination As Workbook
Dim destsheet As Worksheet

For Each ThisWorkSheet In wkbkorigin.Worksheets 
    'this throws subscript out of range if there is not a sheet in the destination 
    'workbook that has the same name as the current sheet in the origin workbook.
    Set destsheet = wkbkdestination.Worksheets(ThisWorkSheet.Name) 
Next

Pada dasarnya saya mengulang semua lembar di buku kerja asal lalu mengatur destsheetdi buku kerja tujuan ke lembar dengan nama yang sama seperti yang saat ini diiterasi di buku kerja asal.

Bagaimana saya bisa menguji jika lembar itu ada? Sesuatu seperti:

If wkbkdestination.Worksheets(ThisWorkSheet.Name) Then 

Beberapa orang tidak menyukai pendekatan ini karena penggunaan penanganan kesalahan yang "tidak tepat", tetapi saya pikir itu dianggap dapat diterima di VBA ... Pendekatan alternatif adalah mengulang semua lembar sampai Anda menemukan kecocokan.

Function WorksheetExists(shtName As String, Optional wb As Workbook) As Boolean
    Dim sht As Worksheet

    If wb Is Nothing Then Set wb = ThisWorkbook
    On Error Resume Next
    Set sht = wb.Sheets(shtName)
    On Error GoTo 0
    WorksheetExists = Not sht Is Nothing
End Function

Jika Anda hanya tertarik pada lembar kerja, Anda dapat menggunakan panggilan Evaluasi sederhana:

Function WorksheetExists(sName As String) As Boolean
    WorksheetExists = Evaluate("ISREF('" & sName & "'!A1)")
End Function

Anda tidak perlu penanganan kesalahan untuk melakukannya. Yang harus Anda lakukan adalah mengulang semua Lembar Kerja dan memeriksa apakah nama yang ditentukan ada:

For i = 1 To Worksheets.Count
    If Worksheets(i).Name = "MySheet" Then
        exists = True
    End If
Next i

If Not exists Then
    Worksheets.Add.Name = "MySheet"
End If

Karena memeriksa anggota suatu koleksi adalah masalah umum, berikut adalah versi abstrak dari jawaban Tim:

Fungsi Berisi (objCollection Sebagai Objek, strName sebagai String) Sebagai Boolean
    Dim o sebagai Objek
    Pada Kesalahan Lanjutkan Berikutnya
    set o = objCollection (strName)
    Berisi = (Err.Number = 0)
    Err. Hapus
 Fungsi Akhir

Fungsi ini dapat digunakan dengan koleksi apapun seperti objek ( Shapes, Range, Names, Workbooks, dll).

Untuk memeriksa keberadaan sheet, gunakan If Contains(Sheets, "SheetName") ...

Diperbaiki: Tanpa penanganan kesalahan:

Function CheckIfSheetExists(SheetName As String) As Boolean
      CheckIfSheetExists = False
      For Each WS In Worksheets
        If SheetName = WS.name Then
          CheckIfSheetExists = True
          Exit Function
        End If
      Next WS
End Function

Jika ada yang ingin menghindari VBA dan menguji apakah lembar kerja hanya ada di dalam rumus sel, dimungkinkan menggunakan fungsi ISREFdan INDIRECT:

=ISREF(INDIRECT("SheetName!A1"))

Ini akan dikembalikan TRUEjika buku kerja berisi lembar yang disebut SheetNamedan FALSEsebaliknya.

Saya menulis yang ini:

Function sheetExist(sSheet As String) As Boolean
On Error Resume Next
sheetExist = (ActiveWorkbook.Sheets(sSheet).Index > 0)
End Function

Solusi saya sangat mirip dengan Tim tetapi juga berfungsi dalam kasus lembar non-lembar kerja - bagan

Public Function SheetExists(strSheetName As String, Optional wbWorkbook As Workbook) As Boolean
    If wbWorkbook Is Nothing Then Set wbWorkbook = ActiveWorkbook 'or ThisWorkbook - whichever appropriate
    Dim obj As Object
    On Error GoTo HandleError
    Set obj = wbWorkbook.Sheets(strSheetName)
    SheetExists = True
    Exit Function
HandleError:
    SheetExists = False
End Function

.

Letakkan tes dalam suatu fungsi dan Anda akan dapat menggunakannya kembali dan Anda memiliki keterbacaan kode yang lebih baik.

JANGAN gunakan "On Error Resume Next" karena dapat menimbulkan konflik dengan bagian lain dari kode Anda.

Sub DoesTheSheetExists()
    If SheetExist("SheetName") Then
        Debug.Print "The Sheet Exists"
    Else
        Debug.Print "The Sheet Does NOT Exists"
    End If
End Sub

Function SheetExist(strSheetName As String) As Boolean
    Dim i As Integer

    For i = 1 To Worksheets.Count
        If Worksheets(i).Name = strSheetName Then
            SheetExist = True
            Exit Function
        End If
    Next i
End Function

Bertahun-tahun terlambat, tetapi saya hanya perlu melakukan ini dan tidak menyukai solusi yang diposting ... Jadi saya membuat satu, semua berkat keajaiban (gerakan tangan pelangi SpongeBob) "Evaluasi ()"!

Evaluate("IsError(" & vSheetName & "!1:1)")

Mengembalikan TRUE jika Sheet TIDAK ada; SALAH jika sheet ADA. Anda dapat mengganti rentang apa pun yang Anda suka untuk "1: 1", tetapi saya menyarankan agar tidak menggunakan satu sel, karena jika mengandung kesalahan (misalnya, # N / A), itu akan mengembalikan True.

wsExistsFungsi kompak _{^{( tanpa bergantung pada Penanganan Kesalahan!)}}

Berikut adalah fungsi singkat & sederhana yang tidak bergantung pada penanganan kesalahan untuk menentukan apakah lembar kerja ada ( dan dinyatakan berfungsi dengan benar dalam situasi apa pun !)

Function wsExists(wsName As String) As Boolean
    Dim ws: For Each ws In Sheets
    wsExists = (wsName = ws.Name): If wsExists Then Exit Function
    Next ws
End Function

Contoh Penggunaan:

Contoh berikut menambahkan lembar kerja baru bernama myNewSheet, jika belum ada:

If Not wsExists("myNewSheet") Then Sheets.Add.Name = "myNewSheet"

Informasi Lebih Lanjut:

• MSDN: For Each… NextPernyataan (VBA)
• MSDN: ExitPernyataan (VBA)
• MSDN: Operator Perbandingan (VBA)

Mengapa tidak menggunakan loop kecil untuk menentukan apakah lembar kerja bernama ada? Katakanlah jika Anda sedang mencari Lembar Kerja bernama "Sheet1" di buku kerja yang saat ini dibuka.

Dim wb as Workbook
Dim ws as Worksheet

Set wb = ActiveWorkbook

For Each ws in wb.Worksheets

    if ws.Name = "Sheet1" then
        'Do something here
    End if

Next

Jika Anda adalah penggemar WorksheetFunction.atau Anda bekerja dari negara non-Inggris dengan Excel non-Inggris, ini adalah solusi yang baik, yang berhasil:

WorksheetFunction.IsErr(Evaluate("'" & wsName & "'!A1"))

Atau dalam fungsi seperti ini:

Function WorksheetExists(sName As String) As Boolean
    WorksheetExists = Not WorksheetFunction.IsErr(Evaluate("'" & sName & "'!A1"))
End Function

Public Function WorkSheetExists(ByVal strName As String) As Boolean
   On Error Resume Next
   WorkSheetExists = Not Worksheets(strName) Is Nothing
End Function

sub test_sheet()

 If Not WorkSheetExists("SheetName") Then
 MsgBox "Not available"
Else MsgBox "Available"
End If

End Sub

    For Each Sheet In Worksheets
    If UCase(Sheet.Name) = "TEMP" Then
    'Your Code when the match is True
        Application.DisplayAlerts = False
        Sheet.Delete
        Application.DisplayAlerts = True
    '-----------------------------------
    End If
Next Sheet

Ubah "Data" menjadi nama sheet apa pun yang Anda uji ...

On Error Resume Next 

Set DataSheet = Sheets("Data")

If DataSheet Is Nothing Then

     Sheets.Add(after:=ActiveSheet).Name = "Data"
     ''or whatever alternate code you want to execute''
End If

On Error GoTo 0

Tanpa ragu bahwa fungsi di atas dapat berfungsi, saya baru saja berakhir dengan kode berikut yang berfungsi dengan cukup baik:

Sub Sheet_exist ()
On Error Resume Next
If Sheets("" & Range("Sheet_Name") & "") Is Nothing Then
    MsgBox "doesnt exist"
Else
    MsgBox "exist"
End if
End sub

Catatan: Sheets_Nameadalah tempat saya meminta pengguna untuk memasukkan nama, jadi ini mungkin tidak sama untuk Anda.

Saya melakukan hal lain: hapus lembar hanya jika ada - tidak mendapatkan kesalahan jika tidak:

Excel.DisplayAlerts = False 
Dim WS
For Each WS In Excel.Worksheets
    If WS.name = "Sheet2" Then
        Excel.sheets("Sheet2").Delete
        Exit For
    End If
Next
Excel.DisplayAlerts = True

Saya menemukan cara mudah untuk melakukannya, tetapi saya tidak membuat sub baru untuk itu. Sebaliknya, saya hanya "memeriksa" di sub-sub yang sedang saya kerjakan. Dengan asumsi nama sheet yang kita cari adalah "Sheet_Exist" dan kita hanya ingin mengaktifkannya jika ditemukan:

Dim SheetCounter As Integer

SheetCounter = 1

Do Until Sheets(SheetCounter).Name = "Sheet_Exist" Or SheetCounter = Sheets.Count + 1
 SheetCounter = SheetCounter +1
Loop
If SheetCounter < Sheets.Count + 1 Then
 Sheets("Sheet_Exist").Activate
Else
 MsgBox("Worksheet ""Sheet_Exist"" was NOT found")
End If

Saya juga menambahkan pop-up ketika sheet tidak ada.

Saya tahu ini adalah posting lama, tetapi ini adalah solusi sederhana lain yang cepat.

Public Function worksheetExists(ByVal wb As Workbook, ByVal sheetNameStr As String) As Boolean

On Error Resume Next
worksheetExists = (wb.Worksheets(sheetNameStr).Name <> "")
Err.Clear: On Error GoTo 0

End Function

Pendek dan bersih:

Function IsSheet(n$) As Boolean
    IsSheet = Not IsError(Evaluate(n & "!a1"))
End Function

Saya sebenarnya memiliki cara sederhana untuk memeriksa apakah lembar itu ada dan kemudian menjalankan beberapa instruksi:

Dalam kasus saya, saya ingin menghapus sheet dan kemudian membuat ulang sheet yang sama dengan nama yang sama tetapi kode terputus jika program tidak dapat menghapus sheet karena sudah dihapus.

Sub Foo ()

    Application.DisplayAlerts = False

    On Error GoTo instructions
    Sheets("NAME OF THE SHEET").Delete

    instructions:

    Sheets.Add After:=Sheets(Sheets.Count)
    ActiveSheet.Name = "NAME OF THE SHEET"

End Sub