Bagaimana cara mendapatkan data trailing dari arsip gzip?

Saya memiliki arsip gzip dengan data tambahan. Jika saya membongkar menggunakan gzip -ditu memberitahu saya: " dekompresi OK, trailing sampah diabaikan " (berlaku juga gzip -tyang dapat digunakan sebagai metode mendeteksi bahwa ada data seperti itu).

Sekarang saya ingin mengenal sampah ini, tetapi anehnya saya tidak dapat menemukan cara untuk mengekstraknya. gzip -l --verbosememberi tahu saya bahwa ukuran "terkompresi" dari arsip adalah ukuran file (yaitu dengan data trailing), itu salah dan tidak membantu. filejuga tidak membantu, jadi apa yang bisa saya lakukan?

Menemukan sekarang bagaimana cara mendapatkan data trailing.

Saya membuat skrip Perl yang membuat file dengan data trailing, sangat didasarkan pada https://bugs.debian.org/cgi-bin/bugreport.cgi?bug=604617#10 :

#!/usr/bin/perl
use strict;
use warnings; 

use IO::Uncompress::Gunzip qw(:all);
use IO::File;

unshift(@ARGV, '-') unless -t STDIN;

my $input_file_name = shift;
my $output_file_name = shift;

if (! defined $input_file_name) {
  die <<END;
Usage:

  $0 ( GZIP_FILE | - ) [OUTPUT_FILE]

  ... | $0 [OUTPUT_FILE]

Extracts the trailing data of a gzip archive.
Outputs to stdout if no OUTPUT_FILE is given.
- as input file file causes it to read from stdin.

Examples:

  $0 archive.tgz trailing.bin

  cat archive.tgz | $0

END
}

my $in = new IO::File "<$input_file_name" or die "Couldn't open gzip file.\n";
gunzip $in => "/dev/null",
  TrailingData => my $trailing;
undef $in;

if (! defined $output_file_name) {
  print $trailing;
} else {
  open(my $fh, ">", $output_file_name) or die "Couldn't open output file.\n";
  print $fh $trailing;
  close $fh;
  print "Output file written.\n";
}