obat untuk trackball roda gulir tidak?

Saya berpikir untuk membeli trackball dan pilihan saya adalah Logitech trackman marble. Tetapi kemudian saya menemukan bahwa tidak ada roda gulir. Bagaimana Anda mengatasinya? Apakah saya benar-benar ingin membeli trackball dengan roda gulir? Saya gulir banyak menggunakan facebook.

Saya tidak ingin mengklik dengan jari telunjuk dan tengah saya, jadi beberapa mouse trackball tidak akan bekerja untuk saya, seperti Trackman Wheel.

Jika Anda menggunakan Windows, saya sarankan untuk mencoba Autohotkey, pengguna lain telah menangani pengguliran dengan Mouse Marmer (saya menggunakan skrip di bagian bawah):

http://www.autohotkey.com/board/topic/4677-wheel-button-emulation-script/

Solusi Logitech yang datang dengan driver mereka aneh: Anda mengklik sekali untuk mengaktifkan scrolling 4 arah dan klik lagi untuk menonaktifkannya. Anda tidak dapat menahan dan menggulir yang saya cari. Saya akhirnya menghapus perangkat lunak mereka.

Saya memiliki trackball yang sama dan solusinya sangat elegan: ketika Anda mengklik tombol yang dipilih, bola itu sendiri menjadi roda gulir. Saya telah memilih tombol kanan besar yang saya tekan dengan jari kelingking.

Ini sangat nyaman dan hanya perlu beberapa hari untuk membiasakan diri.

Anda akan dengan cepat mempertimbangkan bahwa roda gulir mana pun (pada mouse atau trackball) adalah sesuatu yang tidak dapat digunakan. Percayalah, itu layak ;-)

Keuntungan:

• Pengguliran 2D bukannya 1D
• gulir lebih cepat dan lebih tepat daripada roda
• lebih nyaman untuk scroll panjang (terima kasih untuk inersia bola). Sempurna untuk contoh facebook Anda.

Saya tidak bisa hidup tanpanya lagi.

Mengkonfigurasi bahwa di bawah OS Linux apa pun tidak sulit. Ini hanya mengharuskan Anda untuk membuat file /etc/X11/xorg.conf (lihat konfigurasi saya di sini: Mengkonfigurasi trackball di Linux tanpa mengedit Xorg.conf )

Detail lebih lanjut dapat ditemukan di sini: https://help.ubuntu.com/community/Logitech_Marblemouse_USB

Di Windows, saya tidak punya pengalaman tapi saya pikir alat konfigurasi dikirim dengan trackball.

Anda dapat mencoba Roda Gulir Mouse Marmer, yang dikembangkan khusus untuk mouse itu:

Marble Mouse Scroll Wheel, atau hanya Marble Scroll, adalah program kecil yang dirancang untuk mensimulasikan roda gulir pada trackball atau mouse apa pun tanpa mouse. Itu secara khusus dirancang untuk Mouse Marmer Logitech tetapi dapat bekerja dengan mouse standar atau trackball. Ini dirancang untuk Windows 2000 dan lebih tinggi.

Marble Scroll adalah pengganti untuk fungsi Autoscroll dan Universal Scroll Logitech; tidak ada yang benar-benar meniru roda gulir nyata dan keduanya memiliki keterbatasan dan kekurangan.

Marble Scroll berfungsi dengan mouse atau trackball apa pun dan tidak memerlukan driver SetPoint atau MouseWare Logitech untuk diinstal.

fitur

• Tambahkan roda gulir ke mouse apa pun dengan lebih dari dua tombol
• Kesesuaian dengan sebagian besar aplikasi yang mendukung roda gulir (untuk semua jenis input)
• Akselerasi yang bisa disesuaikan
• Jarak pengguliran yang bisa disesuaikan (per "langkah" - lihat di bawah)
• Scrolling melangkah untuk mensimulasikan roda mouse nyata
• Pengalih mode tangan kiri / kanan cepat
• Cepat aktifkan / nonaktifkan dengan mengklik ikon baki
• Kecil dan ringan pada sumber daya sistem

Situs web produk tampaknya saat ini sedang down, tetapi di sini ada salinan teks situs di Archive.org .

Tautan unduhan ada di sini .

Ada 100 baris C ++ alternatif sederhana yang sangat mirip dengan solusi AutoHotKey, yaitu

