Cara mengeksekusi file yang saya edit di Vi (m)

Bagaimana cara mengeksekusi file yang saya edit di Vi (m) dan mendapatkan output di jendela terpisah (seperti di SciTE)?

Tentu saja saya bisa menjalankannya seperti itu:

:!scriptname

Tetapi apakah mungkin untuk menghindari penulisan nama skrip dan bagaimana cara mendapatkan output di jendela terpisah, bukan di bagian bawah layar?

Ada makeperintahnya. Ini menjalankan perintah yang ditetapkan dalam makeprgopsi. Gunakan %sebagai tempat penampung untuk nama file saat ini. Misalnya, jika Anda mengedit skrip python:

:set makeprg=python\ %

Ya, Anda harus keluar dari ruang angkasa. Setelah ini, Anda cukup menjalankan:

:make

Jika mau, Anda dapat mengatur autowriteopsi dan ini akan disimpan secara otomatis sebelum menjalankan makeprg:

:set autowrite

Ini menyelesaikan bagian eksekusi. Tidak tahu cara apa pun untuk mendapatkan keluaran itu ke jendela terpisah yang tidak melibatkan pengalihan ke file.

Untuk mengakses nama file buffer saat ini, gunakan %. Untuk membuatnya menjadi variabel Anda dapat menggunakan expand()fungsi tersebut. Untuk membuka jendela baru dengan buffer baru, gunakan :newatau :vnew. Untuk menyalurkan output dari perintah ke buffer saat ini, gunakan :.!. Menyatukan semuanya:

:let f=expand("%")|vnew|execute '.!ruby "' . f . '"'

jelas mengganti rubydengan perintah apa pun yang Anda inginkan. Saya menggunakan executeagar saya bisa mengelilingi nama file dengan tanda kutip, jadi itu akan berfungsi jika nama file memiliki spasi di dalamnya.

Vim memiliki !perintah ("bang") yang menjalankan perintah shell langsung dari jendela VIM. Selain itu memungkinkan peluncuran urutan perintah yang terhubung dengan pipa dan membaca stdout.

Sebagai contoh:

! node %

setara dengan membuka jendela prompt perintah dan meluncurkan perintah:

cd my_current_directory 
node my_current_file

Lihat "Tips Vim: Bekerja dengan perintah eksternal" untuk detailnya.

Saya memiliki jalan pintas untuk itu di vimrc saya:

nmap <F6> :w<CR>:silent !chmod 755 %<CR>:silent !./% > .tmp.xyz<CR>
     \ :tabnew<CR>:r .tmp.xyz<CR>:silent !rm .tmp.xyz<CR>:redraw!<CR>

Ini menulis buffer saat ini, membuat file saat ini dapat dieksekusi (hanya unix), mengeksekusinya (hanya unix) dan mengalihkan output ke .tmp.xyz, kemudian membuat tab baru, membaca file dan kemudian menghapusnya.

Memecahnya:

:w<CR>                             write current buffer
:silent !chmod 755 %<CR>           make file executable
:silent !./% > .tmp.xyz<CR>        execute file, redirect output
:tabnew<CR>                        new tab
:r .tmp.xyz<CR>                    read file in new tab
:silent !rm .tmp.xyz<CR>           remove file
:redraw!<CR>                       in terminal mode, vim get scrambled
                                   this fixes it

Untuk skrip Shell yang saya gunakan

:set makeprg=%

:make

Vim 8 memiliki terminal interaktif bawaan. Untuk menjalankan skrip bash saat ini dalam panel terpisah:

:terminal bash %

atau singkatnya

:ter bash %

% memperluas ke nama file saat ini.

Dari :help terminal:

The terminal feature is optional, use this to check if your Vim has it:
    echo has('terminal')
If the result is "1" you have it.

Saya menggunakan mekanisme yang sedikit lebih mengganggu melalui peta:

map ;e :w<CR>:exe ":!python " . getreg("%") . "" <CR>

Buat saja jadi saya tidak perlu menabung, lalu pergi. Pergi saja.

Anda dapat menggunakan plugin bexec dari vim . Sepengetahuan saya, versi terbaru adalah 0,5.

Kemudian:

$ mkdir -p ~/.vim/plugin
$ mv bexec-0.5.vba ~/.vim/plugin
$ vim ~/.vim/plugin/bexec-0.5.vba

Di dalam vim itu sendiri saat mengedit file .vba lakukan:

:so %

Beberapa keluaran akan muncul memberi tahu Anda bahwa bexec.vim telah ditulis serta dokumentasinya, dll ..

