Bagaimana cara menjalankan file batch dari jaringan berbagi tanpa pesan "jalur UNC tidak didukung"?

Saya mencoba menjalankan file batch dari jaringan bersama, tetapi saya terus mendapatkan pesan berikut: "Jalur UNC tidak didukung. Default ke direktori Windows." File batch berada di \\Server\Soft\WPX5\install.bat. Saat masuk sebagai administrator, dari Desktop Windows 7 saya, saya menavigasi ke \\Server\Soft\WP15\dan klik dua kali pada install.bat, saat itulah saya mendapatkan "jalur UNC tidak didukung." pesan. Saya menemukan beberapa saran online yang menyatakan bahwa drive pemetaan tidak akan berfungsi, tetapi menggunakan tautan simbolis akan menyelesaikan masalah ini, tetapi tautan simbolis tidak berfungsi untuk saya. Di bawah ini adalah konten file batch saya, saya sangat menghargai bantuan apa pun yang dapat membantu saya mencapai apa yang saya coba lakukan. Pada dasarnya, saya ingin menjalankan file batch dari \\Server\Soft\WP15\install.bat.

Konten file batch

mklink /d %userprofile%\Desktop\WP15 \\server\soft\WP15
\\server\soft\WP15\setup.exe
robocopy.exe "\\server\soft\WP15\Custom" /copyall "C:\Program Files (x86)\WP\Custom Templates"
Regedit.exe /s \\server\soft\WPX5\Custom\Migrate.reg

Juga, bagaimana cara menghapus tautan simbolis setelah penginstalan selesai?

PUSHD dan POPD akan membantu dalam kasus Anda.

@echo off
:: Create a temporary drive letter mapped to your UNC root location
:: and effectively CD to that location
pushd \\server\soft

:: Do your work
WP15\setup.exe
robocopy.exe "WP15\Custom" /copyall "C:\Program Files (x86)\WP\Custom Templates"
Regedit.exe /s WPX5\Custom\Migrate.reg

:: Remove the temporary drive letter and return to your original location
popd

Ketik PUSHD /?dari baris perintah untuk informasi lebih lanjut.

Ada pengaturan registri untuk menghindari pemeriksaan keamanan ini (meskipun demikian, gunakan dengan risiko Anda sendiri):

Di bawah jalur registri

   HKEY_CURRENT_USER
     \ Software
       \ Microsoft
         \ Command Processor

tambahkan nilai DisableUNCCheck REG_DWORD dan atur nilainya menjadi 0 x 1 (Hex).

Catatan: Pada Windows 10 versi 1803, pengaturan tampaknya berada di bawah HKLM: HKEY_LOCAL_MACHINE \ SOFTWARE \ Microsoft \ Command Processor

Saya merasa clsadalah jawaban terbaik. Ini menyembunyikan pesan UNC sebelum siapa pun dapat melihatnya. Saya menggabungkannya dengan @pushd %~dp0kanan setelahnya sehingga akan tampak seperti membuka skrip dan memetakan lokasi dalam satu langkah, sehingga mencegah masalah UNC lebih lanjut.

cls
@pushd %~dp0
:::::::::::::::::::
:: your script code here
:::::::::::::::::::
@popd

Catatan:

pushd akan mengubah direktori kerja Anda ke lokasi skrip di drive baru yang dipetakan.

popd pada akhirnya, untuk membersihkan drive yang dipetakan.

Pada dasarnya, Anda tidak dapat menjalankannya dari jalur UNC tanpa melihat pesan itu.

Yang biasanya saya lakukan hanyalah meletakkan a CLSdi bagian atas skrip jadi saya tidak perlu melihat pesan itu. Kemudian, tentukan jalur lengkap ke file di berbagi jaringan yang perlu Anda gunakan.

Saya hanya perlu dapat menjelajah Windows Explorer melalui berbagi server, lalu klik dua kali meluncurkan file batch. @dbenham membawa saya ke solusi yang lebih mudah untuk skenario saya (tanpa popdkekhawatiran):

:: Capture UNC or mapped-drive path script was launched from
set NetPath=%~dp0

:: Assumes that setup.exe is in the same UNC path
%NetPath%setup.exe

:: Note that NetPath has a trailing backslash ("\")
robocopy.exe "%NetPath%Custom" /copyall "C:\Program Files (x86)\WP\Custom Templates"
Regedit.exe /s %NetPath%..\WPX5\Custom\Migrate.reg

:: I am not sure if WPX5 was typo, so use ".." for parent directory
set NetPath=
pause

Alih-alih meluncurkan batch langsung dari explorer - buat pintasan ke batch dan setel direktori awal di properti pintasan ke jalur lokal seperti% TEMP% atau semacamnya.

Untuk menghapus tautan simbolik, gunakan perintah rmdir.

Saya mengalami masalah yang sama baru-baru ini bekerja dengan file batch pada drive berbagi jaringan di Windows 7.

Cara lain yang berhasil bagi saya adalah memetakan server ke drive melalui Windows Explorer: Tools -> Map network drive. Berikan huruf drive dan jalur folder ke \ server Anda. Karena saya bekerja dengan berbagi jaringan yang sering memetakannya membuatnya lebih nyaman, dan menyelesaikan kesalahan "jalur UNC tidak didukung".

Situasi saya hanya sedikit berbeda. Saya menjalankan file batch saat memulai untuk mendistribusikan versi terbaru aplikasi bisnis internal.

Dalam situasi ini saya menggunakan Windows Registry Run Key dengan string berikut

cmd /c copy \\serverName\SharedFolder\startup7.bat %USERPROFILE% & %USERPROFILE%\startup7.bat

Ini menjalankan dua perintah saat startup dalam urutan yang benar. Pertama-tama menyalin file batch secara lokal ke direktori yang izinnya dimiliki pengguna. Kemudian menjalankan file batch yang sama. Saya dapat membuat direktori lokal c: \ InternalApps dan menyalin semua file dari jaringan.

Ini mungkin terlambat untuk menjawab pertanyaan pembuat poster asli tetapi mungkin membantu orang lain.

Ini adalah RegKey yang saya gunakan:

Windows Registry Editor Version 5.00

[HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Command Processor]
"DisableUNCCheck"=dword:00000001

Ini adalah utas yang sangat lama, tetapi saya masih menggunakan Windows 7. :-)

Ada satu hal yang tampaknya tidak diperhitungkan oleh siapa pun, yang mungkin juga akan membantu pengguna Windows 10.

Jika Ekstensi Perintah diaktifkan, perintah PUSHD menerima jalur jaringan selain huruf dan jalur drive normal.

Jadi jawaban yang jelas - dan paling sederhana - mungkin untuk mengaktifkan ekstensi perintah dalam skrip batch, jika Anda bermaksud menggunakan PUSHD. Paling tidak, ini harus mengurangi masalah yang mungkin Anda alami dalam menggunakan PUSHD dengan jalur jaringan.

Saya env windows10 2019 versi lts dan saya menambahkan dua data binray ini, perbaiki kesalahan ini

Computer\HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Command ProcessorDisableUNCCheck nilai 1 Computer\HKEY_LOCAL_MACHINE\SOFTWARE\WOW6432Node\Microsoft\Command Processor DisableUNCCheck nilai 1

Mengedit registri Windows tidak sepadan dan tidak aman, gunakan Map network drivedan muat berbagi jaringan seolah-olah dimuat dari salah satu drive lokal Anda.