Bagaimana cara saya membuat file batch berakhir setelah menemukan kesalahan?

Saya memiliki file batch yang memanggil executable yang sama berulang kali dengan parameter yang berbeda. Bagaimana cara saya membuatnya segera berakhir jika salah satu panggilan mengembalikan kode kesalahan dari tingkat apa pun?

Pada dasarnya, saya ingin yang setara dengan MSBuild ContinueOnError=false.

Periksa errorleveldalam sebuah ifpernyataan, dan kemudian exit /b(keluar b berkas atch saja, bukan seluruh proses cmd.exe) untuk nilai-nilai selain 0.

same-executable-over-and-over.exe /with different "parameters"
if %errorlevel% neq 0 exit /b %errorlevel%

Jika Anda ingin nilai tingkat kesalahan menyebar di luar file batch Anda

if %errorlevel% neq 0 exit /b %errorlevel%

tetapi jika ini di dalam foritu agak rumit. Anda akan membutuhkan sesuatu yang lebih seperti:

setlocal enabledelayedexpansion
for %%f in (C:\Windows\*) do (
    same-executable-over-and-over.exe /with different "parameters"
    if !errorlevel! neq 0 exit /b !errorlevel!
)

Sunting: Anda harus memeriksa kesalahan setelah setiap perintah. Tidak ada tipe konstruksi "on error goto" global dalam batch cmd.exe / command.com. Saya juga telah memperbarui kode saya per CodeMonkey , meskipun saya belum pernah menemukan tingkat kesalahan negatif dalam salah satu batch-hacking saya di XP atau Vista.

Tambahkan || goto :labelke setiap baris, lalu tentukan a :label.

Misalnya, buat file .cmd ini:

@echo off

echo Starting very complicated batch file...
ping -invalid-arg || goto :error
echo OH noes, this shouldn't have succeeded.
goto :EOF

:error
echo Failed with error #%errorlevel%.
exit /b %errorlevel%

Lihat juga pertanyaan tentang keluar dari subrutin file batch .

Yang paling pendek:

command || exit /b

Jika perlu, Anda dapat mengatur kode keluar:

command || exit /b 666

Dan Anda juga dapat login:

command || echo ERROR && exit /b

Satu pembaruan kecil, Anda harus mengubah pemeriksaan "jika tingkat kesalahan 1" menjadi yang berikut ...

IF %ERRORLEVEL% NEQ 0 

Ini karena pada XP Anda bisa mendapatkan angka negatif sebagai kesalahan. 0 = tidak ada masalah, yang lainnya adalah masalah.

Dan perlu diingat cara DOS menangani tes "JIKA ERRORLEVEL". Ini akan mengembalikan true jika nomor yang Anda periksa adalah angka itu atau lebih tinggi jadi jika Anda mencari nomor kesalahan tertentu Anda harus mulai dengan 255 dan menghitung.

Berikut adalah program polyglot untuk BASH dan Windows CMD yang menjalankan serangkaian perintah dan berhenti jika ada yang gagal:

#!/bin/bash 2> nul

:; set -o errexit
:; function goto() { return $?; }

command 1 || goto :error

command 2 || goto :error

command 3 || goto :error

:; exit 0
exit /b 0

:error
exit /b %errorlevel%

Saya telah menggunakan hal semacam ini di masa lalu untuk skrip integrasi berkelanjutan beberapa platform .

Saya lebih suka bentuk perintah ATAU, karena saya menemukan mereka yang paling mudah dibaca (sebagai lawan memiliki jika setelah setiap perintah). Namun, cara naif untuk melakukan hal ini, command || exit /b %ERRORLEVEL%adalah salah .

Ini karena batch memperluas variabel ketika sebuah baris pertama kali dibaca, bukan ketika mereka sedang digunakan. Ini berarti bahwa jika commanddalam baris di atas gagal, file batch keluar dengan benar, tetapi keluar dengan kode pengembalian 0, karena itulah nilai %ERRORLEVEL%pada awal baris. Jelas, ini tidak diinginkan dalam skrip kami, jadi kami harus mengaktifkan ekspansi yang tertunda , seperti:

SETLOCAL EnableDelayedExpansion

command-1 || exit /b !ERRORLEVEL!
command-2 || exit /b !ERRORLEVEL!
command-3 || exit /b !ERRORLEVEL!
command-4 || exit /b !ERRORLEVEL!

Cuplikan ini akan menjalankan perintah 1-4, dan jika salah satu dari mereka gagal, ia akan keluar dengan kode keluar yang sama seperti yang dilakukan oleh perintah yang gagal.

Kami tidak selalu dapat bergantung pada ERRORLEVEL, karena berkali-kali program eksternal atau skrip batch tidak mengembalikan kode keluar.

Dalam hal ini kita dapat menggunakan pemeriksaan umum untuk kegagalan seperti ini:

IF EXIST %outfile% (DEL /F %outfile%)
CALL some_script.bat -o %outfile%
IF NOT EXIST %outfile%  (ECHO ERROR & EXIT /b)

Dan jika program mengeluarkan sesuatu ke konsol, kita dapat memeriksanya juga.

some_program.exe 2>&1 | FIND "error message here" && (ECHO ERROR & EXIT /b)
some_program.exe 2>&1 | FIND "Done processing." || (ECHO ERROR & EXIT /b)

Tidak peduli bagaimana saya mencoba, tingkat kesalahan selalu tetap 0 bahkan ketika msbuild gagal. Jadi saya membangun solusi saya:

Bangun Proyek dan simpan log ke Build.log

SET Build_Opt=/flp:summary;logfile=Build.log;append=true

msbuild "myproj.csproj" /t:rebuild /p:Configuration=release /fl %Build_Opt%

cari string "0 Error" di build log, atur hasilnya ke var

FOR /F "tokens=* USEBACKQ" %%F IN (`find /c /i "0 Error" Build.log`) DO (
    SET var=%%F
)
echo %var%

dapatkan karakter terakhir, yang menunjukkan berapa banyak baris berisi string pencarian

set result=%var:~-1%

echo "%result%"

jika string tidak ditemukan, maka error> 0, build gagal

if "%result%"=="0" ( echo "build failed" )

Solusi itu terinspirasi oleh posting Mechaflash di Cara mengatur output perintah sebagai variabel dalam file batch

dan https://ss64.com/nt/syntax-substring.html

@echo off

set startbuild=%TIME%

C:\WINDOWS\Microsoft.NET\Framework\v3.5\msbuild.exe c:\link.xml /flp1:logfile=c:\link\errors.log;errorsonly /flp2:logfile=c:\link\warnings.log;warningsonly || goto :error

copy c:\app_offline.htm "\\lawpccnweb01\d$\websites\OperationsLinkWeb\app_offline.htm"

del \\lawpccnweb01\d$\websites\OperationsLinkWeb\bin\ /Q

echo Start Copy: %TIME%

set copystart=%TIME%

xcopy C:\link\_PublishedWebsites\OperationsLink \\lawpccnweb01\d$\websites\OperationsLinkWeb\ /s /y /d

del \\lawpccnweb01\d$\websites\OperationsLinkWeb\app_offline.htm

echo Started Build: %startbuild%
echo Started Copy: %copystart%
echo Finished Copy: %TIME%

c:\link\warnings.log

:error

c:\link\errors.log