Bagaimana saya bisa membuka aplikasi konsol dengan ukuran jendela yang diberikan?

Aplikasi yang ingin saya mulai adalah MongoDB. Jika saya memulainya secara normal, tampilannya seperti ini:

Saya tidak suka jumlah jeda baris dan saya memiliki banyak ruang layar, jadi saya ingin memanfaatkan ruang tersebut untuk menghilangkan jeda baris.

Saya dapat mengubah ukuran jendela konsol MODE, jadi saya menulis file batch seperti ini:

@ECHO OFF
MODE con:cols=140 lines=70
%~dp0mongodb\bin\mongod --dbpath %~dp0data --rest

Sejauh ini baik. Ketika saya memulai file batch ini, saya mendapatkan jendela yang lebih besar, seperti yang diinginkan.

Tapi ketika saya sekarang tekan Ctrl+ Cuntuk keluar dari MongoDB, saya mendapatkan prompt yang mengganggu:

Terminate batch job (Y/N)?

Yang tidak berguna, karena perintah yang baru saja saya keluar adalah perintah terakhir dalam pekerjaan batch dan tidak peduli apa yang saya jawab, hasilnya sama.

Jadi, bagaimana saya bisa mendapatkan jendela konsol yang lebih besar untuk aplikasi tanpa meminta itu ketika saya menekan Ctrl+ C?

Saya menghabiskan beberapa jam hari ini untuk mengimplementasikan aplikasi C # kecil yang dapat membungkus aplikasi konsol lain dan menyesuaikan ukuran jendela host konsol.

console-wrappermudah digunakan. Hanya mengharapkan beberapa parameter baris perintah:

Usage: console-wrapper.exe [OPTIONS]

Options:

      --subject=VALUE        The application that should be started by the
                               console wrapper.
      --width=VALUE          The desired width of the console window.
      --height=VALUE         The desired height of the console window.
  -h, -?, --help             Shows this help message

--widthdan --heightdigunakan untuk mengatur ukuran jendela konsol yang dihasilkan. --subjectdapat digunakan secara opsional, jika dihilangkan, parameter yang tersisa diperlakukan sebagai perintah (dengan parameter) untuk memulai.

Jadi panggilan terakhir yang saya gunakan sekarang dalam skrip startup kami adalah:

START "MongoDB" database\console-wrapper.exe --width=140 --height=70 %~dp0database\mongodb\bin\mongod.exe --dbpath %~dp0database\data --rest

Jendela yang dihasilkan akan memiliki ukuran yang diminta dan pada saat memukul Ctrl+ C, jendela akan menutup (setelah benar-benar mematikan proses yang terkandung).

Sudahkah Anda mempertimbangkan untuk menjalankannya dari skrip PowerShell? Powershell mampu mengubah ukuran jendela itu sendiri

$h = Get-Host
$buf = $h.UI.RawUI.BufferSize
$buf.Width = 300
$h.ui.rawui.BufferSize = $buf
$win = $h.UI.RawUI.WindowSize
$win.Width = 150
$h.ui.rawui.WindowSize = $win
#Command to start mongodb here.

Ini menciptakan jendela dengan ukuran 150 tetapi juga memiliki penyangga yang dapat digulir ke samping sebanyak 300.

Sejauh yang saya mengerti pertanyaannya, Anda ingin MongoDB memiliki ukuran jendela konsol yang ditentukan dan untuk keluar ketika Anda menekan Ctrl+ C. Maka jawabannya cukup sederhana: gunakan jalan pintas untuk memulainya.

Saya tidak memiliki mongodexecutable, jadi saya akan gunakan perl.exesebagai contoh. Ketika Anda memulainya dari dialog Run ( Windows+ R), ukuran jendela konsol akan menjadi standar 80 × 25 dengan ukuran buffer untuk 300 baris.

