Periksa apakah string nol atau kosong di XSLT

Bagaimana saya bisa memeriksa apakah suatu nilai nol atau kosong dengan XSL ?

Misalnya, apakah categoryNamekosong? Saya menggunakan ketika memilih konstruksi.

Sebagai contoh:

<xsl:choose>
    <xsl:when test="categoryName !=null">
        <xsl:value-of select="categoryName " />
    </xsl:when>
    <xsl:otherwise>
        <xsl:value-of select="other" />
    </xsl:otherwise>
</xsl:choose>

test="categoryName != ''"

Sunting : Ini mencakup interpretasi yang paling mungkin, menurut pendapat saya, tentang "[bukan] nol atau kosong" seperti yang disimpulkan dari pertanyaan, termasuk pseudo-code dan pengalaman awal saya sendiri dengan XSLT. Yaitu, "Apa yang setara dengan Java berikut?":

!(categoryName == null || categoryName.equals(""))

Untuk lebih jelasnya, misalnya, mengidentifikasi nol vs kosong, lihat jawaban johnvey di bawah ini dan / atau 'biola' XSLT yang telah saya adaptasi dari jawaban itu, yang mencakup opsi dalam komentar Michael Kay serta kemungkinan interpretasi keenam.

Tidak ada informasi lain, saya akan menganggap XML berikut:

<group>
    <item>
        <id>item 1</id>
        <CategoryName>blue</CategoryName>
    </item>
    <item>
        <id>item 2</id>
        <CategoryName></CategoryName>
    </item>
    <item>
        <id>item 3</id>
    </item>
    ...
</group>

Contoh kasus penggunaan akan terlihat seperti:

<xsl:for-each select="/group/item">
    <xsl:if test="CategoryName">
        <!-- will be instantiated for item #1 and item #2 -->
    </xsl:if>
    <xsl:if test="not(CategoryName)">
        <!-- will be instantiated for item #3 -->
    </xsl:if>
    <xsl:if test="CategoryName != ''">
        <!-- will be instantiated for item #1 -->
    </xsl:if>
    <xsl:if test="CategoryName = ''">
        <!-- will be instantiated for item #2 -->
    </xsl:if>
</xsl:for-each>

Dari Elemen Kosong :

Untuk menguji apakah nilai node tertentu kosong

Itu tergantung pada apa yang Anda maksud dengan kosong.

• Tidak mengandung node anak: not(node())
• Tidak mengandung konten teks: not(string(.))
• Tidak mengandung teks selain spasi putih: not(normalize-space(.))
• Tidak mengandung apa pun kecuali komentar: not(node()[not(self::comment())])

Bagaimana dengan?

test="not(normalize-space(categoryName)='')"

Dua kesepakatan pertama dengan nilai nol dan dua kesepakatan kedua dengan string kosong.

<xsl:if test="USER/FIRSTNAME">
    USERNAME is not null
</xsl:if>
<xsl:if test="not(USER/FIRSTNAME)">
    USERNAME is null
 </xsl:if>
 <xsl:if test="USER/FIRSTNAME=''">
     USERNAME is empty string
 </xsl:if>
 <xsl:if test="USER/FIRSTNAME!=''">
     USERNAME is not empty string
 </xsl:if>

Dalam beberapa kasus, Anda mungkin ingin tahu kapan nilainya secara khusus nol, yang sangat diperlukan saat menggunakan XML yang telah diserialisasi dari objek .NET. Sementara jawaban yang diterima berfungsi untuk ini, itu juga mengembalikan hasil yang sama ketika string kosong atau kosong, yaitu '', sehingga Anda tidak dapat membedakan.

<group>
    <item>
        <id>item 1</id>
        <CategoryName xsi:nil="true" />
    </item>
</group>

Jadi, Anda cukup menguji atributnya.

<xsl:if test="CategoryName/@xsi:nil='true'">
   Hello World.
</xsl:if>

Kadang-kadang perlu untuk mengetahui keadaan sebenarnya dan Anda tidak bisa begitu saja memeriksa apakah CategoryName adalah instantiated, karena tidak seperti mengatakan Javascript

<xsl:if test="CategoryName">
   Hello World.
</xsl:if>

