Cara membuat pengingat Kalender Outlook tetap teratas di Windows 7

Saya baru mulai menggunakan Windows 7 dan saya ingin tahu cara membuat pengingat Outlook saya muncul dan menunjukkan diri mereka dengan jelas. Mereka terus membuka secara diam-diam, hanya sebagai jendela lain di tumpukan Outlook di taskbar. Akibatnya, saya terus mengabaikan mereka karena mereka muncul di belakang segalanya.

Bagaimana saya membuatnya lebih mudah untuk diabaikan?

(Jelas, orang biasanya tidak ingin aplikasi yang menjengkelkan yang mendorong diri mereka ke garis depan. Tetapi ada beberapa tempat di mana perilaku seperti itu diinginkan, dan pengingat kalender Outlook adalah salah satunya.)

Saya memiliki masalah yang sama dengan Outlook 2010. Gunakan langkah-langkah yang disebutkan di bawah, ini berfungsi seperti pesona. Jangan lupa untuk mengaktifkan semua makro: Pusat Kepercayaan> Pengaturan Makro.

• Buat sertifikat Digital untuk nanti: Tekan Mulai dan ketik 'sertifikat', pilih 'Sertifikat Digital untuk Proyek VBA'
• Masukkan nama untuk sertifikat Anda. Klik OK. Buka Outlook dan tekan Alt+ F11untuk memulai editor VBA.
• Di pohon di sebelah kiri, rentangkan 'Microsoft Office Outlook Objects' dan klik dua kali pada 'ThisOutlookSession'

• Rekatkan dalam kode ini:

  Private Declare PtrSafe Function FindWindowA Lib "user32" _
  (ByVal lpClassName As String, ByVal lpWindowName As String) As Long
  
  Private Declare PtrSafe Function SetWindowPos Lib "user32" ( _
  ByVal hwnd As Long, ByVal hWndInsertAfter As Long, _
  ByVal X As Long, ByVal Y As Long, ByVal cx As Long, _
  ByVal cy As Long, ByVal wFlags As Long) As Long
  
  Private Const SWP_NOSIZE = &H1
  Private Const SWP_NOMOVE = &H2
  Private Const FLAGS As Long = SWP_NOMOVE Or SWP_NOSIZE
  Private Const HWND_TOPMOST = -1
  
  Private Sub Application_Reminder(ByVal Item As Object)
  Dim ReminderWindowHWnd As Variant
  On Error Resume Next
  ReminderWindowHWnd = FindWindowA(vbNullString, "1 Reminder")
  SetWindowPos ReminderWindowHWnd, HWND_TOPMOST, 0, 0, 0, 0, FLAGS
  
  End Sub
  

• Tanda tangani Makro sehingga akan berjalan: Alat> Tanda Tangan Digital ... dan pilih sertifikat yang Anda buat sebelumnya

• Tutup jendela VBA
• Aktifkan semua makro di File> Opsi> Pusat Kepercayaan> Pengaturan Pusat Kepercayaan> Pengaturan Makro

AutoHotKey juga dapat digunakan untuk menyelesaikan ini. Script ini akan menempatkan jendela pengingat di atas tanpa mencuri fokus (diuji dengan Win10 / Outlook 2013)

TrayTip Script, Looking for Reminder window to put on top, , 16
SetTitleMatchMode  2 ; windows contains
loop {
  WinWait, Reminder(s), 
  WinSet, AlwaysOnTop, on, Reminder(s)
  WinRestore, Reminder(s)
  TrayTip Outlook Reminder, You have an outlook reminder open, , 16
  WinWaitClose, Reminder(s), ,30
}

AHK Script - Kompilasi EXE

Jawaban terbaik yang saya temukan ada di sini: Cara mendapatkan pengingat janji temu Outlook untuk muncul di depan jendela lain lagi menggunakan beberapa VBA sederhana.

Ini mencakup penambahan beberapa baris kode VBA sederhana ke "ThisOutlookSession". Sekarang, muncul jendela setiap saat. Jauh lebih baik.

• Buat sertifikat Digital untuk nanti
• Tekan Mulai dan ketik 'sertifikat', pilih 'Sertifikat Digital untuk Proyek VBA'
• Masukkan nama untuk sertifikat Anda
• Selesai
• Buka Outlook dan tekan Alt + F11 untuk memulai editor VBA.
• Di pohon di sebelah kiri, rentangkan 'Microsoft Office Outlook Objects' dan klik dua kali pada 'ThisOutlookSession'

• Rekatkan dalam kode ini, modifikasi teks dalam tanda kutip yang sesuai dengan preferensi Anda. Biarkan tanda kutip masuk

  Private Sub Application_Reminder(ByVal Item As Object)
  
  
      If TypeOf Item Is AppointmentItem Then
      MsgBox "Message text", vbSystemModal, "Message title"
      End If
  
  
  End Sub
  