1. Buat pintasan ke mongod(atau perldalam kasus saya).
2. Klik kanan pintasan dan klik Properti .
   1. Pada tab Pintasan di bidang Target , tambahkan parameter ke mongod.
   2. Mulai di bidang mengontrol direktori awal saat ini dari program yang dimulai. Secara default itu akan menjadi direktori di mana .exe berada.
3. Klik tab Layout .
   1. Ubah ukuran Jendela menjadi 140 × 70.
      
   2. Anda dapat meningkatkan Tinggi dari ukuran buffer layar sampai 1000 atau lebih untuk dapat menggulir ke atas pesan yang lebih tua.
   3. Jika Anda menghapus Biarkan jendela posisi sistem , Anda dapat menentukan lokasi jendela konsol di layar.
4. Klik OK untuk menutup properti pintasan.

Sekarang ketika Anda mengklik pintasan ini, jendela konsol akan memiliki ukuran yang ditentukan. Ketika Anda menekan Ctrl+ C, aplikasi keluar dan jendela ditutup tanpa ada permintaan tambahan.

Anda juga dapat mengubah tata letak jendela setelah Anda meluncurkannya dari dialog Run . Klik kanan judul jendela konsol dan klik Properti . Klik tab Layout , sesuaikan ukuran jendela dan klik OK untuk menutup properti dan menerapkan perubahan segera. (Jika jendela dimulai dari pintasan, properti pintasan diperbarui.)

Lain kali Anda memulai aplikasi yang sama, ukuran jendela konsol akan secara ajaib memiliki ukuran yang sama. (Saya belum memeriksanya kali ini tetapi dulu berfungsi.)

Pengaturan tata letak konsol default tinggal di sini di registri:

[HKEY_CURRENT_USER\Console]

Anda dapat mengubah pengaturan ini dan itu akan berlaku untuk SEMUA jendela perintah yang diluncurkan, terlepas dari jalurnya. Sayangnya, nilai mentahnya tidak ramah manusia.

Untuk mengaturnya seperti yang Anda inginkan, buka jendela cmd biasa, lalu edit pengaturan sesuai keinginan Anda. Lihat di registri di jalur di atas dan Anda akan melihat sub kunci di bawah "Konsol" untuk cmd.exe. Ekspor kunci itu ke file, ubah jalur ke atas dan impor, atau cukup salin nilai secara manual dari satu ke yang lain. Anda kemudian dapat menghapus entri spesifik cmd.exe. Sekarang, semua jendela perintah yang terbuka akan menggunakan default yang dimodifikasi.

Saya merasa berguna untuk membuat beberapa file entri registri dengan standar standar saya sehingga saya dapat dengan mudah meletupnya ke server baru ketika saya RDP masuk untuk pertama kalinya. Saya membuat preset untuk dua ukuran yang biasanya saya gunakan.

Untuk 1024 x 768 (Saya menggunakan ini untuk server yang biasanya diakses melalui alat RDP multi sesi):

Windows Registry Editor Version 5.00

[HKEY_CURRENT_USER\Console]
"ScreenBufferSize"=dword:012c0050
"WindowSize"=dword:00190050
"WindowPosition"=dword:000a000a
"FontSize"=dword:000c0007
"FontFamily"=dword:00000030
"FontWeight"=dword:00000190
"FaceName"="Terminal"
"QuickEdit"=dword:00000001

Untuk 1280 x 1024:

Windows Registry Editor Version 5.00

[HKEY_CURRENT_USER\Console]
"ScreenBufferSize"=dword:0bb800af
"WindowSize"=dword:004b00af
"WindowPosition"=dword:000a000a
"FontSize"=dword:000c0007
"FontFamily"=dword:00000030
"FontWeight"=dword:00000190
"FaceName"="Terminal"
"QuickEdit"=dword:00000001

Letakkan Startperintah di depan memanggil mongodb. Saya percaya itu harus memperbaikinya.

Jika Anda senang menjalankan file batch bersama dengan beberapa program pembantu kecil, solusi lengkap diposting oleh saya di sini:
Bagaimana file batch dapat menjalankan program dan mengatur posisi dan ukuran jendela?

Isi seperti di bawah ini. . . .

File kumpulan demo ini akan menjalankan program baris perintah dan mengatur posisi dan ukuran jendela konsol Prompt Perintahnya. Tema umum dari batch ini adalah sama dengan dua solusi sebelumnya (pada halaman Stack Overflow pada tautan di atas), tetapi ada beberapa masalah dan solusi yang unik untuk membuat pekerjaan ini - ini adalah jendela Prompt Perintah yang diselenggarakan oleh 'CMD .EXE 'dan bukan jendela GUI seperti' EXPLORER.EXE '.

Baca semua komentar dan deskripsi dalam file batch untuk info lebih lanjut.

Alat yang digunakan:
1.   MonitorInfoView  oleh Nir Sofer (41 KB)
2.   NirCmd  oleh Nir Sofer (43 KB)
3.   GetPIDs  oleh Daniel Scheibli (280 KB)
4.   upx.exe  --- adalah program baris perintah yang akan kita gunakan untuk demo ini; letakkan di direktori yang sama dengan file batch.
5. File batch --- lihat di bawah

Kumpulkan semua file ke dalam direktori. Ini adalah file batch, siap dijalankan di sistem Windows apa pun.

Apa yang akan dilakukan batch demo ini, selain menampilkan jendela konsol khusus kepada Anda, apakah akan dijalankan upx.exedengan sakelar baris perintah--best -v -o getpids-compressed.exe getpids.exe. Kami akan memampatkan alat kami 'GetPIDs' hingga 88 KB ........ Setelah diluncurkan, klik dua kali pada bilah judul jendela konsol ini untuk melihat fenomena menarik; jendela konsol ini berperilaku seperti GUI!

@echo off
setlocal enabledelayedexpansion enableextensions
pushd %~dp0%

REM ----- ADD SOME USEFUL INFORMATION TO THIS CONSOLE WINDOW TITLE.
for /f "tokens=3" %%A in ('getpids.exe') do set _PROCESS_ID_=%%A
title This batch file runs a command-line program and sets the position and size of its console window        (PROCESS ID = %_PROCESS_ID_%)

REM ********************** DESCRIPTION ************************************
REM ** This script opens a command-line program console window with specified
REM ** screen properties at the primary monitor (containing the taskbar).
REM ** The "X/Y position" and "W/H size" of the console window is auto-set by
REM ** this script and the monitor resolution is auto-calculated to suit.
REM ** 'MonitorInfoView.exe' is the helper tool used to capture the resolution
REM ** info of the monitor.
REM ** 'nircmd.exe' is the tool performing all the display trickery.
REM ** 'getpids.exe' is the helper tool used to capture the Process ID of the
REM ** working batch file, thus allowing us to identify which CMD.EXE host this
REM ** console window belongs to when looking at Task Manager.
REM **
REM ** To tweak this script, go to the code section named:
REM ** >>>>> USER INPUT/PREFERENCES ARE ALL SET HERE <<<<<
REM ***********************************************************************

REM ----- CLEAR ANY PREVIOUS JOB OUTPUTS IF THEY EXIST
if exist ~TMP.TXT type NUL > ~TMP.TXT

REM ----- OUTPUT THE PRIMARY MONITOR INFORMATION TO A TEXT FILE
MonitorInfoView.exe /hideinactivemonitors 1 /stext ~TMP.TXT

REM ----- ISOLATE THE RESOLUTION LINE, REMOVING ALL THE OTHER LINES IN THE TEXT FILE
for /f "delims=" %%A in ('type "~TMP.TXT" ^|find.exe /i "Maximum Resolution"') do echo %%A>~TMP.TXT

REM ----- GET THE RESOLUTION NUMBERS, AND SET THEM AS VARIABLES
for /f "tokens=3,4 delims=:X " %%A in ('type "~TMP.TXT"') do set _SCREENW_=%%A& set _SCREENH_=%%B


REM >>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>><<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
REM >>>>>>>>>> USER INPUT/PREFERENCES ARE ALL SET HERE [BEGIN] <<<<<<<<<<<<

