Saya mencoba menulis file batch yang perlu menjalankan beberapa perintah menggunakan akun admin lokal (mulai / hentikan layanan) dan beberapa perintah menggunakan pengguna yang masuk (salin file dari direktori pengguna) dan saya menghadapi masalah. Saya sudah mencoba perintah berikut:

runa dengan / savecred

runas /user:(PC name)\(admin username) /savecred "net stop \"(service name)\""
runas /user:(PC name)\(admin username) /savecred "sc stop \"(service name)\""

Saat menggunakan /savecredsaya tidak dimintai kata sandi. Sebagai gantinya, jendela prompt perintah akan berkedip sebentar dan menghilang. Saya tidak dapat memberi tahu apa yang ada di jendela ini. Layanan tidak dihentikan.

runa tanpa / savecred

runas /user:(PC name)\(admin username) "net stop \"(service name)\""
runas /user:(PC name)\(admin username) "sc stop \"(service name)\""

Perintah-perintah ini meminta saya untuk kata sandi tetapi kemudian menunjukkan perilaku yang sama seperti perintah di atas - jendela prompt perintah muncul sebentar dan layanan tidak berhenti.

Idealnya saya ingin menyimpan kata sandi untuk sesi ini karena saya perlu menjalankan lebih banyak perintah dengan detail.

Apakah ini mungkin dan jika demikian, apa yang saya lakukan salah?

Anda dapat menambahkan berikut ini ke skrip Anda dan itu akan memaksanya untuk menjalankan yang ditinggikan. Tidak perlu mengunduh apa pun.

:: BatchGotAdmin
:-------------------------------------
REM  --> Check for permissions
>nul 2>&1 "%SYSTEMROOT%\system32\cacls.exe" "%SYSTEMROOT%\system32\config\system"

REM --> If error flag set, we do not have admin.
if '%errorlevel%' NEQ '0' (
    echo Requesting administrative privileges...
    goto UACPrompt
) else ( goto gotAdmin )

:UACPrompt
    echo Set UAC = CreateObject^("Shell.Application"^) > "%temp%\getadmin.vbs"
    echo UAC.ShellExecute "%~s0", "", "", "runas", 1 >> "%temp%\getadmin.vbs"

    "%temp%\getadmin.vbs"
    exit /B

:gotAdmin
    if exist "%temp%\getadmin.vbs" ( del "%temp%\getadmin.vbs" )
    pushd "%CD%"
    CD /D "%~dp0"
:--------------------------------------

pisahkan file batch Anda menjadi dua. Bagian yang ingin Anda jalankan sebagai paste admincmd ke system32. Bagian yang ingin Anda jalankan dalam cmd normal tempel di folder biasa, & dari sini panggil file batch kedua yang ada system32. Dengan cara ini bagian kedua selalu berjalan di admincmd. Saya sudah mencobanya & ini bekerja untuk saya.

Jika Anda tidak keberatan dengan perangkat lunak pihak ketiga, Anda dapat mencoba menjalankannya sebagai kata sandi runasspc. Ini akan menyimpan kata sandi Anda ke file terenkripsi. Kata sandi tidak perlu diekspos dalam file batch.

Perintah "Runas" tidak akan "sudo" perintah Anda.

Untuk melakukan ini dari file batch, Anda perlu "meninggikan" perintah yang Anda hasilkan. Unduh skrip Tinggikan Powertoy.

http://technet.microsoft.com/en-us/magazine/2008.06.elevation.aspx

Luncurkan perintah Anda sebagai:

runas /user:(PC name)\(admin username) /savecred "elevate.cmd net stop \"(service name)\""

atau

runas /user:(PC name)\(admin username) /savecred "elevate sc stop \"(service name)\""

Apa yang saya gunakan adalah kode berikut:

::#################################################################################################################################
:: Elevate this script                                                                                                            #
::#################################################################################################################################

(
    :: Check Admin rights and create VBS Script to elevate
    >nul fsutil 2>&1 || (

        :: Very little red console
        mode con cols=80 lines=3 
        color cf

        :: Message
        title Please wait...
        echo.
        echo                         Requesting elevated shell...

        :: Create VBS script
        echo Set UAC = CreateObject^("Shell.Application"^)>"%TEMP%\elevate.vbs"
        echo UAC.ShellExecute "%~f0", "%TEMP%\elevate.vbs", "", "runas", 1 >>"%TEMP%\elevate.vbs"
        if exist "%TEMP%\elevate.vbs" start /b >nul cscript /nologo "%TEMP%\elevate.vbs" 2>&1
        exit /b
    )

    :: Delete elevation script if exist
    if exist "%~1" >nul del /f "%~1" 2>&1
)

pushd "%~dp0"

.... your code ....

popd

Tunda setelah @echo Anda off dan komentar.

Jawaban yang disederhanakan (tambahan untuk user325534) jika Anda hanya perlu mulai bekerja di beberapa direktori dengan akses yang lengkap:

@echo off

set MyWorkDir=D:\dev\

echo Requesting administrative privileges...

echo Set UAC = CreateObject^("Shell.Application"^) > "%temp%\getadmin.vbs"
echo UAC.ShellExecute "cmd", "/C start /D %MyWorkDir% cmd", "", "runas", 1 >> "%temp%\getadmin.vbs"

"%temp%\getadmin.vbs"

Kode ini memungkinkan cmd untuk meminta kata sandi pengguna. Pengguna harus mengetikkan kata sandi mereka dan kemudian executable.batakan dijalankan sebagai administrator

main.bat

@echo off
color 1f
Title Main
Goto start
:Start
runas /user:%username% executable.bat
pause

executable.bat

all code that runs as administrator