Akan mengembalikan true untuk elemen nol.

Saya tahu pertanyaan ini sudah tua, tetapi di antara semua jawaban, saya kehilangan satu yang merupakan pendekatan umum untuk kasus penggunaan ini dalam pengembangan XSLT.

Saya membayangkan bahwa kode yang hilang dari OP terlihat seperti ini:

<xsl:template match="category">
    <xsl:choose>
        <xsl:when test="categoryName !=null">
            <xsl:value-of select="categoryName " />
        </xsl:when>
        <xsl:otherwise>
            <xsl:value-of select="other" />
        </xsl:otherwise>
    </xsl:choose>
</category>

Dan inputnya terlihat seperti ini:

<categories>
    <category>
       <categoryName>Books</categoryName>
    </category>
    <category>
       <categoryName>Magazines</categoryName>
       <categoryName>Periodicals</categoryName>
       <categoryName>Journals</categoryName>
    </category>
    <category>
        <categoryName><!-- please fill in category --></categoryName>
    </category>
    <category>
        <categoryName />
    </category>
    <category />
</categories>

Yaitu, saya berasumsi mungkin ada nol, kosong, categoryNameelemen tunggal atau ganda . Untuk menangani semua kasus ini menggunakan xsl:choosekonstruksi gaya, atau dengan kata lain, secara imperatif, dengan cepat menjadi berantakan (terlebih lagi jika elemen dapat berada pada level yang berbeda!). Sebuah idiom pemrograman tipikal dalam XSLT adalah menggunakan templat (maka T dalam XSLT), yang merupakan pemrograman deklaratif, bukan keharusan (Anda tidak memberi tahu prosesor apa yang harus dilakukan, Anda hanya memberi tahu apa yang Anda inginkan keluaran jika kondisi tertentu terpenuhi). Untuk kasus penggunaan ini, itu bisa terlihat seperti berikut:

<!-- positive test, any category with a valid categoryName -->
<xsl:template match="category[categoryName[text()]]">
    <xsl:apply-templates />
</xsl:template>

<!-- any other category (without categoryName, "null", with comments etc) -->
<xsl:template match="category">
    <xsl:text>Category: Other</xsl:text>
</xsl:template>

<!-- matching the categoryName itself for easy handling of multiple names -->
<xsl:template match="categoryName">
    <xsl:text>Category: </xsl:text>
    <xsl:value-of select="." />
</xsl:template>

Ini berfungsi (dengan versi XSLT apa pun), karena yang pertama di atas memiliki prioritas lebih tinggi (memiliki predikat). Templat pencocokan "fall-through", yang kedua, menangkap apa pun yang tidak valid. Yang ketiga kemudian menangani menghasilkan categoryNamenilai dengan cara yang tepat.

Perhatikan bahwa dalam skenario ini tidak perlu mencocokkan secara spesifik categoriesatau category, karena prosesor akan secara otomatis memproses semua anak, kecuali kami memberi tahu sebaliknya (dalam contoh ini, templat kedua dan ketiga tidak memproses lebih lanjut anak-anak, karena tidak ada xsl:apply-templatesdalam mereka).

Pendekatan ini lebih mudah diperluas daripada pendekatan imperatif, karena pendekatan ini secara otomatis menangani beberapa kategori dan dapat diperluas untuk elemen atau pengecualian lainnya dengan hanya menambahkan templat pencocokan lain. Pemrograman tanpa if-branch .

Catatan: tidak ada yang namanya nullXML. Ada xsi: nihil , tapi itu jarang digunakan, terutama jarang dalam skenario yang tidak diketik tanpa skema.

Bagaimana saya bisa memeriksa apakah suatu nilai nol atau kosong dengan XSL?

Misalnya, apakah categoryNamekosong?

Ini mungkin ekspresi XPath yang paling sederhana (yang ada di jawaban yang diterima memberikan tes untuk kebalikannya, dan akan lebih lama, jika dinegasikan):

not(string(categoryName))

Penjelasan :

Argumen untuk not()fungsi di atas adalah false()tepat ketika tidak ada categoryNameanak ("null") dari item konteks, atau anak (tunggal tersebut) categoryNamememiliki nilai string - string kosong.

