Bagaimana saya bisa menghapus semua file / subfolder dalam folder yang diberikan melalui command prompt?

Saya ingin menghapus semua file dan subfolder dalam file batch di Windows 7 dan menyimpan folder teratas. Pada dasarnya mengosongkan folder. Apa instruksi baris perintah untuk itu?

Anda dapat melakukan ini menggunakan deldan /Sbendera (untuk memberi tahu menghapus semua file dari semua subdirektori):

del /S C:\Path\to\directory\*

Solusi terbaik: mis. Saya ingin menghapus semua file dan sub-direktori dari direktori induk katakanlah "C: \ Users \ Desktop \ New folder \". Cara mudah adalah membuat file batch di bawah tiga perintah.

cd C: \ Users \ Desktop \ New folder \

del * / S / Q

rmdir / S / Q "C: \ Users \ Desktop \ New folder \"

Di sini pertama-tama akan membersihkan semua file di semua sub-direktori dan kemudian membersihkan semua sub-direktori yang kosong. Karena direktori kerja saat ini adalah direktori induk yaitu "\ Folder baru", perintah rmdir tidak dapat menghapus direktori ini sendiri.

Arahkan ke direktori induk:

pushd "Parent Directory"

Hapus sub folder:

rd /s /q . 2>nul

rmdir "c:\pathofyourdirectory" /q /s

Jangan lupa untuk menggunakan tanda kutip dan untuk /q /situ akan menghapus semua repositori dan tanpa diminta.

Anda dapat menggunakan rmdir untuk menghapus file dan subfolder, seperti ini:

rmdir /s/q MyFolderPath

Namun, ini secara signifikan lebih cepat, terutama ketika Anda memiliki banyak subfolder dalam struktur Anda untuk menggunakan del sebelum rmdir, seperti ini:

del /f/s/q MyFolderPath > nul
rmdir /s/q MyFolderPath

Jika Anda ingin menghapus semua file dalam folder, termasuk semua subfolder dan tidak bergantung pada beberapa kondisi kesalahan untuk menjaga folder root tetap utuh (seperti yang saya lihat di jawaban lain), Anda bisa memiliki file batch seperti ini:

@echo off

REM Checking for command line parameter
if "%~1"=="" (

    echo Parameter required.
    exit /b 1

) else (

    REM Change directory and keep track of the previous one
    pushd "%~1"

    if errorlevel 1 (

        REM The directory passed from command line is not valid, stop here.
        exit /b %errorlevel%

    ) else (

        REM First we delete all files, including the ones in the subdirs, without confirmation
        del * /S /Q

        REM Then we delete all the empty subdirs that were left behind
        for /f %%D IN ('dir /b /s /a:d "%~1"') DO rmdir /S /Q "%%D"

        REM Change directory back to the previous one
        popd

        REM All good.
        exit /b 0
    )

)

Dan kemudian Anda cukup menyebutnya dengan:

empty_my_folder.bat "C:\whatever\is\my folder"

Anda dapat melakukannya dengan cepat dan mudah dengan memasukkan tiga instruksi ini ke file bat Anda:

mkdir empty_folder
robocopy /mir empty_folder "path_to_directory"
rmdir empty_folder

Ini bekerja lebih baik untuk saya ketika saya memiliki spasi di nama folder.

@echo off
REM ---- Batch file to clean out a folder
REM Checking for command line parameter
if "%~1"=="" (

echo Parameter required.
exit /b 1

) else (
echo ***********************************************************************************
    echo *** Deleting all files, including the ones in the subdirs, without confirmation *** 
    del "%~1\*" /S /Q
echo ***********************************************************************************
    REM Deleting all the empty subdirs that were left behind
FOR /R "%~1" %%D IN (.) DO (
    if "%%D"=="%~1\."  (
    echo *** Cleaning out folder: %~1 *** 
    ) else (
    echo Removed folder "%%D"
    rmdir /S /Q "%%D"
    )
) 

    REM All good.
    exit /b 0

)

Untuk menghapus file:

del PATH_TO_FILE

Untuk menghapus folder dengan semua file di dalamnya:

rmdir /s /q PATH_TO_FOLDER

Untuk menghapus semua file dari folder tertentu (tidak menghapus folder itu sendiri) agak rumit. del /s *.*tidak dapat menghapus folder, tetapi menghapus file dari semua subfolder. Jadi diperlukan dua perintah:

del /q PATH_TO_FOLDER\*.*
for /d %i in (PATH_TO_FOLDER\*.*) do @rmdir /s /q "%i"

Anda dapat membuat skrip untuk menghapus apa pun yang Anda inginkan (folder atau file) seperti ini mydel.bat:

@echo off
setlocal enableextensions

if "%~1"=="" (
    echo Usage: %0 path
    exit /b 1
)

:: check whether it is folder or file
set ISDIR=0
set ATTR=%~a1
set DIRATTR=%ATTR:~0,1%
if /i "%DIRATTR%"=="d" set ISDIR=1

:: Delete folder or file
if %ISDIR%==1 (rmdir /s /q "%~1") else (del "%~1")
exit /b %ERRORLEVEL%

Beberapa contoh penggunaan:

mydel.bat "path\to\folder with spaces"
mydel.bat path\to\file_or_folder

Inilah yang bekerja untuk saya.

1. Menavigasi di dalam folder tempat Anda ingin menghapus file.
2. Mengetik: del *
3. Y untuk ya.
4. Selesai