Set busur umpan balik transitif (TFAS): Lengkap dengan NP?

Beberapa waktu yang lalu, saya memposting permintaan referensi untuk masalah grafik di mana kami ingin menemukan 2-partisi tepi di mana kedua set memenuhi properti yang tidak terkait dengan kardinalitas mereka. Saya mencoba membuktikan bahwa masalah berikut ini NP-hard:

Diberikan turnamen , apakah ada busur umpan balik yang menetapkan dalam yang mendefinisikan hubungan transitif?$G = (V,E)$$F \subseteq E$$G$

Saya memang memiliki konstruksi untuk mencoba pembuktian, tetapi tampaknya itu akan menemui jalan buntu, jadi saya pikir saya mungkin bertanya di sini untuk melihat apakah saya kehilangan sesuatu yang jelas. Agar tidak membatasi kreativitas Anda pada alur pemikiran yang serupa dengan yang saya gunakan, saya tidak akan memposting upaya saya di sini.

Apakah ini masalah NP-hard? Jika demikian, bagaimana cara membuktikannya?

Untuk menambahkan sedikit konteks, berikut adalah konstruksi untuk grafik yang tidak memiliki set arc umpan balik transitif. Untuk konstruksi ini, saya akan menggunakan grafik gadget berikut:

Turnamen ini memiliki properti berikut (yang saya periksa menggunakan program, saya tidak membuktikannya secara resmi):

• jika (2,7) tidak ada dalam TFAS yang diberikan, maka (1,3) adalah
• jika (5,1) dalam TFAS yang diberikan, maka demikian juga (3,6)
• jika (7,3) dalam TFAS yang diberikan, maka (5,1) tidak

atau sedikit menyalahgunakan notasi logika predikat:

• $\neg (2,7) \rightarrow (1,3)$
• $(5,1) \rightarrow (3,6)$
• $(7,3) \rightarrow \neg (5,1)$

Anda akan melihat bahwa untuk setiap implikasi, kedua sisi saling berpasangan, sehingga konstruksi berikut berfungsi:

$A$

Saya menjalankan program clingo pendek yang melaporkan tidak ada grafik tanpa TFAS, tetapi ada bug. Saya memperbaikinya dan sekarang memverifikasi tidak ada grafik tanpa TFAS untuk n = 8 atau kurang. Untuk n = 9, ia menemukan yang ini:

is_edge(edge(2,3)) is_edge(edge(1,4)) is_edge(edge(2,4)) is_edge(edge(3,5)) is_edge(edge(4,5)) is_edge(edge(1,6)) is_edge(edge(2,6)) is_edge(edge(3,6)) is_edge(edge(5,6)) is_edge(edge(1,7)) is_edge(edge(4,7)) is_edge(edge(5,7)) is_edge(edge(6,7)) is_edge(edge(1,8)) is_edge(edge(3,8)) is_edge(edge(4,8)) is_edge(edge(5,9)) is_edge(edge(6,9)) is_edge(edge(7,9)) is_edge(edge(2,1)) is_edge(edge(3,1)) is_edge(edge(4,3)) is_edge(edge(5,1)) is_edge(edge(5,2)) is_edge(edge(6,4)) is_edge(edge(7,2)) is_edge(edge(7,3)) is_edge(edge(8,2)) is_edge(edge(8,5)) is_edge(edge(8,6)) is_edge(edge(8,7)) is_edge(edge(9,1)) is_edge(edge(9,2)) is_edge(edge(9,3)) is_edge(edge(9,4)) is_edge(edge(9,8))

Inilah pengkodean (diperbaiki)

% tfas.asp
#show is_edge/1.
vertex(1..n).

opp_edges(edge(A,B),edge(B,A)) :- vertex(A), vertex(B), A < B.
possible_edge(E1;E2) :- opp_edges(E1,E2).

{is_edge(E1); is_edge(E2)} = 1 :- opp_edges(E1, E2).
ntfas(E) :- possible_edge(E), not is_edge(E).
ntfas(edge(X, X)) :- vertex(X).

tfas(E) | fs(E) :- is_edge(E).
ntfas(E) :- fs(E).

broken :- ntfas(edge(A,C)), tfas(edge(A, B)), tfas(edge(B,C)).

reachable(X, Y) :- fs(edge(X, Y)), is_edge(edge(X, Y)).
reachable(X, Z) :- reachable(X, Y), fs(edge(Y, Z)), is_edge(edge(Y, Z)).
broken :- reachable(X, X).

tfas(E) :- broken, possible_edge(E).
fs(E) :- broken, possible_edge(E).
:- not broken.

Jalankan dengan clingo -c n=7 tfas.asp(Menggunakan clingo 4.2.1)

(n = 7 menunjukkan grafik tepat 7 simpul)

Ini harus mengembalikan memuaskan jika dan hanya jika ada grafik tanpa TFAS pada 7 simpul.

Oke, saya sudah tahu grafik apa yang dijelaskan oleh @Bach, dan buat kode itu di clingo (lihat deskripsi clingo di bawah. Itu dimulai dengan deskripsi grafik gadget dan dilanjutkan dengan menggambarkan cara menggabungkan salinannya bersama-sama untuk mendapatkan yang lengkap. Grafik 34-vertex turnamen G.Bach menjelaskan. Saya sudah melampirkan deskripsi grafik juga).

Saya kemudian melanjutkan untuk menjalankan clingo pada grafik itu dan mengklaim telah menemukan TFAS dengan 241 tepi. Tapi saya membuat kesalahan dalam pengkodean grafik. Saya memperbaiki kesalahan dan kloning sekarang melaporkan tidak memuaskan (yaitu tidak ada TFAS).

