Bagaimana saya bisa memformat ulang string multi-line di vim saat menggunakan filetype Python?

Mari kita asumsikan saya sedang mengedit beberapa kode Python di vim yang agak mirip:

myobj.myfunc("Some string parameter that goes on and on and on and on and sometimes doesn't"
             "split very"
             "neatly over different lines so that"
             "it is formatted attractively")

Saya lebih suka memformat ulang ini sehingga mencerminkan hingga yang textwidthtelah saya tetapkan:

myobj.myfunc("Some string parameter that goes on and on and "
             "on and on and sometimes doesn't split very "
             "neatly over different lines so that it is "
             "formatted attractively")

Apakah ada cara mudah untuk melakukan ini? Jika ini adalah paragraf teks konvensional, gqipatau serupa akan berguna, tetapi ini tidak akan menangani tanda kutip yang digunakan untuk menghapus string.

Catatan : Saya bertanya secara khusus tentang Python di sini, tetapi idealnya, jawaban ini akan relevan untuk banyak jenis bahasa pemrograman yang memungkinkan kelanjutan string.

Oh, itu yang sulit. Saya pikir pendekatan terbaik mungkin adalah makro tetapi lebih mungkin sebuah plugin. Ini adalah contoh yang saya buat (saya butuh hobi yang lebih baik). Tampaknya bekerja untuk saya tetapi perlu plugin indentasi python untuk indentasi dengan benar. Cobalah.

function ReformatMultiLines()
  let brx = '^\s*"'
  let erx = '"\s*$'
  let fullrx = brx . '\(.\+\)' . erx
  let startLine = line(".")
  let endLine   = line(".")
  while getline(startLine) =~ fullrx
    let startLine -= 1
  endwhile
  if getline(endLine) =~ erx
    let endLine += 1
  endif
  while getline(endLine) =~ fullrx
    let endLine += 1
  endwhile
  if startLine != endLine
    exec endLine . ' s/' . brx . '//'
    exec startLine . ' s/' . erx . '//'
    exec startLine . ',' . endLine . ' s/' . fullrx . '/\1/'
    exec startLine . ',' . endLine . ' join'
  endif
  exec startLine
  let orig_tw = &tw
  if &tw == 0
    let &tw = &columns
    if &tw > 79
      let &tw = 79
    endif
  endif
  let &tw -= 3 " Adjust for missing quotes and space characters
  exec "normal A%-%\<Esc>gqq"
  let &tw = orig_tw
  let endLine = search("%-%$")
  exec endLine . ' s/%-%$//'
  if startLine == endLine
    return
  endif
  exec endLine
  exec 'normal I"'
  exec startLine
  exec 'normal A "'
  if endLine - startLine == 1
    return
  endif
  let startLine += 1
  while startLine != endLine
    exec startLine
    exec 'normal I"'
    exec 'normal A "'
    let startLine += 1
  endwhile
endfunction

Kemudian Anda bisa menggunakannya dengan :call ReformatMultiLines()dan / atau menggunakannya dalam pemetaan.

Jika ini kejadian biasa, Anda sebaiknya mencari plugin atau menggunakan fungsi @Sukima. Namun, jika saya melakukan ini dengan cepat, inilah yang mungkin akan saya lakukan:

1. Tambahkan baris baru setelah paren pembuka dan sebelum paren penutup sehingga string berada pada garis yang terpisah.

   myobj.myfunc(
                "Some string parameter that goes on and on and on and on and sometimes doesn't"
                "split very"
                "neatly over different lines so that"
                "it is formatted attractively"
   )
   

2. Pilih baris dengan string dan hapus kutipan di sekitarnya: :norm ^x$x

3. Kurangi lebar teks (untuk memperhitungkan kutipan yang hilang) :set tw-=2
4. Pilih kembali dan format: gvgq
5. Perbaiki lebar teks: :set tw+=2
6. Kutipan Re-add: gv:norm I"<Esc>A". Alih-alih <Esc>Anda ingin memasukkan escape literal dengan mengetikkan ctrl-v diikuti oleh key escape. Karena saya memetakan jj untuk melarikan diri, saya biasanya ketik jj di sini.
7. Opsional gunakan J untuk menggabungkan kembali dua baris pertama / dua terakhir. Ketika saya memiliki string yang sangat panjang dalam python seperti ini, saya biasanya lebih suka memulainya di baris berikutnya dan hanya membuat indentasi satu tingkat lebih tinggi dari baris sebelumnya. Ini memberi ruang lebih horizontal untuk string dan terasa lebih alami bagi saya. Atau, Anda bisa menyimpan string ke variabel di suatu tempat di atas. Dengan asumsi itu adalah string statis, Anda bahkan dapat menyimpannya ke variabel global sehingga berada pada tingkat lekukan yang jauh lebih rendah dan dapat ditampung pada baris yang lebih sedikit. Perhatikan bahwa Anda harus bergabung kembali dengan paren penutup pada baris yang sama, Anda mungkin ingin mengurangi / menambah bandwidth dengan 3 bukannya 2.

Memisahkan dan memformat kode sulit, terutama untuk bahasa dinamis seperti Python.

Alih-alih mencoba mengurai Python dalam Vimscript, saya sarankan Anda dapat menggunakan formatter eksternal seperti yapf . Dengan jawaban saya di sini, Anda dapat menulis ini secara otomatis saat menulis dengan:

augroup write_cmd
    autocmd BufWritePre *.py call s:write_cmd('yapf')
augroup end

The s:write_cmd()fungsi dalam jawaban lain - saya tidak akan menambahkannya di sini jadi aku tidak perlu memperbaruinya di dua tempat jika saya menemukan bug :-)

Anda juga dapat mengatur formatprguntuk yapfdan format secara manual dengan gq.

Fungsi-fungsi berikut dan pemetaan yang sesuai memecahkan masalah ini untuk saya:

function! BreakMultlineString(quote)
let c = 100
while c == 100
    normal 100|
    let c = virtcol('.')
    if c == 100
        execute "normal ," . a:quote
    endif
endwhile
endfunction

function! JoinMultilineString()
    let c = "'"
    while c == "'" || c == '"'
        normal gj^
        let c = matchstr(getline('.'), '\%' . col('.') . 'c.')
        normal k
        if c == "'" || c == '"'
            normal ,j
        endif
    endwhile
endfunction

" break lines
nnoremap <Leader>" 100\|Bi"<CR>"<Esc>
nnoremap <Leader><Leader>" :call BreakMultlineString('"')<CR>
nnoremap <Leader>' 100\|Bi'<CR>'<Esc>
nnoremap <Leader><Leader>' :call BreakMultlineString("'")<CR>

" join lines
nmap <Leader>j Jds'ds"x
nnoremap <Leader>J :call JoinMultilineString()<CR>