REM ----- ----------------------------------------
REM ----- |COMMAND-LINE PROGRAM TO BE RUN:  FILE NAME (WITH EXTENSION)
REM ----- |
REM ----- | |IF PROG TO BE RUN IS 'CMD.EXE' (WINDOWS COMMAND PROCESSOR)
REM ----- | |ALSO READ THE NEXT COMMENTS ABOUT SETTING SWITCHES   

    set _MYPROGRAM_=upx.exe

REM ----- ----------------------------------------   
REM ----- |COMMAND-LINE PROGRAM TO BE RUN:  SWITCHES (TO BE PASSED TO THE PROGRAM)
REM ----- |
REM ----- | |YOU CAN LEAVE THIS VARIABLE WITH A BLANK VALUE IF RUNNING THE PROG WITHOUT ANY PARAMETERS
REM ----- | | 
REM ----- | | |IF THE VALUE CONTAINS THE CHARS  '|'  OR  '<'  OR  '>'  THIS BATCH WILL FAIL TO RUN !!!
REM ----- | | |
REM ----- | | | |YOU CAN APPEND EXTRA TEXT TO THE END OF THE COMMAND BY USING THE AMPERSAND CHARACTER '&'
REM ----- | | | | EXAMPLES:
REM ----- | | | | set _MYPROGRAMSWITCHES_=dir "%systemroot%\system32" /a/o/s/4 & this text will be ignored; useful for adding some inline comments.
REM ----- | | | | set _MYPROGRAMSWITCHES_=dir "%systemroot%\system32" /a/o/s/4         & this works too, and the extra blank spaces will also be ignored.
REM ----- | | | | 
REM ----- | | | | |IF PROG TO BE RUN IS 'CMD.EXE' (WINDOWS COMMAND PROCESSOR), PATH ARGUMENTS MUST POINT TO A SPECIFIC LOCATION
REM ----- | | | | |AND BE ABSOLUTE OR INCLUDE ENVIRONMENT VARIABLES, AND ALWAYS ENCLOSE PATHS IN QUOTES.
REM ----- | | | | | EXAMPLES:
REM ----- | | | | | set _MYPROGRAMSWITCHES_=type "C:\Folder With Spaces\File.txt"
REM ----- | | | | | set _MYPROGRAMSWITCHES_=type "C:\FolderWithoutSpaces\File.txt"
REM ----- | | | | | set _MYPROGRAMSWITCHES_=type "%SYSTEMROOT%\..\Folder With Spaces\File.txt"
REM ----- | | | | | set _MYPROGRAMSWITCHES_=type "%SYSTEMROOT%\..\FolderWithoutSpaces\File.txt"
REM ----- | | | | | set _MYPROGRAMSWITCHES_=type %0                                       <<<<<<<this batch file (quotes are optional; the only exception to the rule)
REM ----- | | | | | set _MYPROGRAMSWITCHES_=type "%~dp0%\..\File.txt"                     <<<<<<<goes back one Dir from this batch file
REM ----- | | | | | set _MYPROGRAMSWITCHES_=type "%~dp0%\..\SomeFolder\File.txt"          <<<<<<<goes back one Dir from this batch file and then forwards into "SomeFolder"
REM ----- | | | | | set _MYPROGRAMSWITCHES_=dir "%systemroot%\system32" /a/o/s/4          <<<<<<<displays directory listing of the System folder. NOTE: 'dir' by itself and
REM ----- | | | | |                                                                                without a specific path argument will resolve to the folder of this batch file.

    set _MYPROGRAMSWITCHES_=--best -v -o getpids-compressed.exe getpids.exe      &// original is 280 KB, will compress down to 88 KB