Sekarang, Anda dapat mengujinya dengan membuka (skrip bahasa apa pun yang memiliki #! Interpreter berfungsi dengan baik) di vim dan menjalankan

:Bexec 

Catatan: Saya ingin perpecahan menjadi vertikal daripada horizontal, jadi saya lakukan:

$ grep -i -n split ~/.vim/plugin/bexec.vim | grep -i hor
102:    let bexec_splitdir = "hor" " hor|ver
261:        exec {"ver":"vsp", "hor":"sp"}[g:bexec_splitdir]

dan mengubah nilai dari "hor" menjadi "ver" ..

Saya tahu ini pertanyaan lama, tapi saya harap ini bisa membantu seseorang di luar sana. Saya telah mengalami masalah yang sama saat mengambil kursus Teknik Startup Coursera di mana profesor Palaji menggunakan Emacs dan saya tidak suka Emacs ..

Berdasarkan jawaban @SethKriticos dan @Cyril, saya sekarang menggunakan yang berikut:

function! Setup_ExecNDisplay()
  execute "w"
  execute "silent !chmod +x %:p"
  let n=expand('%:t')
  execute "silent !%:p 2>&1 | tee ~/.vim/output_".n
  " I prefer vsplit
  "execute "split ~/.vim/output_".n
  execute "vsplit ~/.vim/output_".n
  execute "redraw!"
  set autoread
endfunction

function! ExecNDisplay()
  execute "w"
  let n=expand('%:t')
  execute "silent !%:p 2>&1 | tee ~/.vim/output_".n
  " I use set autoread
  "execute "1 . 'wincmd e'"
endfunction

:nmap <F9> :call Setup_ExecNDisplay()<CR>
:nmap <F2> :call ExecNDisplay()<CR>

Gunakan F9 untuk menyiapkan jendela baru dan F2 untuk menjalankan skrip dan tee ke file output Anda.

Saya juga menambahkan nama skrip ke nama file keluaran, sehingga Anda dapat menggunakan ini untuk beberapa skrip pada saat yang bersamaan.

Di Anda, .vimrcAnda dapat menempelkan fungsi ini

function! s:ExecuteInShell(command)
  let command = join(map(split(a:command), 'expand(v:val)'))
  let winnr = bufwinnr('^' . command . '$')
  silent! execute ':w'
  silent! execute  winnr < 0 ? 'vnew ' . fnameescape(command) : winnr . 'wincmd w'
  setlocal buftype=nowrite bufhidden=wipe nobuflisted noswapfile nowrap number
  silent! execute 'silent %!'. command
  silent! redraw
  silent! execute 'au BufUnload <buffer> execute bufwinnr(' . bufnr('#') . ') . ''wincmd w'''
  silent! execute 'nnoremap <silent> <buffer> <LocalLeader>r :call <SID>ExecuteInShell(''' . command . ''')<CR>'
  silent! execute 'wincmd w'
  " echo 'Shell command ' . command . ' executed.'
endfunction
command! -complete=shellcmd -nargs=+ Shell call s:ExecuteInShell(<q-args>)
cabbrev shell Shell

Setelah itu, di vimjalankan perintah :shell python ~/p.pysebagai contoh. Dan Anda akan mendapatkan output di jendela terbelah. + Setelah perubahan p.pysebagai contoh Anda akan menjalankan perintah yang sama lagi, fungsi ini tidak akan membuat jendela baru lagi, ini akan menampilkan hasilnya di jendela terpisah sebelumnya (sama).

@tokopedia

Saya mencari skrip ini (python / Windows) cukup lama. Karena tidak ada "tee" di Windows, saya mengubahnya menjadi:

function! Setup_ExecNDisplay()
  execute "w"
  let n=expand('%:t')
  execute "silent ! python % > d:\\temp\\output_".n ." 2>&1"
  execute "vsplit d:\\temp\\output_".n
  execute "redraw!"
  set autoread
endfunction

function! ExecNDisplay()
  execute "w"
  let n=expand('%:t')
  execute "silent ! python % > d:\\temp\\output_".n . " 2>&1"
endfunction

:nmap <F9> :call Setup_ExecNDisplay()<CR>
:nmap <F2> :call ExecNDisplay()<CR>

Cukup gunakan titik dua dan tanda seru seperti yang ditunjukkan di bawah ini

:! <script_name>

Saya akan merekomendasikan plugin quickrun . Cepat dan mudah untuk dikonfigurasi. Berikut sedikit demonstrasi: