File batch. Hapus semua file dan folder dalam sebuah direktori

Saya ingin memiliki file batch yang akan menghapus semua folder dan file di folder cache saya untuk toolkit nirkabel saya.

Saat ini saya memiliki yang berikut:

cd "C:\Users\tbrollo\j2mewtk\2.5.2\appdb\RMS"
del *.db

Ini akan menghapus semua file .db di direktori RMS saya , namun saya ingin menghapus semuanya dari direktori ini. Bagaimana saya bisa melakukan ini?

del *.*bukannya del *.db. Itu akan menghapus semuanya.

Menggunakan:

• Buat file batch

• Salin teks di bawah ini ke dalam file batch

  set folder="C:\test"
  cd /d %folder%
  for /F "delims=" %%i in ('dir /b') do (rmdir "%%i" /s/q || del "%%i" /s/q)
  

Ini akan menghapus semua file dan folder.

IF EXIST "C:\Users\tbrollo\j2mewtk\2.5.2\appdb\RMS" (
    rmdir "C:\Users\tbrollo\j2mewtk\2.5.2\appdb\RMS" /s /q
)

Ini akan menghapus semuanya dari folder (dan folder itu sendiri).

del *.*hanya akan menghapus file, bukan subdirektori. Untuk memasukkan konten direktori, Anda dapat menggunakan skrip ini:

@echo off
setlocal enableextensions
if {%1}=={} goto :HELP
if {%1}=={/?} goto :HELP
goto :START

:HELP
echo Usage: %~n0 directory-name
echo.
echo Empties the contents of the specified directory,
echo WITHOUT CONFIRMATION. USE EXTREME CAUTION!
goto :DONE

:START
pushd %1 || goto :DONE
rd /q /s . 2> NUL
popd

:DONE
endlocal

The pushdperubahan ke direktori yang ingin Anda hapus anak-anak. Kemudian ketika rddiminta untuk menghapus direktori saat ini dan semua sub direktori, penghapusan sub direktori berhasil, tetapi penghapusan direktori saat ini gagal - karena kita berada di dalamnya. Ini menghasilkan kesalahan yang 2> NULmenelan. (2 adalah aliran kesalahan).

Saya baru saja mengumpulkan ini dari apa yang diposting morty346:

set folder="C:\test"
IF EXIST "%folder%" (
    cd /d %folder%
    for /F "delims=" %%i in ('dir /b') do (rmdir "%%i" /s/q || del "%%i" /s/q)
)

Ini menambahkan pemeriksaan cepat bahwa folder yang ditentukan dalam variabel ada terlebih dahulu, mengubah direktori ke folder, dan menghapus isinya.

Anda dapat melakukan ini dengan menggunakan deldan /Sbendera (untuk memberitahukannya untuk mengulang semua file dari semua subdirektori):

del /S C:\Path\to\directory\*

The RD Perintah ini juga dapat digunakan. Hapus secara berulang secara diam-diam tanpa perintah:

@RD /S /Q %VAR_PATH%

Rmdir (rd)

set "DIR_TO_DELETE=your_path_to_the_folder"

IF EXIST %DIR_TO_DELETE% (
    FOR /D %%p IN ("%DIR_TO_DELETE%\*.*") DO rmdir "%%p" /S /Q
    del %DIR_TO_DELETE%\*.* /F /Q
)

Coba yang berikut ini; itu berhasil untuk saya.

Saya memiliki aplikasi yang membuang data di folder "C: \ tmp" saya, dan berikut ini yang terbaik untuk saya. Ia bahkan tidak meminta Ya atau Tidak untuk menghapus data. Saya telah membuat jadwal untuk menjalankannya setiap 5 menit

cd "C:\tmp"

del *.* /Q

Menggunakan

set dir="Your Folder Path Here"
rmdir /s %dir%
mkdir %dir%

Versi ini menghapus tanpa bertanya:

set dir="Your Folder Here"
rmdir /s /q %dir%
mkdir %dir%

Contoh:

set dir="C:\foo1\foo\foo\foo3"
rmdir /s /q %dir%
mkdir %dir%

Ini akan jelas C:\foo1\foo\foo\foo3.

_{(Saya ingin menyebutkan jawaban Abdullah Sabouin ini . Ada mencampur tentang saya menyalin dirinya. Saya tidak melihat jabatannya. Saya ingin mengucapkan terima kasih Melpomene untuk menunjukkan kesalahan!)}

Lebih baik lagi, katakanlah saya ingin menghapus semua yang ada di bawah C:\windows\tempfolder.

@echo off
rd C:\windows\temp /s /q

Anda dapat menggunakan robocopy untuk mencerminkan folder kosong ke folder yang Anda hapus.

robocopy "C:\temp\empty" "C:\temp\target" /E /MIR

Ini juga berfungsi jika Anda tidak dapat menghapus atau membuat ulang folder sebenarnya.

Itu membutuhkan direktori kosong yang ada.

Anda tidak dapat menghapus semuanya dengan salah satu rmdiratau delsendiri:

• rmdir /s /qtidak menerima parameter karakter pengganti. Begitu rmdir /s /q *juga dengan kesalahan.
• del /s /f /q akan menghapus semua file, tetapi subdirektori kosong akan tetap ada.

Solusi pilihan saya (seperti yang telah saya gunakan di banyak file batch lainnya) adalah:

rmdir /s /q . 2>NUL

Hanya versi modifikasi dari jawaban GregM :

set folder="C:\test"
cd /D %folder%
if NOT %errorlevel% == 0 (exit /b 1)
echo Entire content of %cd% will be deleted. Press Ctrl-C to abort
pause

REM First the directories /ad option of dir
for /F "delims=" %%i in ('dir /b /ad') do (echo rmdir "%%i" /s/q)

REM Now the files /a-d option of dir
for /F "delims=" %%i in ('dir /b /a-d') do (echo del "%%i" /q)

REM To deactivate simulation mode remove the word 'echo' before 'rmdir' and 'del'.

@echo off
@color 0A

echo Deleting logs

rmdir /S/Q c:\log\

ping 1.1.1.1 -n 5 -w 1000 > nul

echo Adding log folder back

md c:\log\

Anda berada di jalur yang benar. Cukup tambahkan kode untuk menambahkan folder yang dihapus kembali.