Bagaimana cara menulis rumus dalam excel yang memungkinkan saya mengevaluasi jika setiap nilai dalam satu baris BENAR?

3

Pada dasarnya, saya ingin cara yang paling efisien untuk melakukan sesuatu seperti yang berikut ini dengan cara yang paling efisien dan dengan lebih banyak kolom:

=and(f2=true,g2=true,h2=true,i2=true)

Terima kasih.

microsoft-excel

— debryc
sumber

10

Anda bisa melakukan ini dengan sangat ringkas dengan rumus array. Rekatkan yang berikut ke dalam bilah rumus dan tekan Ctrl+ Shift+ Enter.

=AND(F2:I2)

EDIT:
Sebagai tanggapan terhadap komentar Jerry, jika rentang yang Anda periksa akan berisi apa pun selain nilai boolean, Anda harus menggunakan rumus yang lebih spesifik (karena semua teks, kosong, dan angka yang tidak sama dengan 0 akan dievaluasi sebagai TRUE). Berikut ini hanya akan menganggap sel dengan nilai boolean TRUEsebagai true.

=AND(F2:I2=TRUE)

Ini juga harus dimasukkan sebagai fungsi array dengan menekan Ctrl+ Shift+ Enter.

Jika kebetulan Anda ingin menghitung keduanya TRUEdan 1benar, Anda dapat menggunakan rumus array yang lebih rumit ini (dimasukkan dengan Ctrl+ Shift+ Enter).

=AND(NOT(ISERROR(MATCH(F2:I2,{TRUE,1},0))))

— Excellll
sumber

Ini jelas cara untuk pergi.

— LPChip

Entah bagaimana, saya mendapat kesan bahwa semua rumus array tidak berfungsi AND(). Ternyata itu hanya berlaku ketika ada lebih dari satu syarat! +1 Namun, saya lebih suka formula non-array bila memungkinkan.

— Jerry

@ Jerry Saya tahu apa maksud Anda tentang ANDtidak bekerja dalam rumus array. Ia berfungsi sebagai agregator (tidak yakin apakah itu istilah yang tepat) seperti SUM,, MINdan SUMPRODUCT, misalnya, ia dapat menggunakan array sebagai argumen, tetapi hanya mengembalikan satu nilai, tidak pernah menjadi array nilai. Jadi, jika Anda mencoba menekan ANDke layanan dalam kondisi IFformula dalam array, itu tidak akan mengembalikan array nilai T / F yang mungkin Anda cari, melainkan T / F tunggal. Sama berlaku untuk OR.

— Excellll

6

Anda dapat melakukan hal seperti ini untuk mempersingkat:

=COUNTIF(F2:I2,TRUE)=4

Ini menghitung jumlah TRUEdan memeriksa apakah ada 4.

Atau jika Anda tidak ingin 'menghitung' mereka dan memasukkan nomor ...

=COUNTIF(F2:I2,TRUE)=COUNTA(F2:I2)

Di atas tidak akan mempertimbangkan sel kosong. Jika Anda ingin menghitungnya juga:

=COUNTIF(F2:I2,TRUE)=COUNTA(F2:I2)+COUNTBLANK(F2:I2)

— Jerry
sumber

2

Pilihan lain adalah menggunakan fakta bahwa TRUE mengevaluasi ke 1 dan FALSE mengevaluasi ke 0 dalam kondisi tertentu.

Deskripsi evaluasi yang BENAR dan SALAH

Dengan menggunakan tautan di atas, Anda dapat menggunakan fungsinya

=product(F2:I2*1)

yang akan mengevaluasi ke 1 jika semuanya benar dan 0 jika ada kesalahan atau kekosongan.

fungsi ini harus dimasukkan dengan menekan ctrl + shift + enter karena ini merupakan formula array.

— gtwebb
sumber

Tapi jika ada 1dan TRUEdalam data, formula yang akan menghitung 1sebagai TRUEjuga, yang saya tidak berpikir dimaksudkan. Tapi yah, jika rentang OP hanya bisa berisi boolean, tidak mungkin ini salah.

— Jerry