REM ----- ----------------------------------------
REM ----- |COMMAND-LINE PROGRAM TO BE RUN:  DIRECTORY PATH (OF THE PROGRAM)
REM ----- | 
REM ----- | |YOU CAN LEAVE THIS VARIABLE WITH A BLANK VALUE IF THE PROG IS AT SAME LOCATION AS BATCH
REM ----- | |THIS VARIABLE WILL BE IGNORED IF THE PROG IS 'CMD.EXE'
REM ----- | | 
REM ----- | | EXAMPLES:
REM ----- | | set _MYPROGRAMDIR_=.\                               <<<<<<<relative path, program and batch in same directory
REM ----- | |                                                                  dot backslash *OR* dot (trailing backslash is optional).
REM ----- | | set _MYPROGRAMDIR_=%dp0%                            <<<<<<<relative path, program and batch in same directory
REM ----- | |                                                                  same locatiion as previous but using environment variable.
REM ----- | | set _MYPROGRAMDIR_=..\                              <<<<<<<relative path, program is back one directory from batch
REM ----- | |                                                                  dot dot backslash *OR* dot dot (trailing backslash is optional).
REM ----- | | set _MYPROGRAMDIR_=%dp0%\..                         <<<<<<<relative path, program is back one directory from batch
REM ----- | |                                                                  same as location as previous but using environment variable.
REM ----- | | set _MYPROGRAMDIR_=%SYSTEMROOT%\..\My Utilities     <<<<<<<relative path, program is back one directory from the Windows folder
REM ----- | |                                                                  and then forwards into the folder 'My Utilities'
REM ----- | | set _MYPROGRAMDIR_=C:\My Utilities\                 <<<<<<<absolute path, enclosing quotes are optional; trailing backslash is optional
REM ----- | |                                                                  same location as previous

    set _MYPROGRAMDIR_=

REM ----- ----------------------------------------
REM ----- |SET THE WANTED DIMENSIONS OF THIS CONSOLE WINDOW

    set /a _WINW_=(%_SCREENW_% / 2) + 250
    set /a _WINH_=(%_SCREENH_% / 2) + 150
    set /a _WINX_=(%_SCREENW_% - %_WINW_%) / 2
    set /a _WINY_=(%_SCREENH_% - %_WINH_%) / 2

REM ----- ----------------------------------------
REM ----- |STYLE THIS CONSOLE WINDOW   !!!IMPORTANT!!!
REM ----- |
REM ----- | |IF WE DO NOT USE THE 'MODE' COMMAND HERE ALONG WITH ITS 'COLS/LINES' VALUES THEN
REM ----- | |THE POSITIONING/SIZING OF THIS WINDOW BY 'NIRCMD.EXE' FURTHER DOWN WILL NOT WORK !!!
REM ----- | |
REM ----- | | |SOME COMMANDS WILL OUTPUT A LOT OF LINES AND AND THE CONSOLE DISPLAY WILL BE TRUNCATED
REM ----- | | |RUN THIS FOR AN EXAMPLE=====>   cmd.exe dir "%systemroot%\system32" /a/o/s/4   <=====
REM ----- | | |TO SOLVE THIS PROBLEM, SET THE 'LINES' VALUE OF 'MODE' TO A VERY HIGH NUMBER
REM ----- | | |THE MAXIMUM NUMBER IS 32000 (ON MY SYSTEM); 'MODE' WILL BE IGNORED IF THE NUMBER IS HIGHER !!!   

    color 0A
    mode.com con:cols=%_SCREENW_% lines=10000

REM ----- ----------------------------------------
REM ----- |DELETE THE TEMP TEXT FILE MADE BY 'MonitorInfoView.exe'
REM ----- |COMMENT OUT THE LINE IF YOU DON'T CARE ABOUT DELETING IT

    del /f /q ~TMP.TXT 2>nul >nul

REM >>>>>>>>>> USER INPUT/PREFERENCES ARE ALL SET HERE [END] <<<<<<<<<<<<<<
REM >>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>><<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<


REM ----- RUN THE TASK . . .
nircmd.exe win setsize foreground %_WINX_% %_WINY_% %_WINW_% %_WINH_%
popd