• mengirimkan peristiwa roda gulir vertikal / horizontal dengan menggerakkan trackball sambil memegang salah satu Tombol-X dan
• klik tengah saat menekan dan melepaskan X-Button tanpa menggerakkan trackball.

https://github.com/Seelge/TrackballScroll

Sunting: Versi yang lebih baru menyediakan ikon systray, berfungsi pada Windows 10 dan didasarkan pada C #.

Inilah skrip AutoHotKey yang saya gunakan. Anda gulir dengan menahan tombol kecil kiri dan menggulirkan bola ke atas / bawah. Namun mengklik tombol kecil kiri masih BACK. Itu juga dapat menggulir ke kiri / kanan tetapi itu terlalu sensitif bagi saya sehingga berkomentar di sini (blok yang dimulai dengan ;timesX := Abs(movedx) / 4).

Saya menemukan versi aslinya di http://www.autohotkey.com/board/topic/30816-simulate-scroll-wheel-using-right-mouse-button/ . Saya memposting versi saya di sana sebagai orang lain8923.

$*XButton1::
Hotkey, $*XButton1 Up, XButton1up, off
;KeyWait, XButton1, T0.4
;If ErrorLevel = 1
;{
   Hotkey, $*XButton1 Up, XButton1up, on
   MouseGetPos, ox, oy
   SetTimer, WatchTheMouse, 5
   movedx := 0
   movedy := 0
   pixelsMoved := 0
;   TrayTip, Scrolling started, Emulating scroll wheel
;}
;Else
;   Send {XButton1}
return

XButton1up:
Hotkey, $*XButton1 Up, XButton1up, off
SetTimer, WatchTheMouse, off
;TrayTip
If (pixelsMoved = 0)
{
    ;The mouse was not moved, send the click event
    ; (May want to make it PGUP or something)
    Send {XButton1}
    Send {XButton1Up}
}
return

WatchTheMouse:
MouseGetPos, nx, ny
movedx := movedx+nx-ox
movedy := movedy+ny-oy

pixelsMoved := pixelsMoved + Abs(nx-ox) + Abs(ny-oy)

;timesX := Abs(movedx) / 4
;ControlGetFocus, control, A
;Loop, %timesX%
;{
;    If (movedx > 0)
;    {
;        SendMessage, 0x114, 1, 0, %control%, A ; 0x114 is WM_HSCROLL
;        movedx := movedx - 4
;    }
;    Else
;    {
;        SendMessage, 0x114, 0, 0, %control%, A ; 0x114 is WM_HSCROLL
;        movedx := movedx + 4
;    }
;}

timesY := Abs(movedy) / 4
Loop, %timesY%
{
    If (movedy > 0)
    {
        Click WheelDown
        movedy := movedy - 4
    }
    Else
    {
        Click WheelUp
        movedy := movedy + 4
    }
}   

MouseMove ox, oy
return

Sayang sekali Logitech tidak menerapkan simulasi roda gulir. Pengemudi mereka menjanjikan fitur untuk melakukannya, tetapi tidak berfungsi untuk semua aplikasi, menjadikannya tidak berguna. Mereka sangat dekat untuk menciptakan mouse yang sempurna! : s

Satu-satunya solusi yang saya temukan adalah menggunakan skrip AutoHotkey untuk itu. Dengan itu Anda dapat membuat tombol kecil kiri / kanan gulir ke atas dan ke bawah. Ini berfungsi dengan baik, tetapi itu benar-benar merepotkan untuk mengonfigurasinya: Anda harus mempelajari dasar-dasar AutoHotkey terlebih dahulu. Jika Anda memutuskan untuk melakukannya, inilah skrip AutoHotkey saya. Ini adalah adaptasi dari naskah asli Jerbo . Satu klik akan mulai menggulir dengan kecepatan normal, tetapi klik dua kali atau tripple akan mulai menggulir lebih cepat.

; This script remaps the two small buttons on a Logitech Trackman® Marble® Mouse
; to act as scroll up and scroll down

global lastXButton1ClickTime := 0
global nrSubsequentXButton1Clicks := 0

ScrollTheWheel(direction, scrollKey)
{
    now := A_TickCount
    timeSinceLastClick := now - lastXButton1ClickTime 
    lastXButton1ClickTime := now
    if (timeSinceLastClick < 300)
    {
        nrSubsequentXButton1Clicks := nrSubsequentXButton1Clicks + 1
    }
    else
    {
        nrSubsequentXButton1Clicks := 1
    }        

    sleepingFraction := 5

    if (nrSubsequentXButton1Clicks <= 1)
        scrollSpeed := 30
    if (nrSubsequentXButton1Clicks == 2)
        scrollSpeed := 15
    if (nrSubsequentXButton1Clicks >= 3)
        scrollSpeed := 5

    timeSlept := scrollSpeed

    loop 
    {
        if (direction == 1) ; Scroll down
        {
            static downKeyState
            if (scrollKey == 0) 
                GetKeyState, downKeyState, XButton1, P
            else
                GetKeyState, downKeyState, PgDn, P

            if downKeyState = U ; The key has been released, so break out of the loop
               break

            if (timeSlept >= scrollSpeed)
            {
                Send {WheelDown}
                timeSlept = 0                
            }
        }
        else ; Scroll up
        {
            static upKeyState
            if (scrollKey == 0)
                GetKeyState, upKeyState, XButton2, P
            else
                GetKeyState, upKeyState, PgUp, P

            if upKeyState = U ; The key has been released, so break out of the loop
               break            

            if (timeSlept >= scrollSpeed)
            {
                Send {WheelUp}
                timeSlept = 0                
            }
        }   

        Sleep, sleepingFraction
        timeSlept := timeSlept + sleepingFraction
    }    
}

XButton2::
    ScrollTheWheel(0, 0)
    return
XButton1::
    ScrollTheWheel(1, 0)
    return
!PgUp::
    ScrollTheWheel(0, 1)
    return
!PgDn::
    ScrollTheWheel(1, 1)
    return

Saya baru saja mendapatkan mouse Marmer Logitech dan juga memiliki masalah scrolling. Jadi saya telah membuat skrip ini di AutoHotKey. Xbutton kiri memungkinkan pengguliran, yang berarti bahwa saat turun Anda dapat menggulir secara vertikal dan horizontal dengan bola, dan bergerak maju dan mundur di browser dengan tombol kiri dan kanan. Xbutton kanan memiliki aksi yang sama dengan tombol tengah.

Saya di windows 7.

#SINGLEINSTANCE FORCE  
GLOBAL status := "basic"
GLOBAL cnt_x
GLOBAL cnt_y

XButton2::MButton

$*XButton1::
    status := "scroll"
    cnt_x := 0
    cnt_y := 0
    MOUSEGETPOS, st_x, st_y
    SETTIMER, _scroll, 30
RETURN

$*XButton1 UP::
    status := "basic"
    SETTIMER, _scroll, OFF
RETURN

_scroll:
    MOUSEGETPOS, cur_x, cur_y
    MOUSEMOVE, st_x, st_y

IF(abs(cur_x-st_x) > abs(cur_y-st_y)) {
    cnt_x := cnt_x + (cur_x-st_x)
    ControlGetFocus, control, A 
    IF (cnt_x > 7) {
        cnt := floor(cnt_x / 8)
        LOOP, %cnt% {
            SendMessage, 0x114, 0, 0, %control%, A
        }
        cnt_x := cnt_x - 8*floor(cnt_x / 8)
    } ELSE IF (cnt_x < -7) {
        cnt := -ceil(cnt_x / 8)
        LOOP, %cnt% {
            SendMessage, 0x114, 1, 0, %control%, A
        }
        cnt_x := cnt_x - 8*ceil(cnt_x / 8)
    }
} ELSE {
    IF (cur_y >= st_y) {
        cnt_y := cnt_y + (cur_y-st_y)**1.2
    } ELSE {
        cnt_y := cnt_y -(st_y-cur_y)**1.2
    }   
    IF (cnt_y > 7) {
        cnt := floor(cnt_y / 8)
        LOOP, %cnt% {
            CLICK WheelUp
        }
        cnt_y := cnt_y - 8*floor(cnt_y / 8)
    } ELSE IF (cnt_y < -7) {
        cnt := -ceil(cnt_y / 8)
        LOOP, %cnt% {
            CLICK WheelDown
        }
        cnt_y := cnt_y - 8*ceil(cnt_y / 8)
    }
}   
RETURN

$*LButton::
    IF (status = "basic") {
        CLICK DOWN Left
    } ELSE IF (status = "scroll") {
        SEND {Browser_Back}
    }
RETURN

$*LButton UP::
    IF (status = "basic") {
        CLICK UP Left
    }
RETURN

$*RButton::
    IF (status = "basic") {
        CLICK DOWN Right
    } ELSE IF (status = "scroll") {
        SEND {Browser_Forward}
    }
RETURN

$*RButton UP::
    IF (status = "basic") {
        CLICK UP Right
    }
RETURN

Bergantung pada OS Anda, Anda mungkin dapat mengonfigurasi salah satu tombol untuk mengaktifkan pengguliran melalui pemindahan pointer saat ditahan. Misalnya skrip berikut mengaktifkan ini pada tombol 10 pada mouse saya (tombol "tengah atas" dari Logitech MX310):

#!/bin/sh
xinput set-prop "Logitech USB-PS/2 Optical Mouse" 290 10
xinput set-prop "Logitech USB-PS/2 Optical Mouse" 286 1
xinput set-prop "Logitech USB-PS/2 Optical Mouse" 287 6 7 4 5

Ada tikus marmer (tikus) yang memiliki roda gulir disertakan. Kalau tidak, sepertinya aplikasi atau skrip akan diperlukan untuk mouse tanpa roda bersama dengan penggunaan salah satu tombol untuk menggunakan fungsi gulir (yang Anda catat dalam komentar ke jawaban lain, bukan solusi yang dapat diterima).

Jadi, "Mengapa menemukan kembali kemudi?" adalah pepatah yang baik dalam hal ini.

Dalam contoh-contoh ini, elemen dipasang secara fisik dan ada banyak jenis untuk dipilih. Di bawah ini adalah dua contoh dan gaya.

Atau sesuatu seperti ini: Adesso

Dua opsi non konvensional

• Gunakan Apple Magic Trackpad selain trackball. (Ini solusi saya saat ini) http://www.apple.com/magictrackpad/

• Beli pengontrol leapmotion dan gunakan itu sebagai tambahan untuk trackball. Lambaikan tangan Anda di depan perangkat untuk menggulir ke atas dan ke bawah. https://www.leapmotion.com/product

Kredit gambar http://www5.pcmag.com/media/images/393268-leap-motion-controller.jpg

Solusi sederhana (dan berani saya katakan secara ergonomis) adalah dengan menempatkan fungsi menggulir di kiri Anda.

Ini dapat dicapai dengan menggunakan mouse dengan tangan kiri / menggunakan keyboard dengan roda gulir bawaan di tepi kiri / dengan menetapkan fungsi gulir ke tombol tombol yang dapat diprogram dengan program seperti Mkey ( http: // www.seriosoft.org/en/index.php ).

Mengapa saya pikir ini lebih ergonomis - karena pendekatan ini mendistribusikan ketegangan secara lebih merata di kedua tangan. (Lebih lanjut tentang ini: http://capsoff.org/checklist ).

Saya menggunakan Windows7 dan menggunakan Kensington Orbit Optical Trackball tanpa menggulirkan - ini adalah trackball dua tombol, tanpa tombol-X yang dibutuhkan oleh sebagian besar skrip dan aplikasi AHK yang ditunjukkan oleh orang lain.

Namun, MouseImp bekerja untuk saya di Windows7. Ini dapat dikonfigurasi, tetapi saya sudah mengaturnya untuk right-click + rollmendapatkan layar gulir. Ini lebih mirip seret, jadi penunjuknya bergerak, dan Anda hanya punya satu layar pada satu waktu [perbarui: laju gulir dapat dikonfigurasi, sehingga bisa lebih dari "satu halaman"].

Pada saat yang sama, TrackballWorks Kensington telah dikonfigurasi untuk memberi saya gulir ke bawah halaman left-click + right-click. Sayangnya itu tidak bisa kemudian gulir kembali ke atas halaman pada satu waktu (satu atau yang lain).

Ini bukan plug produk - itu hanya apa yang saya temukan untuk bekerja dengan model / tipe trackball ini .

Peringatan: Anda terus-menerus mengklik kanan dan kiri, dan ini dapat menyebabkan kebingungan, dan tautan diikuti / js-diaktifkan ketika Anda hanya ingin berhenti menggulir . :::mendesah:::

Saya baru saja mendapat trackball nirkabel orbit dari kensington, ini luar biasa. Anda memiliki bola, Anda memiliki kedua tombol di setiap sisi dan Anda memiliki semacam lingkaran di luar trackball yang memungkinkan untuk menggulir ke atas atau ke bawah halaman. Ini benar-benar berfungsi, dan saya gunakan di Windows dan Mac OSX.

Saya sebenarnya membuat sesuatu untuk ini menggunakan AutoHotkey beberapa waktu lalu dan berpikir saya akan membagikannya di sini juga: Emulator Roda Mouse

Ini mengemulasi bergulir roda mouse dengan menggerakkan mouse di sekitar sambil menahan tombol kiri dan kanan mouse.

Anda juga dapat meniru klik tengah dengan mengklik tombol kiri dan kanan pada saat yang bersamaan.

Solusi lain untuk Windows 7 yang memungkinkan pengguliran di semua aplikasi, termasuk Internet Explorer:

1. Instal Autohotkey .
2. Simpan script ini sebagai scroll.ahkke Desktop.
3. Klik kanan scroll.ahk.
4. Pilih Run Script .
5. Konfirmasikan, jika diminta.

Ini akan membuat Anda menahan tombol kecil kanan gulir secara vertikal saat menggerakkan trackball. Tombol kiri kecil adalah tombol kembali.

Jika tautan ke kode Erik Elmore menghilang, ini dia:

;;
;; Emulate_Scrolling_Middle_Button.ahk
;; Author: Erik Elmore <erik@ironsavior.net>
;; Version: 1.1 (Aug 16, 2005)
;;
;; Enables you to use any key with cursor movement
;; to emulate a scrolling middle button.  While
;; the TriggerKey is held down, you may move the
;; mouse cursor up and down to send scroll wheel
;; events.  If the cursor does not move by the
;; time the TriggerKey is released, then a middle
;; button click is generated.  I wrote this for my
;; 4-button Logitech Marble Mouse (trackball),  
;; which has no middle button or scroll wheel.
;;

;; Configuration

;#NoTrayIcon

;; Higher numbers mean less sensitivity
esmb_Threshold = 7

;; This key/Button activates scrolling
esmb_TriggerKey = XButton2

;; End of configuration

#Persistent
CoordMode, Mouse, Screen
Hotkey, %esmb_TriggerKey%, esmb_TriggerKeyDown
HotKey, %esmb_TriggerKey% Up, esmb_TriggerKeyUp
esmb_KeyDown = n
SetTimer, esmb_CheckForScrollEventAndExecute, 10
return

esmb_TriggerKeyDown:
  esmb_Moved = n
  esmb_FirstIteration = y
  esmb_KeyDown = y
  MouseGetPos, esmb_OrigX, esmb_OrigY
  esmb_AccumulatedDistance = 0
return

esmb_TriggerKeyUp:
  esmb_KeyDown = n
  ;; Send a middle-click if we did not scroll
  if esmb_Moved = n
    MouseClick, Middle
return

esmb_CheckForScrollEventAndExecute:
  if esmb_KeyDown = n
    return

  MouseGetPos,, esmb_NewY
  esmb_Distance := esmb_NewY - esmb_OrigY
  if esmb_Distance
    esmb_Moved = y

  esmb_AccumulatedDistance := (esmb_AccumulatedDistance + esmb_Distance)
  esmb_Ticks := (esmb_AccumulatedDistance // esmb_Threshold) ; floor divide
  esmb_AccumulatedDistance := (esmb_AccumulatedDistance - (esmb_Ticks * esmb_Threshold))
  esmb_WheelDirection := "WheelDown"
  if (esmb_Ticks < 0) {
    esmb_WheelDirection := "WheelUp"
    esmb_Ticks := (-1 * esmb_Ticks)
  }

  ;; Do not send clicks on the first iteration
  if esmb_FirstIteration = y
    esmb_FirstIteration = n
  else {
    Loop % esmb_Ticks {
      MouseClick, %esmb_WheelDirection%
    }
  }

  MouseMove,esmb_OrigX,esmb_OrigY,0
return

Pengguna Marble Trackman lain di sini.

Saya menggunakan X-Mouse Button Control untuk emulasi gulir. Implementasi fitur ini belum sempurna di sana (belum?), Tetapi jauh lebih bermanfaat daripada implementasi Logitech di perangkat lunak SetPoint ™ mereka sendiri.

Saya merekomendasikan XMBC kepada siapa pun yang tidak ingin main-main dengan Autohotkey dan mencari sesuatu yang hanya berfungsi.