CMake & CTest: membuat tes tidak membangun tes

Saya mencoba CTest di CMake untuk menjalankan beberapa pengujian saya secara otomatis menggunakan make testtarget. Masalahnya adalah CMake tidak "memahami" bahwa pengujian yang ingin saya jalankan harus dibuat karena ini adalah bagian dari proyek.

Jadi saya mencari cara untuk menentukan ketergantungan ini secara eksplisit.

Hal ini bisa dibilang sebuah bug di CMake (sebelumnya dilacak disini ) bahwa ini tidak bekerja di luar kotak. Solusinya adalah dengan melakukan hal berikut:

add_test(TestName ExeName)
add_custom_target(check COMMAND ${CMAKE_CTEST_COMMAND}
                  DEPENDS ExeName)

Kemudian Anda dapat menjalankan make checkdan itu akan mengkompilasi dan menjalankan pengujian. Jika Anda memiliki beberapa tes, maka Anda harus menggunakan DEPENDS exe1 exe2 exe3 ...baris di atas.

Sebenarnya ada cara untuk menggunakan make test. Anda perlu menentukan build pengujian yang dapat dieksekusi sebagai salah satu pengujian, lalu menambahkan dependensi di antara pengujian tersebut. Itu adalah:

ADD_TEST(ctest_build_test_code
         "${CMAKE_COMMAND}" --build ${CMAKE_BINARY_DIR} --target test_code)
ADD_TEST(ctest_run_test_code test_code)
SET_TESTS_PROPERTIES(ctest_run_test_code
                     PROPERTIES DEPENDS ctest_build_test_code)

Saya menggunakan varian jawaban richq. Di tingkat atas CMakeLists.txt, saya menambahkan target khusus build_and_test,, untuk membangun dan menjalankan semua pengujian:

find_package(GTest)
if (GTEST_FOUND)
    enable_testing()
    add_custom_target(build_and_test ${CMAKE_CTEST_COMMAND} -V)
    add_subdirectory(test)
endif()

Di berbagai CMakeLists.txtfile sub-proyek di bawah test/, saya menambahkan setiap pengujian yang dapat dieksekusi sebagai ketergantungan build_and_test:

include_directories(${CMAKE_SOURCE_DIR}/src/proj1)
include_directories(${GTEST_INCLUDE_DIRS})
add_executable(proj1_test proj1_test.cpp)
target_link_libraries(proj1_test ${GTEST_BOTH_LIBRARIES} pthread)
add_test(proj1_test proj1_test)
add_dependencies(build_and_test proj1_test)

Dengan pendekatan ini, saya hanya perlu make build_and_testdaripada make test(atau make all test), dan ini memiliki keuntungan hanya membangun kode pengujian (dan dependensinya). Sayang saya tidak bisa menggunakan nama target test. Dalam kasus saya, ini tidak terlalu buruk karena saya memiliki skrip tingkat atas yang melakukan debug dan rilis out-of-tree (dan dikompilasi silang) dengan memanggil cmakedan kemudian make, dan itu diterjemahkan testmenjadi build_and_test.

Jelas, hal-hal GTest tidak diperlukan. Saya kebetulan menggunakan / menyukai Google Test, dan ingin membagikan contoh lengkap cara menggunakannya dengan CMake / CTest. IMHO, pendekatan ini juga memiliki keuntungan karena memungkinkan saya untuk menggunakan ctest -V, yang menunjukkan keluaran Google Test saat pengujian berjalan:

1: Running main() from gtest_main.cc
1: [==========] Running 1 test from 1 test case.
1: [----------] Global test environment set-up.
1: [----------] 1 test from proj1
1: [ RUN      ] proj1.dummy
1: [       OK ] proj1.dummy (0 ms)
1: [----------] 1 test from proj1 (1 ms total)
1:
1: [----------] Global test environment tear-down
1: [==========] 1 test from 1 test case ran. (1 ms total)
1: [  PASSED  ] 1 test.
1/2 Test #1: proj1_test .......................   Passed    0.03 sec

Jika Anda mencoba meniru make check, Anda mungkin menemukan entri wiki ini berguna:

http://www.cmake.org/Wiki/CMakeEmulateMakeCheck

Saya baru saja memeriksa apakah apa yang dikatakannya berhasil (CMake 2.8.10).

Selamatkan diri Anda dari sakit kepala:

make all test

