Pergi ke X byte dari sini

Bagaimana saya bisa bergerak maju X byte, mulai dari lokasi kursor saat ini (termasuk jeda baris)?

[count]godapat digunakan untuk bergerak maju X byte dari awal buffer. Saya mencoba Shift + V, G, [count]go(dengan asumsi bahwa [count]goakan mulai menghitung dari awal pilihan saya), tetapi sayangnya itu tidak berhasil karena gohanya mulai menghitung dari awal buffer.

Saya juga mencoba :set rulerformat=%omenampilkan byte byte saat ini (seperti yang disarankan oleh Jumping ke byte byte, dan menampilkan posisi sebagai byte offset ), menambahkan angka di kepala saya dan akhirnya dikeluarkan [count]go. Ini berfungsi, tetapi tidak terlalu praktis ...

Pencarian ini bergerak 40 karakter (bukan byte, meskipun) maju:

/\_.\{40}/e

dengan mencari tepat 40 karakter ( \{40}) dalam bentuk apa pun, termasuk baris baru ( \_.), dan menempatkan kursor di akhir pencarian ( /e). Lihat: http://vimregex.com/#Non-Greedy , :help search-offsetdan:help \_

Juga, lihat :h 23.4untuk pengeditan biner.

Pembaruan: Berdasarkan jawaban ini , inilah fungsi yang melompat ke byte offset:

let s:last_jump_bytes = 0

function! JumpTo(byte_nr)
    let crt_byte = line2byte(line('.')) + col('.')
    if (a:byte_nr == 0)
        let dst_byte = crt_byte + s:last_jump_bytes
    else
        let dst_byte = crt_byte + a:byte_nr
        let s:last_jump_bytes = a:byte_nr
    endif
    let dst_line = byte2line(dst_byte)
    let dst_col = dst_byte -line2byte(dst_line)
    "remove next line if you don't want to record this for `Ctrl-O`
    execute "normal " . dst_line . "G"
    call setpos('.', [0, dst_line, dst_col])
endfunction

command! -nargs=1 JumpToOffset :call JumpTo(<f-args>)

" silly mapping to Ctrl-C (demo)
nnoremap <expr> <silent> <c-c> ":<c-u>call JumpTo(" . v:count . ")<cr>"

Dapat digunakan seperti ini:

:JumpToOffset 400

atau mengetik pemetaan keyboard yang dipetakan, dengan hitungan:

40CTRL-C

Jika Anda tidak menggunakan hitungan, nomor hitungan sebelumnya digunakan kembali. Jadi Anda dapat melakukan: 40CTRL-C CTRL-C CTRL-C 30CTRL-C CTRL-Cuntuk melompat 40, 40, 40, 30, 30 byte dll.

Tekan Ctrl-Ountuk melompat kembali (lihat komentar di dalam fungsi).

Saya akhirnya menggunakan solusi berikut, yang mengimplementasikan logika dari pertanyaan saya.

• [count]GOuntuk [count]memajukan byte.
• [count]Gountuk memindahkan [count]byte ke belakang.

Tambahkan ini ke Anda .vimrc:

function! JumpToByte(byte_nr)
    " See https://vi.stackexchange.com/a/3911/2720 for the byte counting bug
    let crt_byte = line2byte(line('.')) + col('.') - 1
    if version < 781 && &l:binary == 1 && &l:eol == 0
        let crt_byte += 1
        let crt_byte += line('.') == 1
    endif
    let dst_byte = crt_byte + a:byte_nr
    execute "normal " . dst_byte . "go"
endfunction
nnoremap <expr> <silent> GO ":<c-u>call JumpToByte(" . v:count . ")<cr>"
nnoremap <expr> <silent> Go ":<c-u>call JumpToByte(-" . v:count . ")<cr>"

Terima kasih kepada VanLaser untuk implementasi awalnya, yang menempatkan saya ke arah yang benar.