Mengekspor spreadsheet Excel ke file teks lebar tetap?

Excel memiliki fungsionalitas untuk mengimpor file teks lebar tetap di mana ia menyajikan dialog yang memungkinkan Anda memilih di mana awal dan akhir bidang yang dimasukkan ke dalam kolom.

Apakah ini juga memiliki fungsi di mana, mengingat spreadsheet yang ada, Anda dapat mengekspor ke file teks lebar-tetap?

Jika demikian, bagaimana cara mengakses ini? Saya telah mencoba menggunakan Simpan Sebagai dan memilih File Teks tetapi tampaknya hanya menyimpan sebagai Tab-dibatasi yang tidak membantu saya.

Ini adalah Excel 2003 jika itu penting.

Saya pikir yang paling dekat yang bisa Anda dapatkan dari fungsionalitas Excel asli adalah Save As | Teks Terformat (Dibatasi Ruang) (* .prn) . Ini akan secara otomatis menentukan lebar dan menyisipkan spasi untuk pad dengan lebar yang diperlukan.

Selain itu, Anda perlu memiliki makro atau tambahan lainnya yang memungkinkan Anda melakukan lebih banyak.

Jika Anda memiliki Office Professional, Anda bisa membuka file Excel di Access, dan lalu Ekspor dari Access. Akses akan memungkinkan Anda menentukan tata letak lebar tetap untuk file yang diekspor, dan memberi Anda kontrol yang sangat terperinci untuk menentukan lebar tersebut.

Wow, saya sendiri akan mengajukan pertanyaan ini tetapi sudah ditanyakan. Semua output clipboard Excel tabdibatasi secara default. Ini agak menyebalkan untuk output teks biasa "nyata" ketika Anda memiliki font lebar tetap tetapi tidak perlu dukungan pembatas tab.

Lagi pula, saya menemukan dan memodifikasi Excel Macro kecil yang akan menyalin wilayah yang saat ini dipilih sebagai tabel ASCII kolom lebar tetap sederhana - seperti:

187712 201 37 0,18   
2525 580 149 0,25   
136829 137 43 0,31   

Ini kode makronya. Untuk menggunakannya, pastikan Anda mengaktifkan tab Pengembang di Opsi Excel jika Anda menggunakan Excel 2007 atau yang lebih baru.

Sub CopySelectionToClipboardAsText()

   ' requires a reference to "Windows Forms 2.0 Object Library"
   ' add it via Tools / References; if it does not appear in the list
   ' manually add it as the path C:\Windows\System32\FM20.dll

    Dim r As Long, c As Long
    Dim selectedrows As Integer, selectedcols As Integer

    Dim arr
    arr = ActiveSheet.UsedRange
    selectedrows = UBound(arr, 1)
    selectedcols = UBound(arr, 2)

    Dim temp As Integer
    Dim cellsize As Integer
    cellsize = 0
    For c = 1 To selectedcols
        temp = Len(CStr(Cells(1, c)))
        If temp > cellsize Then
            cellsize = temp
        End If
    Next c
    cellsize = cellsize + 1

    Dim line As String
    Dim output As String

    For r = 1 To selectedrows
        line = Space(selectedcols * cellsize)
        For c = 1 To selectedcols
            Mid(line, c * cellsize - cellsize + 1, cellsize) = Cells(r, c)
        Next c
        output = output + line + Chr(13) + Chr(10)
    Next r

    Dim MyData As MSForms.DataObject
    Set MyData = New DataObject
    MyData.SetText output
    MyData.PutInClipboard

    MsgBox "The current selection was formatted and copied to the clipboard"

End Sub

Pertama, format data Anda sebagai Courier New (atau font dengan lebar tetap lainnya). Kemudian simpan sebagai .prn dan Anda akan mendapatkan lebar tetap yang benar.

Memperluas jawaban Jeff Atwood, karena itu tidak akan membiarkan saya berkomentar di sana:

Saya memodifikasi makro untuk mengatur lebar kolom ke sel terlebar di kolom itu dan memiliki masing-masing kolom lebarnya sendiri. Makronya hanya menemukan sel terlebar di baris pertama dan kemudian mengatur lebar semua kolom ke sana.

Sub CopySelectionToClipboardAsText()

   ' requires a reference to "Windows Forms 2.0 Object Library"
   ' add it via Tools / References; if it does not appear in the list
   ' manually add it as the path C:\Windows\System32\FM20.dll

    Dim r As Long, c As Long, linesize As Long
    Dim selectedrows As Integer, selectedcols As Integer

    Dim arr
    arr = ActiveSheet.UsedRange
    selectedrows = UBound(arr, 1)
    selectedcols = UBound(arr, 2)
    ReDim CellSizes(1 To selectedcols, 2) As Integer

    Dim temp As Integer
    Dim cellsize As Integer
    linesize = 0
    For c = 1 To selectedcols
        cellsize = 0
        For r = 1 To selectedrows
            temp = Len(CStr(Cells(r, c)))
            If temp > cellsize Then
                cellsize = temp
            End If
        Next
        CellSizes(c, 0) = cellsize + 1
        CellSizes(c, 1) = linesize
        linesize = linesize + cellsize + 1
    Next c

    Dim line As String
    Dim output As String

    For r = 1 To selectedrows
        line = Space(linesize)
        For c = 1 To selectedcols
            Mid(line, CellSizes(c, 1) + 1, CellSizes(c, 0)) = Cells(r, c)
        Next c
        output = output + line + Chr(13) + Chr(10)
    Next r

    Dim MyData As MSForms.DataObject
    Set MyData = New DataObject
    MyData.SetText output
    MyData.PutInClipboard

    MsgBox "The current selection was formatted and copied to the clipboard"

End Sub

Ini pembunuh bagiku. Ini memiliki beberapa opsi juga.

http://www.sensefulsolutions.com/2010/10/format-text-as-table.html

Ini berfungsi dengan Akses di luar kotak: https://support.office.com/en-ie/article/export-data-to-a-text-file-f72dfc38-a8a0-4c5b-8c2c-bf2950814140#bmsteps dengan ini cara saya mengelolanya cukup mudah dan cepat - lebih baik daripada dengan Excel. Dalam kasus saya itu adalah konversi tabel.