• Masuk Macro sehingga akan berjalan dengan masuk ke Alat> Tanda Tangan Digital ... dan memilih sertifikat yang Anda buat sebelumnya

• Tutup jendela VBA

Pada Versi 1803 (Februari 2018), opsi "Tampilkan pengingat di atas jendela lain" sekarang tersedia. Tampaknya tidak diaktifkan secara default.

Tidak ada jalan. Perusahaan kami mencoba meningkatkannya ke Microsoft secara langsung. Satu hal yang dilakukan orang di sini adalah memberinya suara yang lebih menjengkelkan, untuk membantu menyadarinya. Tetapi Microsoft telah memberitahu kami bahwa itu adalah desain.

Sama seperti jawaban Gullu di atas tetapi dengan perubahan untuk mengakomodasi judul jendela yang berbeda:

Private Declare PtrSafe Function FindWindowA Lib "user32" (ByVal lpClassName As String, ByVal lpWindowName As String) As Long

Private Declare PtrSafe Function SetWindowPos Lib "user32" (ByVal hwnd As Long, ByVal hWndInsertAfter As Long, ByVal X As Long, ByVal Y As Long, ByVal cx As Long, ByVal cy As Long, ByVal wFlags As Long) As Long

Private Const SWP_NOSIZE = &H1
Private Const SWP_NOMOVE = &H2
Private Const FLAGS As Long = SWP_NOMOVE Or SWP_NOSIZE
Private Const HWND_TOPMOST = -1

'// TO ACCOUNT FOR WINDOW TITLE CHANGING WITH NOTIFICATION COUNT:
Private Sub Application_Reminder(ByVal Item As Object)
    Dim ReminderWindowHWnd As Variant
    'On Error Resume Next
    On Error GoTo err
    'Loop 25 times as FindWindowA needs exact title which varies according to number of reminder items...
    Dim iReminderCount As Integer
    For iReminderCount = 1 To 25
        'Try two syntaxes...
        ReminderWindowHWnd = FindWindowA(vbNullString, iReminderCount & " Reminder"): SetWindowPos ReminderWindowHWnd, HWND_TOPMOST, 0, 0, 0, 0, FLAGS
        ReminderWindowHWnd = FindWindowA(vbNullString, iReminderCount & " Reminder(s)"): SetWindowPos ReminderWindowHWnd, HWND_TOPMOST, 0, 0, 0, 0, FLAGS
    Next
Exit Sub
err:
    Debug.Print err.Number & " - " & err.Description & " (iReminderCount = " & iReminderCount & ")"
    Resume Next
End Sub

Ini menggangguku juga. Setelah beberapa pencarian intens saya menemukan jawaban parsial: http://www.pcreview.co.uk/forums/hidden-outlook-reminders-t3972914.html

Jika Anda mengubah pengaturan "Tombol-tombol Taskbar" di bawah "Taskbar dan Start Menu Properties" menjadi "Never menggabungkan," maka pengelompokan memisahkan dan pengingat muncul di depan apa pun yang Anda buka.

Saya mencoba mengujinya dan ternyata tidak konsisten; satu kali itu tetap tersembunyi di balik apa yang saya kerjakan, dan lain kali muncul di depan. Dalam kedua kasus ada ikon di bilah tugas yang tampak berbeda dari Outlook itu sendiri, jadi setidaknya ada kemungkinan saya akan melihatnya.

Saya menggunakan Filebox eXtender dan ketika pengingat pertama datang saya membukanya dan klik ikon 'pin' baru di kanan atas bilah keterangan. Kemudian ketika pengingat berikutnya datang, itu datang di latar depan ...

Saya menemukan addin yang disebut ShowReminders ( http://www.sagelamp.com/pages/showreminders.aspx ), yang membawa jendela pengingat ke atas. Ia bahkan berfungsi saat Anda memperkecil jendela pengingat.

Saya akhirnya menemukan solusi sederhana menggunakan Outlook VBA dan EXE sederhana.

Inilah cara untuk tidak pernah melewatkan janji temu pertemuan prospek lagi.

Mengapa aplikasi exe yang berdiri sendiri hanya untuk tujuan ini? Yah saya memiliki kotak merah besar yang tertanam di VBA, tapi solusi itu penuh masalah (saya percaya itu karena saya harus menggunakan hwnd dan properti sistem tidak biasa lainnya untuk menjaga kotak merah besar di atas). Jadi untuk membuatnya lebih sederhana, mengapa tidak EXE dasar yang melakukan satu hal. Anda dapat menggunakan alat gratis dari microsoft (Visual studio Community 2015 gratis).

Ini adalah kode EXE. aplikasi windows form sederhana dengan satu form. Kompilasi kode ini.

Imports System.Timers
Public Class Form1
    Dim tTimer As New Timer
    Public Sub New()
        InitializeComponent()
        Me.StartPosition = Windows.Forms.FormStartPosition.CenterScreen
        Me.TopMost = True
        Me.TopLevel = True
    End Sub
    Private Sub Form1_DoubleClick(sender As Object, e As EventArgs) Handles Me.DoubleClick
        Application.Exit()
    End Sub 
    Private Sub Form1_Shown(sender As Object, e As EventArgs) Handles Me.Shown
        flashingQuick()
    End Sub
    Sub flashingQuick()
        tTimer.Start()
        AddHandler tTimer.Elapsed, New ElapsedEventHandler(AddressOf TimerTick)
    End Sub
    Sub TimerTick(ByVal source As [Object], ByVal e As ElapsedEventArgs)
        Dim theTimer As System.Timers.Timer = DirectCast(source, System.Timers.Timer)
        theTimer.Interval = 500
        theTimer.Enabled = True
        If Me.BackColor = System.Drawing.SystemColors.Control Then
            Me.BackColor = Color.Red
        Else
            Me.BackColor = System.Drawing.SystemColors.Control
        End If
    End Sub
End Class

Dan ini semua yang saya butuhkan dalam VBA prospek. Letakkan ini di ThisOutlookSession

Private Sub Application_Reminder(ByVal Item As Object)
    On Error Resume Next
    If Item.MessageClass <> "IPM.Appointment" Then
      Exit Sub
    End If
    Dim sAPPData As String
    Dim sFileName As String
    sAPPData = Environ("AppData")
    sFileName = "\Microsoft\Windows\Start Menu\Programs\BigRedBox\BigRedBox.exe"
    If Dir(sAPPData & sFileName) <> "" Then
        Call Shell(sAPPData & sFileName)
    End If
End Sub

Ini adalah versi lanjutan dari jawaban tbone yang berfungsi pada versi Jerman.

Private Declare PtrSafe Function FindWindowA Lib "user32" (ByVal lpClassName As String, ByVal lpWindowName As String) As Long
Private Declare PtrSafe Function SetWindowPos Lib "user32" (ByVal hwnd As Long, ByVal hWndInsertAfter As Long, ByVal X As Long, ByVal Y As Long, ByVal cx As Long, ByVal cy As Long, ByVal wFlags As Long) As Long
Private Declare PtrSafe Function BringWindowToTop Lib "user32" (ByVal hwnd As Long) As Boolean
Private Declare PtrSafe Function SetForegroundWindow Lib "user32" (ByVal hwnd As Long) As Boolean
Private Declare PtrSafe Function SetFocus Lib "user32" (ByVal hwnd As Long) As Long

Private Const SWP_NOSIZE = &H1
Private Const SWP_NOMOVE = &H2
Private Const FLAGS As Long = SWP_NOMOVE Or SWP_NOSIZE
Private Const HWND_TOPMOST = -1

Private Sub Application_Reminder(ByVal Item As Object)
    Dim ReminderWindowHWnd As Variant
    On Error GoTo err
    'Loop 25 times as FindWindowA needs exact title which varies according to number of reminder items...
    Dim iReminderCount As Integer
    For iReminderCount = 1 To 25
        'Try two syntaxes...

        ReminderWindowHWnd = FindWindowA(vbNullString, iReminderCount & " Erinnerung")
        SetWindowPos ReminderWindowHWnd, HWND_TOPMOST, 0, 0, 0, 0, FLAGS
        BringWindowToTop (ReminderWindowHWnd)
        SetForegroundWindow ReminderWindowHWnd
        SetFocus ReminderWindowHWnd

        ReminderWindowHWnd = FindWindowA(vbNullString, iReminderCount & " Erinnerung(en)")
        SetWindowPos ReminderWindowHWnd, HWND_TOPMOST, 0, 0, 0, 0, FLAGS
        BringWindowToTop ReminderWindowHWnd
        SetForegroundWindow ReminderWindowHWnd
        SetFocus ReminderWindowHWnd
    Next
Exit Sub
err:
    Debug.Print err.Number & " - " & err.Description & " (iReminderCount = " & iReminderCount & ")"
    Resume Next
End Sub

Saya telah menambahkan judul jendela Jerman dan juga beberapa fungsi baru ( BringWindowToTop, SetForegroundWindowdan SetFocus).

Bekerja pada Windows 10 Jerman saya bersama Outlook 2016.

Saya tidak berhasil membuat sertifikat baru (menekan Mulai dan memasukkan "sertifikat" tidak mengungkapkan apa-apa), tetapi cukup memilih sertifikat lain dalam daftar saat masuk.