Berfungsi di luar kotak untuk saya dan akan membangun dependensi sebelum menjalankan pengujian. Mengingat betapa sederhananya ini, ini hampir membuat make testfungsionalitas asli menjadi nyaman karena memberi Anda opsi untuk menjalankan pengujian kompilasi terakhir bahkan jika kode Anda rusak.

Jika Anda menggunakan CMake> = 3.7, maka pendekatan yang disarankan adalah menggunakan perlengkapan :

add_executable(test test.cpp)
add_test(test_build
  "${CMAKE_COMMAND}"
  --build "${CMAKE_BINARY_DIR}"
  --config "$<CONFIG>"
  --target test
)
set_tests_properties(test_build PROPERTIES FIXTURES_SETUP    test_fixture)
add_test(test test)
set_tests_properties(test       PROPERTIES FIXTURES_REQUIRED test_fixture)

Ini melakukan hal berikut:

• Menambahkan testtarget yang dapat dieksekusi yang dibangun daritest.cpp
• Menambahkan test_build"test" yang menjalankan Cmake untuk membangun targettest
• Menandai test_buildtes sebagai tugas pengaturan perlengkapantest_fixture
• Tambahkan testpengujian yang hanya menjalankan testexecutable
• Tandai testujian untuk membutuhkan perlengkapan test_fixture.

Jadi, setiap kali pengujian testakan dijalankan, pengujian terlebih dahulu menjalankan pengujian test_build, yang membangun executable yang diperlukan.

Inilah yang saya pecahkan dan gunakan:

set(${PROJECT_NAME}_TESTS a b c)

enable_testing()
add_custom_target(all_tests)
foreach(test ${${PROJECT_NAME}_TESTS})
        add_executable(${test} EXCLUDE_FROM_ALL ${test}.cc)
        add_test(NAME ${test} COMMAND $<TARGET_FILE:${test}>)
        add_dependencies(all_tests ${test})
endforeach(test)

build_command(CTEST_CUSTOM_PRE_TEST TARGET all_tests)
string(CONFIGURE \"@CTEST_CUSTOM_PRE_TEST@\" CTEST_CUSTOM_PRE_TEST_QUOTED ESCAPE_QUOTES)
file(WRITE "${CMAKE_BINARY_DIR}/CTestCustom.cmake" "set(CTEST_CUSTOM_PRE_TEST ${CTEST_CUSTOM_PRE_TEST_QUOTED})" "\n")

YMMV

Jawaban Derrick, disederhanakan dan dikomentari:

# It is impossible to make target "test" depend on "all":
# https://gitlab.kitware.com/cmake/cmake/-/issues/8774
# Set a magic variable in a magic file that tells ctest
# to invoke the generator once before running the tests:
file(WRITE "${CMAKE_BINARY_DIR}/CTestCustom.cmake"
    "set(CTEST_CUSTOM_PRE_TEST ${CMAKE_MAKE_PROGRAM})\n"
)

Ini tidak sepenuhnya benar, karena tidak menyelesaikan masalah konkurensi saat berjalan ninja all test, jika ada yang melakukannya. Sebaliknya, karena sekarang, Anda memiliki dua proses ninja.

(Ftr, saya juga membagikan solusi ini di sini .)

Semua jawaban di atas sempurna. Tetapi sebenarnya CMake menggunakan CTest sebagai alat pengujiannya, jadi metode standar (menurut saya) untuk melakukan misi adalah:

enable_testing ()
add_test (TestName TestCommand)
add_test (TestName2 AnotherTestCommand)

Kemudian jalankan cmake dan buatlah untuk membangun target. Setelah itu, Anda dapat menjalankan uji make , atau hanya menjalankan

ctest

kamu akan mendapatkan hasilnya. Ini diuji di bawah CMake 2.8.

Periksa detailnya di: http://cmake.org/Wiki/CMake/Testing_With_CTest#Simple_Testing

Semua jawaban bagus, tetapi menyiratkan pelanggaran tradisi untuk menjalankan tes demi perintah make test. Saya telah melakukan trik ini:

add_test(NAME <mytest>
WORKING_DIRECTORY ${CMAKE_BINARY_DIR}
COMMAND sh -c "make <mytarget>; $<TARGET_FILE:<mytarget>>")

Ini berarti bahwa pengujian terdiri dari pembuatan (opsional) dan menjalankan target yang dapat dieksekusi.