if not defined _MYPROGRAMDIR_ set _MYPROGRAMDIR_=%~dp0
if "!_MYPROGRAMDIR_!" == "." set _MYPROGRAMDIR_=%~dp0
if "!_MYPROGRAMDIR_!" == ".\" set _MYPROGRAMDIR_=%~dp0
pushd %_MYPROGRAMDIR_%
if not exist %_MYPROGRAMDIR_% goto _SKIP_
set _CONVERT_PATH_="%CD%"
set _CONVERT_PATH_=%_CONVERT_PATH_:"=%
set _MYPROGRAMDIR_=%_CONVERT_PATH_%
:_SKIP_
popd

echo ===============================================================================
echo PROGRAM ..............: !_MYPROGRAM_!
if "!_MYPROGRAM_!"=="cmd.exe" (echo PROGRAM DIR ..........: %SYSTEMROOT%\system32) else (echo PROGRAM DIR ..........: !_MYPROGRAMDIR_!)
echo PROGRAM SWITCHES .....: !_MYPROGRAMSWITCHES_!
echo ===============================================================================

if "!_MYPROGRAM_!"=="cmd.exe" (goto _PROGRAM_IS_CMD_) else (goto _PROGRAM_IS_OTHER_)

:_PROGRAM_IS_CMD_
cd /d "%SYSTEMROOT%\system32"
!_MYPROGRAMSWITCHES_!
echo. & echo. & echo.
goto _END_

:_PROGRAM_IS_OTHER_ 
cd /d "!_MYPROGRAMDIR_!"
if "%CD%\!_MYPROGRAM_!" == "%CD%\" goto _ERRORMESSAGE_
if not exist "%CD%\!_MYPROGRAM_!" goto _ERRORMESSAGE_
"!_MYPROGRAMDIR_!\!_MYPROGRAM_!" !_MYPROGRAMSWITCHES_!
echo. & echo. & echo.
goto _END_

:_ERRORMESSAGE_
cls
color 4F
echo ===============================================================================
echo PROGRAM ..............: !_MYPROGRAM_!
echo PROGRAM DIR ..........: !_MYPROGRAMDIR_!
echo PROGRAM SWITCHES .....: !_MYPROGRAMSWITCHES_!
echo ===============================================================================
echo                        ^^!^^!^^!  E R R O R  ^^!^^!^^!
echo.
echo The program has failed to run; the path set by the above values does not exist.
echo Please exit this window and check the values you have set in this batch file.
echo.
echo This batch file is located here:
echo %0
echo. & echo. & echo. & echo. & echo.

:_END_

REM ----- CLEAR VARIABLE VALUES FROM MEMORY . . .
set _PROCESS_ID_=
set _SCREENW_=
set _SCREENH_=
set _MYPROGRAM_=
set _MYPROGRAMSWITCHES_=
set _MYPROGRAMDIR_=
set _WINW_=
set _WINH_=
set _WINX_=
set _WINY_=
set _CONVERT_PATH_=

REM ----- STOP THIS CONSOLE WINDOW FROM CLOSING   !!!IMPORTANT!!! . . .
REM ----- |
REM ----- | http://superuser.com/questions/306167/how-to-prevent-the-command-prompt-from-closing-after-execution
REM ----- | | by 'kitsu.eb' (April 26, 2014)
REM ----- | | | "My solution (just tested on Win7) is to add CMD as the last line in the batch file.
REM ----- | | |  This runs a nested command prompt that inherits the environment of its parent.
REM ----- | | |  That child shell holds the batch process open until you EXIT, at which point the
REM ----- | | |  batch has no child processes and also exits."
REM ----- | Comment . . .
REM ----- | | by me
REM ----- | | | "This is a workaround. You can't use PAUSE as the last command to stop this window from closing
REM ----- | | |  because the window will terminate after you press a key. While this batch is running, if you open
REM ----- | | |  Task Manager/Process Hacker/Process Explorer you will see an extra CMD.EXE child process running
REM ----- | | |  under the parent CMD.EXE of this batch file."
cmd.exe