Inilah program untuk menemukan TFAS pada grafik

{tfas(E)} :- is_edge(E).
:- not tfas(edge(A,C)), tfas(edge(A, B)), tfas(edge(B,C)).

reachable(X, Y) :- not tfas(edge(X, Y)), is_edge(edge(X, Y)).
reachable(X, Z) :- reachable(X, Y), not tfas(edge(Y, Z)), is_edge(edge(Y, Z)).
:- reachable(X, X).

tfas_count(N) :- N = #count{tfas(E) : tfas(E)}.

#show tfas/1.
#show tfas_count/1.

Inilah program (yang diperbarui) untuk membuat grafik G.Bach. Saya menambahkan indikator di akhir untuk memeriksa bahwa grafik tersebut adalah grafik turnamen yang tersusun dengan baik:

gadget_vertex(0..7).

gadget_edge(0,1).
gadget_edge(0,2).
gadget_edge(0,3).
gadget_edge(0,4).
gadget_edge(1,2).
gadget_edge(1,3).
gadget_edge(1,6).
gadget_edge(1,7).
gadget_edge(2,3).
gadget_edge(2,4).
gadget_edge(2,5).
gadget_edge(2,7).
gadget_edge(3,4).
gadget_edge(3,5).
gadget_edge(3,6).
gadget_edge(4,1).
gadget_edge(4,5).
gadget_edge(4,6).
gadget_edge(4,7).
gadget_edge(5,0).
gadget_edge(5,1).
gadget_edge(5,6).
gadget_edge(6,0).
gadget_edge(6,2).
gadget_edge(6,7).
gadget_edge(7,0).
gadget_edge(7,3).
gadget_edge(7,5).

special_edge(a;b;c;d;e).

forces(a,b).
forces(b,c).
forcesn(c,a).
nforces(a,d).
forces(d,e).
forces(e,a).

relates(A,B) :- forces(A,B).
relates(A,B) :- nforces(A,B).
relates(A,B) :- forcesn(A,B).

is_se_pair(se_pair(A,B)) :- relates(A,B).
vertex_name(v(V,P)) :- gadget_vertex(V), is_se_pair(P).

matches(from(A), v(5, se_pair(A,B))) :- forces(A,B).
matches(to(A), v(1, se_pair(A,B))) :- forces(A,B).
matches(from(B), v(3, se_pair(A,B))) :- forces(A,B).
matches(to(B), v(6, se_pair(A,B))) :- forces(A,B).

matches(from(A), v(2, se_pair(A,B))) :- nforces(A,B).
matches(to(A), v(7, se_pair(A,B))) :- nforces(A,B).
matches(from(B), v(1, se_pair(A,B))) :- nforces(A,B).
matches(to(B), v(3, se_pair(A,B))) :- nforces(A,B).

matches(from(A), v(7, se_pair(A,B))) :- forcesn(A,B).
matches(to(A), v(3, se_pair(A,B))) :- forcesn(A,B).
matches(from(B), v(5, se_pair(A,B))) :- forcesn(A,B).
matches(to(B), v(1, se_pair(A,B))) :- forcesn(A,B).

same_vertex(V, V) :- vertex_name(V).
same_vertex(M, N; N, M) :- matches(X, M), matches(X, N).

already_found(v(Y,N2)) :- vertex_name(v(X,N1)), same_vertex(v(X,N1),v(Y,N2)), N1 < N2.
vertex(V) :- vertex_name(V), not already_found(V).

named_gadget_edge(edge(v(X,SE),v(Y,SE))) :- gadget_edge(X,Y), is_se_pair(SE).
from_gadget_edge_named(edge(A, B), edge(C,D)) :- named_gadget_edge(edge(C,D)), same_vertex(A,C), same_vertex(B,D), vertex(A), vertex(B).
from_gadget_edge(edge(A,B)) :- from_gadget_edge_named(edge(A,B),edge(C,D)).
is_edge(E) :- from_gadget_edge(E).
is_edge(edge(A,B)) :- vertex(A), vertex(B), A < B, not from_gadget_edge(edge(B,A)).

vertex_count(VN) :- VN = #count{vertex(V) : vertex(V)}.
edge_count(EN) :- EN = #count{is_edge(E) : is_edge(E)}.

#show vertex_count/1.
#show edge_count/1.

bidirectional :- is_edge(edge(A,B)), is_edge(edge(B,A)).
phantom_vertex :- is_edge(edge(A,B)), not vertex(A).
phantom_vertex :- is_edge(edge(A,B)), not vertex(B).
incomplete :- vertex(A), vertex(B), not is_edge(edge(A,B)), not is_edge(edge(B,A)), A != B.

#show bidirectional/0.
#show phantom_vertex/0.
#show incomplete/0.

Dugaan SWAG [sesuatu yang lebih baik daripada tidak sama sekali?]:

$G = (V,E)$$F \subseteq E$$G$$O(1)$

^{Catatan: countdowncontoh shootdown diterima! sepertinya tidak ada yang diberikan sejauh ini. bahkan yang lebih baik adalah beberapa pengamatan pola orientasi tepi yang terkait dengan kelas grafik tertentu. atau lebih banyak motivasi atau mengikatnya ke dalam beberapa literatur yang ada. ditawarkan dalam gaya Bukti dan sanggahan (Lakatos) ... juga, karena tampaknya masalah yang tidak biasa yang belum [banyak berhubungan], menyarankan untuk mempelajarinya secara empiris ....}