Di Outlook2010, apakah ada cara untuk melihat pengingat tunda saat ini?

Apakah ada cara di Outlook 2010 untuk menarik daftar item yang saat ini ditunda? Sebagai contoh, katakanlah dua minggu keluar saya menetapkan pengingat untuk muncul pada hari Jumat untuk pertemuan makan siang yang penting pada hari Senin berikutnya (saya suka diingatkan tentang tugas-tugas Senin sebelum akhir pekan). Ketika pengingat muncul pada hari Jumat, saya tunda selama tiga hari sehingga akan muncul lagi tepat sebelum makan siang pada hari Senin. Lalu Senin berguling-guling dan ingatanku kabur dan aku agak paranoid sehingga aku tidak sengaja mengabaikan pengingat pada hari Jumat alih-alih menunda dengan benar. Saya masih dapat melihat janji temu yang asli di kalender saya, tetapi saya perlu memastikan bahwa saya benar-benar akan memiliki pengingat yang muncul ketika saya mengharapkannya sehingga saya tidak ketinggalan pertemuan saya.

Apakah ada cara di Outlook 2010 untuk menarik daftar pengingat yang saat ini ditunda? Ini juga akan membantu untuk kasus-kasus di mana saya menyelesaikan tugas yang pengingat saya tunda sampai nanti, dan saya sekarang ingin menarik pengingat tertunda dan membatalkannya.

Sub SnoozedReminders()

' http://www.jpsoftwaretech.com/check-your-outlook-reminders-in-vba/

Dim MyReminder As Outlook.Reminder
Dim MyReminders As Outlook.Reminders
Dim Report As String
Dim i As Long

Set MyReminders = Outlook.Reminders

i = 0

For Each MyReminder In MyReminders

    If HasReminderFired(MyReminder) = True Then
        i = i + 1
        Report = Report & i & ": " & MyReminder.Caption & vbCr & _
            "     Snoozed to " & MyReminder.NextReminderDate & vbCr & vbCr
    End If

Next MyReminder

CreateReportAsEmail "Snoozed Items", Report

End Sub


Function HasReminderFired(rmndr As Outlook.Reminder) As Boolean
    HasReminderFired = (rmndr.OriginalReminderDate <> rmndr.NextReminderDate)
End Function


' VBA SubRoutine which displays a report inside an email
' Programming by Greg Thatcher, http://www.GregThatcher.com

Public Sub CreateReportAsEmail(Title As String, Report As String)

    On Error GoTo On_Error

    Dim Session As Outlook.Namespace
    Dim mail As MailItem
    Dim MyAddress As AddressEntry
    Dim Inbox As Outlook.folder 

    Set Session = Application.Session
    Set Inbox = Session.GetDefaultFolder(olFolderInbox)
    Set mail = Inbox.items.Add("IPM.Mail")

    mail.Subject = Title
    mail.Body = Report

    mail.Save
    mail.Display

Exiting:
    Set Session = Nothing
    Set Inbox = Nothing
    Set mail = Nothing
    Exit Sub

On_Error:
    MsgBox "error=" & Err.Number & " " & Err.Description
    Resume Exiting

End Sub

Jika Anda tidak terbiasa dengan VBA, lihat halaman penjelasan Slipstick . Anda akan menemukan informasi tentang:

• pengaturan keamanan makro;
• tempat meletakkan kode (Anda dapat menggunakan modul reguler dengan Sisipkan | Modul); dan
• cara membuat tombol.

Menurut posting forum tunda item ini , tidak mungkin untuk melihat daftar item tunda. Pos menunjukkan bahwa Anda mungkin dapat melihat sejumlah informasi bermanfaat dengan membuat tampilan khusus yang menampilkan beberapa bidang pengingat.

Coba klik pada tab Kalender, pilih Lihat dan Ubah Tampilan. Kemudian pilih Daftar. Ini muncul untuk menampilkan daftar semua pengingat.