Bagaimana cara mendapatkan hasil sp_executesql menjadi variabel?

Saya memiliki sepotong SQL dinamis yang perlu saya jalankan, saya kemudian perlu menyimpan hasilnya ke dalam variabel.

Saya tahu saya dapat menggunakan sp_executesqltetapi tidak dapat menemukan contoh yang jelas tentang bagaimana melakukan ini.

Jika Anda memiliki parameter OUTPUT yang dapat Anda lakukan

DECLARE @retval int   
DECLARE @sSQL nvarchar(500);
DECLARE @ParmDefinition nvarchar(500);

DECLARE @tablename nvarchar(50)  
SELECT @tablename = N'products'  

SELECT @sSQL = N'SELECT @retvalOUT = MAX(ID) FROM ' + @tablename;  
SET @ParmDefinition = N'@retvalOUT int OUTPUT';

EXEC sp_executesql @sSQL, @ParmDefinition, @retvalOUT=@retval OUTPUT;

SELECT @retval;

Tetapi jika tidak, dan tidak dapat memodifikasi SP:

-- Assuming that your SP return 1 value
create table #temptable (ID int null)
insert into #temptable exec mysp 'Value1', 'Value2'
select * from #temptable

Tidak cantik, tapi berhasil.

DECLARE @tab AS TABLE (col1 VARCHAR(10), col2 varchar(10)) 
INSERT into @tab EXECUTE  sp_executesql N'
SELECT 1 AS col1, 2 AS col2
UNION ALL
SELECT 1 AS col1, 2 AS col2
UNION ALL
SELECT 1 AS col1, 2 AS col2'

SELECT * FROM @tab

DECLARE @vi INT
DECLARE @vQuery NVARCHAR(1000)

SET @vQuery = N'SELECT @vi= COUNT(*) FROM <TableName>'

EXEC SP_EXECUTESQL 
        @Query  = @vQuery
      , @Params = N'@vi INT OUTPUT'
      , @vi = @vi OUTPUT

SELECT @vi

Nyatakan @variabel int

Exec @variable = proc_name

Nilai pengembalian umumnya tidak digunakan untuk "mengembalikan" hasil tetapi untuk mengembalikan keberhasilan (0) atau nomor kesalahan (1-65K). Semua di atas tampaknya menunjukkan bahwa sp_executesql tidak mengembalikan nilai, yang tidak benar. sp_executesql akan mengembalikan 0 untuk sukses dan nomor lainnya untuk kegagalan.

Di bawah ini, @ i akan mengembalikan 2727

DECLARE @s NVARCHAR(500)
DECLARE @i INT;
SET @s = 'USE [Blah]; UPDATE STATISTICS [dbo].[TableName] [NonExistantStatisticsName];';
EXEC @i = sys.sp_executesql @s
SELECT @i AS 'Blah'

SSMS akan menampilkan Msg 2727 ini, Level 11, State 1, Line 1 Tidak dapat menemukan indeks 'NonExistantStaticsName'.

DECLARE @ValueTable TABLE (Nilai VARCHAR (100))

                    SELECT @sql = N'SELECT SRS_SizeSetDetails.'+@COLUMN_NAME+' FROM SRS_SizeSetDetails WHERE FSizeID = '''+@FSizeID+''' AND SRS_SizeSetID = '''+@SRS_SizeSetID+'''';

                    INSERT INTO @ValueTable
                    EXEC sp_executesql @sql;

                    SET @Value='';

                    SET @Value = (SELECT TOP 1  Value FROM @ValueTable)

                    DELETE FROM @ValueTable

Jika Anda ingin mengembalikan lebih dari 1 nilai, gunakan ini:

DECLARE @sqlstatement2      NVARCHAR(MAX);
DECLARE @retText            NVARCHAR(MAX);  
DECLARE @ParmDefinition     NVARCHAR(MAX);
DECLARE @retIndex           INT = 0;

SELECT @sqlstatement = 'SELECT @retIndexOUT=column1 @retTextOUT=column2 FROM XXX WHERE bla bla';

SET @ParmDefinition = N'@retIndexOUT INT OUTPUT, @retTextOUT NVARCHAR(MAX) OUTPUT';

exec sp_executesql @sqlstatement, @ParmDefinition, @retIndexOUT=@retIndex OUTPUT, @retTextOUT=@retText OUTPUT;

nilai yang dikembalikan dalam @retIndex dan @retText

Ini sesuatu yang bisa Anda coba

DECLARE  @SqlStatement  NVARCHAR(MAX) = ''
       ,@result     XML
       ,@DatabaseName  VARCHAR(100)
       ,@SchemaName    VARCHAR(10)
       ,@ObjectName    VARCHAR(200);

SELECT   @DatabaseName = 'some database'
       ,@SchemaName   = 'some schema'
       ,@ObjectName   = 'some object (Table/View)'

SET @SqlStatement = '
                    SELECT @result = CONVERT(XML,
                                            STUFF( ( SELECT *
                                                     FROM 
                                                       (
                                                          SELECT TOP(100) 
                                                          * 
                                                          FROM ' + QUOTENAME(@DatabaseName) +'.'+ QUOTENAME(@SchemaName) +'.' + QUOTENAME(@ObjectName) + '
                                                       ) AS A1 
                                                    FOR XML PATH(''row''), ELEMENTS, ROOT(''recordset'')
                                                 ), 1, 0, '''')
                                       )
                ';

EXEC sp_executesql @SqlStatement,N'@result XML OUTPUT', @result = @result OUTPUT;

SELECT DISTINCT
    QUOTENAME(r.value('fn:local-name(.)', 'VARCHAR(200)')) AS ColumnName
FROM @result.nodes('//recordset/*/*') AS records(r)
ORDER BY ColumnName

Ini sudah lama sekali, jadi tidak yakin apakah ini masih diperlukan, tetapi Anda bisa menggunakan variabel @@ ROWCOUNT untuk melihat berapa banyak baris yang terpengaruh dengan pernyataan sql sebelumnya.

Ini berguna ketika misalnya Anda membangun pernyataan Pembaruan dinamis dan menjalankannya dengan exec. @@ ROWCOUNT akan menunjukkan berapa banyak baris yang diperbarui.

Inilah definisi

Ini bekerja untuk saya:

DECLARE @SQL NVARCHAR(4000)

DECLARE @tbl Table (
    Id int,
    Account varchar(50),
    Amount int
) 

-- Lots of code to Create my dynamic sql statement

insert into @tbl EXEC sp_executesql @SQL

select * from @tbl