Saya menggunakan ketika memilih konstruksi.

Sebagai contoh:

<xsl:choose>
    <xsl:when test="categoryName !=null">
        <xsl:value-of select="categoryName " />
    </xsl:when>
    <xsl:otherwise>
        <xsl:value-of select="other" />
    </xsl:otherwise>
</xsl:choose>

Dalam penggunaan XSLT 2.0 :

<xsl:copy-of select="concat(categoryName,  $vOther[not(string(current()/categoryName))])"/>

Ini adalah contoh lengkapnya :

<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
     <xsl:output omit-xml-declaration="yes" indent="yes"/>

 <xsl:variable name="vOther" select="'Other'"/>

 <xsl:template match="/">
  <xsl:copy-of select="concat(categoryName,$vOther[not(string(current()/categoryName))])"/>
 </xsl:template>
</xsl:stylesheet>

Ketika transformasi ini diterapkan pada dokumen XML berikut:

<categoryName>X</categoryName>

hasil yang diinginkan dan benar dihasilkan :

X

Ketika diterapkan pada dokumen XML ini :

<categoryName></categoryName>

atau ini:

<categoryName/>

atau ini

<somethingElse>Y</somethingElse>

hasil yang benar dihasilkan :

Other

Demikian pula, gunakan transformasi XSLT 1.0 ini :

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>

 <xsl:variable name="vOther" select="'Other'"/>

  <xsl:template match="/">
    <xsl:copy-of select=
    "concat(categoryName,  substring($vOther, 1 div not(string(categoryName))))"/>
  </xsl:template>
</xsl:stylesheet>

Perhatikan : Tidak ada persyaratan yang digunakan sama sekali. Pelajari lebih lanjut tentang pentingnya menghindari konstruksi kondisional dalam kursus Pluralsight yang bagus ini:

" Pola Desain Taktis di .NET: Alur Kontrol "

Jika ada kemungkinan elemen tidak ada dalam XML, saya akan menguji apakah elemen tersebut ada dan panjang senarnya lebih besar dari nol:

<xsl:choose>
    <xsl:when test="categoryName and string-length(categoryName) &gt; 0">
        <xsl:value-of select="categoryName " />
    </xsl:when>
    <xsl:otherwise>
        <xsl:value-of select="other" />
    </xsl:otherwise>
</xsl:choose>

Jika sebuah simpul tidak memiliki nilai yang tersedia di input xml seperti di bawah xpath,

<node>
    <ErrorCode/>
</node>

fungsi string () dikonversi menjadi nilai kosong. Jadi ini berfungsi dengan baik:

string(/Node/ErrorCode) =''

Sesuatu seperti ini bekerja untuk saya:

<xsl:choose>
  <xsl:when test="string(number(categoryName)) = 'NaN'"> - </xsl:when> 
  <xsl:otherwise> 
    <xsl:number value="categoryName" />
  </xsl:otherwise>
</xsl:choose>

Atau sebaliknya:

<xsl:choose>
  <xsl:when test="string(number(categoryName)) != 'NaN'">
    <xsl:number value="categoryName" />
  </xsl:when> 
  <xsl:otherwise> - </xsl:otherwise>
</xsl:choose>

Catatan: Jika Anda tidak memeriksa nilai nol atau menangani nilai nol, IE7 mengembalikan -2147483648 alih-alih NaN.

Saya benar-benar menemukan itu lebih baik hanya menguji panjang string karena berkali-kali bidang ini tidak nol, hanya kosong

<xsl: when test = "string-length (bidang-Anda-ingin-menguji) <1">

Menurut pengalaman saya, cara terbaik adalah:

<xsl:when test="not(string(categoryName))">
    <xsl:value-of select="other" />
</xsl:when>
<otherwise>
    <xsl:value-of select="categoryName" />
</otherwise>

Gunakan categoryName / teks sederhana () Tes tersebut berfungsi dengan baik <categoryName/>dan juga <categoryName></categoryName>.

<xsl:choose>
    <xsl:when test="categoryName/text()">
        <xsl:value-of select="categoryName" />
    </xsl:when>
    <xsl:otherwise>
        <xsl:value-of select="other" />
    </xsl:otherwise>
</xsl:choose>