Apakah ada yang punya skrip Terminal Mac untuk menghapus file tersembunyi?

Stereo mobil saya dapat memutar musik dari USB flash drive, jadi saya bertanya tentang menyalin MP3 dari daftar putar iTunes . Itu bekerja dengan baik, tetapi stereo saya tidak akan memutar file MP3. Saya akhirnya memasukkan flash drive ke komputer kerja saya yang menjalankan Windows 7, dan saya menemukan masalah: banyak file tersembunyi dalam format ._[filename].mp3juga dimuat.

Saya tahu bahwa di Windows, Anda dapat menghapus file berdasarkan atribut, dan saya ingin tahu apakah Anda dapat melakukan hal yang sama di Terminal? Mungkin dengan skrip yang dapat saya jalankan dengan Volume sebagai parameter?

File-file ini disembunyikan di OS X karena mereka mulai dengan .dan karena itu tidak ditampilkan di Finder secara default. Tidak ada atribut khusus yang diatur dalam file-file ini selain itu.

Pendekatan yang sangat sederhana adalah menghapus semua file yang dimulai dengan titik dan garis bawah:

find /Volumes/<your-volume-name> -name '._*' -type f -delete

Catatan keamanan: Jalankan tanpa -deletemelihat file mana yang akan dihapus. Dan jangan pernah melakukan ini pada seluruh Mac HD Anda, hanya pada drive USB Anda.

Untuk beberapa informasi tambahan: File-file ini disebut "Resource Forks" dan terkadang mengandung informasi yang tidak ingin Anda hapus. Namun dalam kasus penggunaan Anda, itu tidak masalah. Anda dapat menonaktifkan pembuatan file-file ini secara permanen menggunakan BlueHarvest . Ada juga aplikasi yang mengklaim untuk membersihkan volume mereka, tapi saya belum mencobanya dan ini masih beta, jadi gunakan dengan hati-hati: Hidden Cleaner .

Satu lagi solusi yang bekerja untuk saya (MacOS 10.6.8) dalam tipe terminal:

dot_clean "/Volumes/<your-volume-name>"

Saya memiliki masalah yang sama persis dengan stereo mobil saya, 1 file / 2 tidak dapat diputar, karena pemain menganggap bahwa file dot yang dibuat oleh MAC OS adalah file musik ... Kemudian saya menemukan posting ini benar-benar bermanfaat, terima kasih.

Jadi saya kembali sekarang dengan solusi yang ditingkatkan dan gratis untuk Mavericks:

1. Buat Aplikasi Automator untuk menjalankan skrip AppleScript

2. Gunakan skrip ini:

   on run {input, parameters}
       try
           tell application "Finder" to set allDrives to the name of every disk whose local volume is true and startup is false
           set driveName to {choose from list allDrives with title "DiskCleaner" with prompt "Disk to Clean and Eject:" OK button name "Clean and Eject" cancel button name "Abort"} as text
           set getDriveIdentifier to "diskutil info " & quoted form of driveName & " | grep Ident | awk '{print $3}'"
           set driveIdentifier to do shell script getDriveIdentifier
           try
               do shell script "find /Volumes/" & quoted form of driveName & " -name '.DS_Store' -type f -delete"
               do shell script "find /Volumes/" & quoted form of driveName & " -name '.FBC*' -type f -delete"
               do shell script "find /Volumes/" & quoted form of driveName & " -name '._*' -type f -delete"
               do shell script "rm -rf /Volumes/" & quoted form of driveName & "/.{,_.}{fseventsd,Spotlight-V*,Trashes}"
               display notification "Disk Cleaned"
           on error
               try
                   do shell script "sudo find /Volumes/" & quoted form of driveName & " -name '.DS_Store' -type f -delete" with administrator privileges
                   do shell script "sudo find /Volumes/" & quoted form of driveName & " -name '.FBC*' -type f -delete" with administrator privileges
                   do shell script "sudo find /Volumes/" & quoted form of driveName & " -name '._*' -type f -delete" with administrator privileges
                   do shell script "sudo rm -rf /Volumes/" & quoted form of driveName & "/.{,_.}{fseventsd,Spotlight-V*,Trashes}" with administrator privileges
                   display notification "Disk Cleaned"
               on error
                   display notification "Can't Clean, Permission Denied"
               end try
           end try
           delay 1
           try
               do shell script "diskutil eject " & driveIdentifier
               display notification "Disk Ejected"
           on error
               display notification "Can't Eject, Disk in Use"
           end try
       on error
           display notification "No Disk to Clean and Eject"
       end try
   end run
   

3. Simpan aplikasi sebagai DiskCleaner.app misalnya

Script ini akan meminta Anda untuk memilih disk USB untuk dibersihkan dan dikeluarkan. Maka itu akan membersihkan disk USB (mencoba dengan kredensial admin jika gagal dengan yang sekarang), lalu mengeluarkan jika mungkin.

Tentu saja masih ada tempat untuk perbaikan, saya membuat skrip ini untuk diri saya sendiri!

Anda juga memiliki fleksibilitas untuk menambahkan baris kode untuk membersihkan lebih banyak file.

Nikmati!

Anda juga dapat menggunakan Automator untuk mencapai hal yang sama jika terminal membuat Anda takut:

Skrip ini digunakan untuk menghapus file atau direktori tersembunyi di drive USB. https://github.com/ulasyurtsever/delete-hidden-files-or-directories